The DHS Program User Forum
Discussions regarding The DHS Program data and results
Home » Topics » Child Health » Antibiotic use for ARI Nepal 2011 (using stata)
Antibiotic use for ARI Nepal 2011 (using stata) [message #15355] Wed, 04 July 2018 05:48 Go to next message
charlotte.zheng is currently offline  charlotte.zheng
Messages: 2
Registered: July 2018
Member
Hi!

We are looking at rates of antibiotic use for ARI in Nepal 2011.

I note that I'm getting different values for antibiotic use for ARI compared to what is reported in statcompiler. Interestingly, antibiotic use for ARI is reported as 7% in the report (no other tables/figures available) but 29.8% in statcompiler. My value is 36.5% (weighted).

My codes for ARI and antibiotic use in ARI are below:

gen ari =0
replace ari = 1 if h31b==1 & (h31c==1 | h31c==3)
replace ari =. if b5==0

gen antibari=0 if ari==1
replace antibari=1 if ari==1 & h37f==1
replace antibari=1 if ari==1 & h37g==1
replace antibari=1 if ari==1 & h37j==1
replace antibari=1 if ari==1 & h37n==1
replace antibari=1 if ari==1 & h37o==1

Any way you could explain the discrepancies and advise on the correct figure?

Many thanks in advance,
Charlotte

Re: Antibiotic use for ARI Nepal 2011 (using stata) [message #15357 is a reply to message #15355] Wed, 04 July 2018 08:08 Go to previous messageGo to next message
Mlue
Messages: 88
Registered: February 2017
Location: North West
Senior Member
Hi Charlotte,

Try this one... (This is as far as I can help)

** Matches figures on STATcompiler **
gen antibari=0 if ari==1
replace antibari=1 if ari==1 & h37f==1
replace antibari=1 if ari==1 & h37g==1
replace antibari=1 if ari==1 & h37h==1
tab antibari [iw=weight]

**************************************************

For more, try this...

**************************************************
/* NEPAL DHS 2011 */
clear all
set matsize 800
set mem 1000m
cd "..."
use "NPBR60FL", clear
set more off

********************************************************************************
** WEIGHT VARIABLE
gen weight = v005/1000000

**************************

** SURVEY SET
gen psu =    v021
gen strata = v023
svyset psu [pw = weight], strata(strata)
*svydes

********************************************************************************

// RENAME

rename v013 age
rename v106 education
rename v190 wealth
rename v025 residence
rename v024 region
rename sdist district

////////////////////////////////////////////////////////////////////////////////

** CHILD'S AGE **
gen child_age=v008-b3

keep if child_age <60 & child_age !=.

********************************************************************************

recode child_age	(0/5=1 "<6 months") (6/11=2 "6-11 months") ///
					(12/23=3 "12-23 months") (24/35=4 "24-35 months") ///
					(36/47=5 "36-47 months") ///
					(48/59=6 "48-59 months") (else=.), gen(child_age_grp)

********************************************************************************

** ARI **
cap drop ari
gen ari=0
replace ari=1 if h31b==1 & (h31c==1 | h31c==3)
replace ari =. if child_age>=60 | b5==0
label define ari 0"No" 1"Yes"
label var ari "Child has acute respiratory infection (ARI)"
label val ari ari

********************************************************************************

global cough "h32a h32b h32d h32e h32i h32j h32l h32r h32z"

cap drop treat_ari
gen treat_ari=0 if ari==1
label define treat_ari 0"No" 1"Yes"
label var treat_ari "Received treatment for ARI"
label val treat_ari treat_ari

* TREATMENT FOR "ARI"

foreach xvar of varlist $cough {
replace treat_ari=1 if (`xvar'==1) & ari==1
}
*

********************************************************************************
global biotica "h37f h37g h37h"

cap drop antibari
gen antibari=0 if ari==1

foreach xvar of varlist $biotica {
replace antibari=1 if (`xvar'==1) & ari==1
}
*

*==============================================================================*

** DROP IF NOT WITHIN SAMPLE
qui regr ari [pw=weight]		
drop if e(sample)!=1	

* Code above is the same as: keep if ari !=.

********************************************************************************

** CHECK against report**
svy: tab child_age_grp ari, count format(%4.0f) miss
svy: tab child_age_grp ari, percent format(%4.1f) row miss

***************

svy: tab child_age_grp treat_ari, count format(%4.0f)
svy: tab child_age_grp treat_ari, percent format(%4.1f) row

***************

svy: tab child_age_grp antibari, count format(%4.0f)
svy: tab child_age_grp antibari, percent format(%4.1f) row

Good luck
Mlue
Re: Antibiotic use for ARI Nepal 2011 (using stata) [message #15358 is a reply to message #15355] Wed, 04 July 2018 22:51 Go to previous message
charlotte.zheng is currently offline  charlotte.zheng
Messages: 2
Registered: July 2018
Member
Hi Mlue

Thanks so much! Just tried this and they give the statcompiler figures as you say.

I'm still a bit confused though as the codes miss out h37n and h37o which are ciprofloxacin taken for fever/cough and other antibiotic taken for fever/cough.

When you tabulate these with ARI, 5 and 20 children are given ciprofloxacin and other antibiotic respectively.

An explanation could be that the recommended antibiotics for ARI according to IMCI are amoxicillin, co-trimoxazole and procaine penicillin (h37f, h37g and h37j) so I suppose you could argue these figures represent children given antibiotics to treat ARI but not children with ARI who received antibiotics (the latter being the definition statcompiler uses).

Perhaps someone from DHS can clarify this.

Many thanks for your help though!

Best wishes
Charlotte
Previous Topic: Immunization
Next Topic: Sex and survival of preceding child
Goto Forum:
  


Current Time: Sun Jan 24 01:02:55 Coordinated Universal Time 2021