gen hw2_2 = hw2/10
* set weight to missing if not weighed for any reason
replace hw2_2 = . if hw2 >= 990
gen hw3_2 = hw3/10
* set height to missing if not measured for any reason
replace hw3_2 = . if hw3 >= 9990

* calculate date of measurement and date of birth
gen mdate = mdy(hw18,hw17,hw19)
gen bdate = mdy(b1,hw16,b2) if hw16<=31
replace bdate = mdy(b1,15,b2) if hw16>31
* if month or year of birth not reported, we don't have accurate age
replace bdate = . if b10 > 1
gen age = (mdate-bdate)/30.4375

* lying or standing
gen measure = hw15
replace measure = . if measure == 9
* DHS ignores lying or standing if: "standing" but < 8 months (240 days); or "lying", but >= 36 months (>1095 days)
replace measure = . if measure==2 & age <   8 & age!=.
replace measure = . if measure==1 & age >= 36 & age!=.

* calculate z-scores
zscore06, a(age) s(b4) h(hw3_2) w(hw2_2) measure(measure)

* mark those with different results - these should all be flagged cases
gen dif_ha = (round(haz06*100,1) == hw70) if hw3_2 != .
gen dif_wa = (round(waz06*100,1) == hw71) if hw2_2 != .
gen dif_wh = (round(whz06*100,1) == hw72) if hw2_2 != . & hw3_2 != .

* generate flag variables from the zscore06 variables
gen flag_ha = (haz06 < -6 | haz06 > 6)
gen flag_wa = (waz06 < -6 | waz06 > 5)
gen flag_wh = (whz06 < -5 | whz06 > 5)

* just show the cases with some difference to check
browse b4 b10 hw2_2 hw3_2 hw15 age haz06 waz06 whz06 flag_ha flag_wa flag_wh hw70 hw71 hw72 dif_ha dif_wa dif_wh if dif_ha == 0 | dif_wa == 0 | dif_wh == 0