The DHS Program User Forum
Discussions regarding The DHS Program data and results
Home » Countries » Ethiopia » Analysis on Exclusive breastfeeding (EBF) in Ethiopian DHS 2016 (unable to differentiate exclusive breastfeeding and non-exclusive breastfeeding in Ethiopian DHS 2016 )
Analysis on Exclusive breastfeeding (EBF) in Ethiopian DHS 2016 [message #18741] Mon, 10 February 2020 03:12 Go to next message
sko16 is currently offline  sko16
Messages: 21
Registered: June 2016
Location: Addis Ababa, Ethiopia
Member
Dear,
I am using KR file to replicate exclusive breastfeeding (EBF) and Non-Exclusive BF report on the final 2016 EDHS. M4 code (Duration of breastfeeding) has sub-categories. I re-categorized '95' still breastfeeding as '1' /EBF and all other as not still BF/ Non-EBF or 0.

I used for child living with his mother (B9) and 0 5 ages (B19) variables. I found Still BF as total number of 1003 infants and Non-Still BF infants as 59. But the finding didn't coincide with that of the final 2016 EDHS report, if it's alright the classification.

I have also read Guide to DHS 7 statistics (Breastfeeding and Complementary feeding, pps. 11.5 - 11.12 sub-sections) and many forums on EBF discussions. But I didn't get about Ethiopian DHS 2016 command to find Exclusive breastfeeding vs. Non-Exclusive BF. Would anyone help me the right command to find out Exclusive breastfeeding and Non-Exclusive breastfeeding in the Ethiopian DHS 2016 KR file? I appreciate in help, please.
Best regards,
Re: Analysis on Exclusive breastfeeding (EBF) in Ethiopian DHS 2016 [message #18833 is a reply to message #18741] Thu, 27 February 2020 14:16 Go to previous messageGo to next message
Bridgette-DHS is currently offline  Bridgette-DHS
Messages: 1794
Registered: February 2013
Senior Member

Following is a response from DHS Lead Nutrition Research Associate, Rukundo Benedict:

Based on your message it looks like you are using the correct file and some of the variables. Note if you are replicating table 11.3, this table is based on children under 2 years (var b19<24) who are living with their mother.

The STATA code below will be helpful for replicating table 11.3 in the 2016 Ethiopia DHS.

****Table 11.3 Breastfeeding status according to age****

use "ETKR70FL.DTA"

*Generate weight variable**
gen wgt=v005/1000000

*Generate age, keep those <2 years
gen age=b19
keep if age<24
*keep only those children alive 
ta b5
keep if b5==1

*Generate age groups
recode age (0/1=1 "0-1")(2/3=2 "2-3")(4/5=3 "4-5")(6/8=4 "6-8")(9/11=5 "9-11")(12/17=6 "12-17")(18/23=7 "18-23"), gen (age_months)


**If drank from bottle with nipple (bottlefeeding)
gen bottle=0
replace bottle=1 if m38==1 
gen wgt=v005/1000000
ta age_month bottle  [iw=wgt], row

*Important Note: for the other indicators, children must be the youngest child and living with mother
*keep only those living with mother
keep if b9==0
* finding the youngest child living with the mother
bysort v001 v002 v003: egen minbidx=min(bidx) 
* keep only children less than 2 years 
keep if age<24
ta bidx minbidx 
* need to drop those that are bidx==2 and minbidx==1
drop if bidx>minbidx
ta age_month [iw=wgt]



gen water=0
gen liquids=0
gen milk=0
gen solids=0
gen breast=0


*To determine if child is given water, sugar water, jiuce, tea or other  
replace water=1 if (v409>=1 & v409<=7)
                  
* If given other liquids
foreach xvar of varlist v409a v410 v410a v413*  {
replace liquids=1 if `xvar'>=1 & `xvar'<=7
}
                                                                                          
* If given powder/tinned milk, formula or fresh milk 
foreach xvar of varlist v411 v411a v412 v414p {
replace milk=1 if `xvar'>=1 & `xvar'<=7
}

*If currently breastfeeding
replace breast=1 if m4==95 


*If given any solid
foreach xvar of varlist v414* {
replace solids=1 if `xvar'>=1 & `xvar'<=7
}
replace solids=1 if v412a==1 | v412b==1 

gen feeding=1
replace feeding=2 if water==1
replace feeding=3 if liquids==1
replace feeding=4 if milk==1
replace feeding=5 if solids==1
replace feeding=0 if breast==0
label define feeding 0 "Not breastfeeding" 1 "exclusive breastfeeding" 2 "+Water" 3 "+Liquids" 4 "+Other Milk" 5 "+Solids"
label val feeding feeding


ta age_month feeding  [iw=wgt], row
ta age_month breast  [iw=wgt], row
Re: Analysis on Exclusive breastfeeding (EBF) in Ethiopian DHS 2016 [message #18853 is a reply to message #18741] Sun, 01 March 2020 22:44 Go to previous message
sko16 is currently offline  sko16
Messages: 21
Registered: June 2016
Location: Addis Ababa, Ethiopia
Member
Dear DHS experts,

Thank you so much. Really, it's helpful STATA code for replicating table 11.3 in the 2016 Ethiopia DHS. Please, keep in touch and always be problem solver for DHS data users.

Best wishes,

Previous Topic: RURAL VS URBAN
Next Topic: Calculating stillbirth using Ethiopia DHS 2000
Goto Forum:
  


Current Time: Sun Jun 7 01:34:35 Eastern Daylight Time 2020