*use AFKR70FL.DTA/ NPKR7HFL.DTA/ PKKR61FL.DTA/ IAKR71FL.DTA
*Keep live children under 2
gen age=v008-b3
keep if age<24 & b5==1

* Child lives with respondent, not elsewhere
keep if b9==0
bysort v001 v002 v003: egen minbidx=min(bidx) 
* Need to drop those that are bidx==2 and minbidx==1
drop if bidx>minbidx

** Exclusive breast feeding
gen water=0
gen liquids=0
gen milk=0
gen solids=0
gen breast=0
gen bottle=0

*TO DETERMINE IF CHILD IS GIVEN WATER, SUGAR WATER, JUICE, TEA OR OTHER.
replace water=1 if (v409>=1 & v409<=7)
                                                                   
* IF GIVEN OTHER LIQUIDS
foreach xvar of varlist v409a v410 v410* v413* {
replace liquids=1 if `xvar'>=1 & `xvar'<=7
}
replace liquids=1 if v412c>=1 & v412c<=7
                                                                                                
* IF GIVEN POWDER/TINNED milk, FORMULA OR FRESH milk
foreach xvar of varlist v411 v411a v412 v414p {
replace milk=1 if `xvar'>=1 & `xvar'<=7
}

* IF STILL BREASTFEEDING
replace breast=1 if m4==95 

* IF WAS EVER BOTTLE FED
replace bottle=1 if m38==1 

*IF GIVEN ANY SOLID FOOD
foreach xvar of varlist v414* {
replace solids=1 if `xvar'>=1 & `xvar'<=7
}
replace solids=1 if v412a==1 | v412b==1 
                
gen diet=7
replace diet=0 if water==0 & liquids==0 & milk==0 & solids==0
replace diet=1 if water==1 & liquids==0 & milk==0 & solids==0
replace diet=2 if            liquids==1 & milk==0 & solids==0 
replace diet=3 if                         milk==1 & solids==0 
replace diet=4 if                         milk==0 & solids==1 
replace diet=5 if                         milk==1 & solids==1 
replace diet=6 if breast==0 

gen ebf=0 
replace ebf=1 if diet==0 
lab de A 0 "No" 1 "Yes"
la val ebf A
lab var ebf "Exclusive BF"

** AFGHANISTAN - Matching Table 11.2, page 192 for EBF in children 0-5 months **      
ta ebf if age<6 [iw=v005/1000000]
/*43.36% & 3068 vs. 43.3% & 3095 in DHS report*/

** NEPAL - Matching Table 11.3, page 242 for EBF in children 0-5 months **      
ta ebf if age<6 [iw=v005/1000000]
/*68.35% & 421 vs. 66.1% & 445 in DHS report*/

** PAKISTAN - Matching Table 11.3 for EBF in children 0-5 months **      
ta ebf if age<6 [iw=v005/1000000]
/*37.76% & 1151 vs. 37.7% & 1164 in DHS report*/

** MADHYA PRADESH, INDIA - For Matching Table for EBF in children 0-5 months **      
ta ebf if age<6 & v024==19 [iw=sv005/1000000] 
/*58.27% & 2044 vs. 58.4% & 2047 in DHS report*/

ta ebf if age<4 & v024==19 [iw=sv005/1000000] 
/*67.13% & 1245 vs. 67.3% & 1255 in DHS report*/

ta ebf if age>=6 & age<=9 & v024==19 [iw=sv005/1000000] 
/* 18.38 % & 1669 vs. 18.6% & 1696 in DHS report*/

ta ebf if age>=12 & age<=15 & v024==19 [iw=sv005/1000000] 
/*5.38% & 1522 vs. 5.4% & 1556 in DHS report*/

ta ebf if age>=12 & age<=23 & v024==19 [iw=sv005/1000000]
/*3.55% & 4226 vs. 3.6% & 4531 in DHS report*/

]*Finding the youngest child for each mother
bysort v001 v002 v003: egen minbidx=min(bidx) 

*Need to drop those that are bidx==2 and minbidx==1
drop if bidx>minbidx

*Child's age
gen age=v008-b3

** Matching Table 11.1, page 241 for breast feeding within 1 hour of birth in children under 2**      
gen ei=0 if age<24 
replace ei=1 if m34<=100 & age<24
svy:tab ei v025, col

Estimates:
/*55.07% & 1930 vs. 54.9% & 1978 in DHS report*/
/*Urban: 57.07% & 1034 vs. 57% & 1062 in DHS report*/
/*Rural: 52.76% & 897 vs. 52.5% & 916 in DHS report*/