The DHS Program User Forum
Discussions regarding The DHS Program data and results
Home » Topics » Reproductive Health » Skilled Birth Attendant Cambodia DHS 2014
Skilled Birth Attendant Cambodia DHS 2014 [message #19526] Tue, 07 July 2020 03:21 Go to next message
Savina is currently offline  Savina
Messages: 1
Registered: July 2020
Member
Dear All,
I would like to know how do we recode (STATA) the skilled birth attendant in Cambodia DHS 2014? Any recommended DO- file? I would like to group it into skilled birth attendant and attended by other personnel? I found no clue to group it as a woman can answer more than one category of delivery provider.

Thank so much. Urgent response is much appreciated :)
Re: Skilled Birth Attendant Cambodia DHS 2014 [message #19542 is a reply to message #19526] Thu, 09 July 2020 15:19 Go to previous message
Bridgette-DHS is currently offline  Bridgette-DHS
Messages: 2277
Registered: February 2013
Senior Member
Following is a response from DHS Senior Analysis & Research Manager, Shireen Assaf:

You would need to use the BR or KR file as this indicator is reported among births and not among women. Please see Table 13.6 of the Cambodia 2014 Final report, page 144. You also need to consult this table to know what is considered a skilled provider as this is country specific. The variables you need to explore are m3* . The code below should provide you with the indicator you are searching for (rh_del_pvskill). This code is copied from the DHS Github site for this chapter ( https://github.com/DHSProgram/DHS-Indicators-Stata/tree/mast er/Chap09_RH) and was adjusted for the country specific requirements. The do file you need to check is RH_DEL.do. The DHS GitHub site will contain code for all DHS indicators listed in the Guide to DHS Statistics, please feel free to explore and share (https://github.com/DHSProgram).

Stata code:
*use BR or KR file
              gen period = 60
              gen age = v008 - b3


*Note: Assitance during delivery and skilled provider indicators are both country specific indicators. 
**The table for these indicators in the final report would need to be checked to confirm the code below.
              gen rh_del_pv = 0 if m3a != .
              replace rh_del_pv           = 7         if m3n == 1
              replace rh_del_pv           = 6         if m3h == 1 | m3k == 1 
              replace rh_del_pv           = 5         if m3f == 1
              replace rh_del_pv           = 4         if m3g == 1 
              replace rh_del_pv           = 3         if m3d == 1 | m3e == 1 | m3f == 1 
              replace rh_del_pv           = 2         if m3b == 1 | m3c == 1 
              replace rh_del_pv           = 1         if m3a == 1
              replace rh_del_pv           = 9         if m3a == 8 | m3a == 9
              replace rh_del_pv           = .                        if age>=period
              
              label define pv                               ///
              1 "Doctor"                                                                   ///
              2 "Nurse/midwife"                                      ///
              3 "Country specific health professional" ///
              4 "Traditional birth attendant"   ///
              5 "Other health worker"                            ///
              6 "Relative/other"                                       ///
              7 "No one"                                                                  ///
              9 "Don't know/missing"
              label val rh_del_pv pv
              label var rh_del_pv "Person providing assistance during delivery"

//Skilled provider during delivery
** Note: Please check the final report for this indicator to determine what provider is considered skilled.
              recode rh_del_pv (1/2 = 1 "Skilled provider") (3/6 = 2 "Unskilled provider") (7 = 3 "No one") (9=4 "Don't know/missing"), gen(rh_del_pvskill)
              replace rh_del_pvskill = . if age>=period
              label var rh_del_pvskill "Skilled assistance during delivery"

ta rh_del_pvskill [iw=v005/1000000]       
Previous Topic: Heard about Family Planning Methods- NFHS 4
Next Topic: MOTHER POSTNATAL CARE ON SPSS
Goto Forum:
  


Current Time: Sun May 16 10:57:17 Coordinated Universal Time 2021