The DHS Program User Forum
Discussions regarding The DHS Program data and results
Home » Countries » Nepal » TT injection- table 9.6 of page 170 NDHS 2016
TT injection- table 9.6 of page 170 NDHS 2016 [message #13604] Tue, 28 November 2017 19:55 Go to next message
rkchettri is currently offline  rkchettri
Messages: 19
Registered: November 2017
Member
Hello all,

Can anyone advise me the stata command for generating table 9.6 of Nepal DHS 2016? It is quite confusing how to take three variables (number of TT injection received in the last preg, TT injection before preg and time of those inj received) into account to identify the proportion of women who received TT ( or MATERNAL and NEONATAL TETANUS protection in the last pregnancy).

Thank you
R
Re: TT injection- table 9.6 of page 170 NDHS 2016 [message #13613 is a reply to message #13604] Wed, 29 November 2017 11:34 Go to previous messageGo to next message
Liz-DHS
Messages: 1516
Registered: February 2013
Senior Member
A response from analyst Lindsay Mallick
Quote:

use NPIR7HFL.dta, clear

numlabel, add

gen wt = v005/1000000

*generate denominator: any woman who had a birth in the last 5 years
recode v208 (0=0) (1/10=1) (else = .), gen(birth5)
label var birth5 "Had a birth in the last five years"


*******Tetanus*********
*two injections alst pregnancy
gen tet2lastp = 0 if birth5 == 1
replace tet2lastp =1 if m1_1 >1 & m1_1<8
label var tet2lastp "Had 2 or more tetanus shots during last pregnancy"

/*New variable includes mothers with two injections during the pregnancy of their last birth or two or
more injections (the last within 3 years of the last live birth), three or more injections (the
last within 5 years of the last birth), four or more injections (the last within 10 years of the
last live birth), or five or more injections at any time prior to the last birth.*/

*full tetanus

*first calculate total tetanus shots
g totet=0 if birth5 ==1
replace totet=m1_1 if m1_1>0 & m1_1<8
replace totet= m1a_1 + totet if (m1a_1 > 0 & m1a_1 < 8)

*now generating variable for date of last injection - will be 0 for women with at least 1 injection at last pregnancy
*use b19, new CDC age var
g lastinj= 9999
replace lastinj = 0 if m1_1>0 & m1_1<8
gen int age = (b19_01)/12 
replace lastinj = m1d_1 - age if m1d_1 <20 & (m1_1==0|(m1_1>7 & m1_1<9996)) // years ago of last shot - (age at of child), yields some negatives


*now generate summary variable for protection against neonatal tetanus 
g ttprotect = 0 if birth5==1
replace ttprotect = 1 if tet2lastp ==1 
replace ttprotect=1 if totet>=2 &  lastinj<=2 //at least 2 shots in last 3 years
replace ttprotect=1 if totet>=3 &  lastinj<=4 //at least 3 shots in last 5 years
replace ttprotect=1 if totet>=4 &  lastinj<=9 //at least 4 shots in last 10 years
replace ttprotect=1 if totet>=5  //at least 2 shots in lifetime
replace ttprotect=0 if birth5==1 & ttprotect==.
replace ttprotect = . if birth5==0
lab var ttprotect "Full Neonatal Tetanus Protection"


ta ttprotect [iw=wt]

Re: TT injection- table 9.6 of page 170 NDHS 2016 [message #13615 is a reply to message #13613] Wed, 29 November 2017 15:30 Go to previous messageGo to next message
rkchettri is currently offline  rkchettri
Messages: 19
Registered: November 2017
Member
Thank you very much, Lindsay, for your response.
I have another problem in birth preparedness practices; table 9.14, page number 178. Table shows % of pregnant women are prepared for individual birthpreparedness practices. I want to know the % percentage of women who were prepared 4 items out of 7 BPP items. How can I create stata command for this?

Thank you

[Updated on: Wed, 29 November 2017 15:54]

Report message to a moderator

Re: TT injection- table 9.6 of page 170 NDHS 2016 [message #13984 is a reply to message #13615] Wed, 31 January 2018 16:19 Go to previous messageGo to next message
Liz-DHS
Messages: 1516
Registered: February 2013
Senior Member
Dear User,
Do you still need assistance with this post?
Thank you!
Re: TT injection- table 9.6 of page 170 NDHS 2016 [message #13987 is a reply to message #13984] Wed, 31 January 2018 20:43 Go to previous message
rkchettri is currently offline  rkchettri
Messages: 19
Registered: November 2017
Member
Thank you for the response, Liz. I solved this problem. I will ask again if anything support needed.

Best
Resham
Previous Topic: Matching field worker and other files in 2016 NDHS
Next Topic: Merging Nepal 2016 HR + IR data
Goto Forum:
  


Current Time: Thu Mar 28 17:00:02 Coordinated Universal Time 2024