The DHS Program User Forum
Discussions regarding The DHS Program data and results
Home » Countries » Ethiopia » Computing Newborn Mortality Proportions
Re: Computing Newborn Mortality Proportions [message #10208 is a reply to message #10202] Fri, 08 July 2016 14:06 Go to previous messageGo to previous message
Bridgette-DHS is currently offline  Bridgette-DHS
Messages: 3017
Registered: February 2013
Senior Member
Following is a response from Senior DHS Stata Specialist, Tom Pullum:

First, you are mixing days and months. v008-b3 is months since the birth. It's not a good idea to refer to this as age, because it can only be interpreted as age for children who have survived. When you restrict to this being >30, you are selecting births that were more than 30 months before the survey, not more than 30 days.

Neonatal deaths can occur in either the month of birth or the next month. To take account of censoring, which is very minor, I would restrict to births with v008-b3>1.

Second, there are two b variables for age at death, b6 and b7. b6 is more detailed and must be used for deaths in the first day or the first week but for deaths in the first month we normally use b7, which is a recode of b6, and specifically b7=0, which identifies deaths at less than one month. Someone could make a fuss over the use of "one month" rather than "28 days" but the error due to this difference is negligible when compared with other measurement errors for these estimates. If you do, say, "tab b6 if b7==0" you will see the correspondence between b6 and b7.

It is also relevant that b6 and b7 are not applicable, or ".", if the child survived. If, say you look at the proportion of values of b7 that are 0, you are getting the proportion of deaths that were neonatal, not the proportion of births that were neonatal deaths.

Table C.6 in the Ethiopia 2011 main report is included mainly for assessing data quality assessment. That's why, for example, it does not use b7, but instead uses b6, and it breaks out the response "one year" for children whose age at death is just stated to be "one year", without specification of months.

In the first column of that table, 65.4% is the percentage of infant deaths that are neonatal (among births in the past five years). It is not the neonatal death rate or the proportion of children who have a neonatal death.

In the Guide to DHS Statistics, there is a description of how the under-five mortality rates are calculated. What you are calculating, as a proportion, is not the same thing as a neonatal mortality rate.

You may not need this, but here is Stata code for the construction of table C.6.

* how to get table C.6 in the Ethiopia 2011 DHS main report

* open ETBR61FL.dta

set more off

* prepare the years ago variable
gen months_ago=v008-b3
gen years_ago5=1+int(months_ago/60)
drop if years_ago5>4

* construct the age in months variable used in Table C.6
describe b6
label list b6
* tab b6

gen age_tableC6=.
replace age_tableC6=0 if b6<=130
replace age_tableC6=1 if b6>130 & b6<200
replace age_tableC6=b6-200 if b6>200 & b6<300
replace age_tableC6=24 if b6>=224 & b6<301
replace age_tableC6=99 if b6==301
replace age_tableC6=. if b6==199 | b6==299 | b6>=399
tab age_tableC6 years_ago5 [iweight=v005/1000000]

gen nn_to_infant=.
replace nn_to_infant=0 if age_tableC6<=11
replace nn_to_infant=1 if age_tableC6==0
replace nn_to_infant=. if b6>=399
summarize nn_to_infant if years_ago5==1 [iweight=v005/1000000]
summarize nn_to_infant if years_ago5==2 [iweight=v005/1000000]
summarize nn_to_infant if years_ago5==3 [iweight=v005/1000000]
summarize nn_to_infant if years_ago5==4 [iweight=v005/1000000]
 
Read Message
Read Message
Read Message
Read Message
Read Message
Previous Topic: Cesarean section trends and associated factors
Next Topic: Re calculating the 2000 EDHS table 8.4
Goto Forum:
  


Current Time: Fri Mar 29 06:56:46 Coordinated Universal Time 2024