The DHS Program User Forum
Discussions regarding The DHS Program data and results
Home » Topics » Nutrition and Anthropometry » Discrepancy in Exclusive BF estimates for Madhya Pradesh, India
Discrepancy in Exclusive BF estimates for Madhya Pradesh, India [message #13907] Tue, 23 January 2018 11:15 Go to next message
dgodha
Messages: 44
Registered: November 2016
Location: India
Member
Hello,

I have been doing the estimation for exclusive breastfeeding in multiple countries as described in this forum elsewhere. So far I have not had any problems in matching my estimates. However, it does not match with the DHS report for MP, India (Table 62, page 112). Below, I have pasted the estimates in the report versus those from my output

Quote:
Age Report My Estimates
<4 mths 67.3 67.05
<6 mths 58.4 58.20
6-9 mths 18.6 18.37
12-15 mths 5.4 5.36
12-23 mths 3.6 3.53


I have used the following code:
*Use IAKR71FL.DTA

*Declare survey data
gen wt=v005/1000000
svyset v001 [pweight=wt], strata(v022) vce(linearized) singleunit(missing) || v002

*Keep children under 2
gen age=v008-b3
keep if age<24

* Child lives with respondent, not elsewhere
keep if b9==0
bysort v001 v002 v003: egen minbidx=min(bidx) 
* Need to drop those that are bidx==2 and minbidx==1
drop if bidx>minbidx

** Exclusive breast feeding
gen water=0
gen liquids=0
gen milk=0
gen solids=0
gen breast=0
gen bottle=0

*TO DETERMINE IF CHILD IS GIVEN WATER, SUGAR WATER, JUICE, TEA OR OTHER.
replace water=1 if (v409>=1 & v409<=7)
                                                                   
* IF GIVEN OTHER LIQUIDS
foreach xvar of varlist v409a v410 v410*  v413* {
replace liquids=1 if `xvar'>=1 & `xvar'<=7
}

cap replace liquids=1 if v412c>=1 & v412c<=7
                                                                                                
* IF GIVEN POWDER/TINNED milk, FORMULA OR FRESH milk
foreach xvar of varlist v411 v411a v412 v414p {
replace milk=1 if `xvar'>=1 & `xvar'<=7
}

* IF STILL BREASTFEEDING
replace breast=1 if m4==95 

* IF WAS EVER BOTTLE FED
replace bottle=1 if m38==1 

*IF GIVEN ANY SOLID FOOD
foreach xvar of varlist v414* {
replace solids=1 if `xvar'>=1 & `xvar'<=7
}
replace solids=1 if v412a==1 | v412b==1 
                
gen diet=7
replace diet=0 if water==0 & liquids==0 & milk==0 & solids==0
replace diet=1 if water==1 & liquids==0 & milk==0 & solids==0
replace diet=2 if            liquids==1 & milk==0 & solids==0 
replace diet=3 if                         milk==1 & solids==0 
replace diet=4 if                         milk==0 & solids==1 
replace diet=5 if                         milk==1 & solids==1 
replace diet=6 if breast==0 

*diet=0: given only water (full bf)
*diet=1: given only liquids (bf & liquids)
*diet=2: given only milks (bf & milk)
*diet=3: given only solids (bf & solids)
*diet=4: given only milk and solids (bf & milk & solids)
*diet=5: not still breastfeeding (weaned)
*diet=6: not now being breastfed (m4~=95)

gen ebf=0 
replace ebf=1 if diet==0 
lab de A 0 "No" 1 "Yes"
la val ebf A
lab var ebf "Exclusive BF"

** For matching Table 62, page 112 for exclusive breastfeeding in 0-5 month children in MP**      
ta ebf if age<6 & v024==19 [iw=v005/1000000] 
ta ebf if age<4 & v024==19 [iw=v005/1000000] 
ta ebf if age>=6 & age<=9 & v024==19 [iw=v005/1000000] 
ta ebf if age>=12 & age<=15 & v024==19 [iw=v005/1000000] 
ta ebf if age>=12 & age<=23 & v024==19 [iw=v005/1000000] 


I will appreciate if someone can point out my error.

Thanks
D. Godha


Deepali
Re: Discrepancy in Exclusive BF estimates for Madhya Pradesh, India [message #13934 is a reply to message #13907] Fri, 26 January 2018 06:40 Go to previous messageGo to next message
dgodha
Messages: 44
Registered: November 2016
Location: India
Member
Hi,

I found the error in my command so please ignore my earlier post. I was using the wrong variable for my weights- v005 instead of sv005.

Best


Deepali
Re: Discrepancy in Exclusive BF estimates for Madhya Pradesh, India [message #13983 is a reply to message #13907] Wed, 31 January 2018 15:36 Go to previous messageGo to next message
Radhika_DHS is currently offline  Radhika_DHS
Messages: 4
Registered: January 2018
Location: India
Member
Hi Sir,

I will appreciate yours afford if you can explain the command you have used after computing children living with mother. how you have controlled your study universe to the youngest born child.


Radhika
Re: Discrepancy in Exclusive BF estimates for Madhya Pradesh, India [message #13989 is a reply to message #13983] Thu, 01 February 2018 01:19 Go to previous messageGo to next message
dgodha
Messages: 44
Registered: November 2016
Location: India
Member
Hi Radhika,

The following command helps in restricting the base population to the youngest born:
bysort v001 v002 v003: egen minbidx=min(bidx) 
* Need to drop those that are bidx==2 and minbidx==1
drop if bidx>minbidx


You may want to go through various threads where experts have clarified in detail.

Best


Deepali
Re: Discrepancy in Exclusive BF estimates for Madhya Pradesh, India [message #13990 is a reply to message #13989] Thu, 01 February 2018 05:23 Go to previous message
Radhika_DHS is currently offline  Radhika_DHS
Messages: 4
Registered: January 2018
Location: India
Member
Thank you for your valuable input.

Radhika
Previous Topic: Maternal height: strange patters
Next Topic: Food Security
Goto Forum:
  


Current Time: Fri Mar 29 04:46:20 Coordinated Universal Time 2024