The DHS Program User Forum      
Discussions regarding The DHS Program data and results
Home » Topics » Reproductive Health » Table 9.7 __ BDHS 2007
Table 9.7 __ BDHS 2007 [message #12610] Thu, 22 June 2017 09:45 Go to next message
Mlue
Messages: 26
Registered: February 2017
Location: Cape Town
Member
Hi,

I'm trying to replicate Table 9.7 of the Bangladesh DHS of 2007. But I cannot seem to replicate the percentage delivered by a medically trained provider.

All I need is the variable (from the dataset) which shows that the woman received assistance from a paramedic (Nurse/midwife/paramedic/FWV) within the BDHS 2007 data.





This is what I've done so far (Stata):

use BDBR51FL, clear

***************************************************************************

** WEIGHT VARIABLE
gen weight = v005/1000000

**************************************************************************

** SURVEY SET
gen psu =    v021
gen strata = v023
svyset psu [pw = weight], strata(strata)

**************************************************************************

// RENAME

rename v013 age
rename v106 education
rename v190 wealth
rename v025 residence
rename v024 region
//rename sdist district

///////////////////////////////////////////////////////////////////////////

// GENERATING DEPENDENT VARIABLES


** Doctor
recode m3a (1=1) (else=0), gen(assisted_doctor)
label define assisted_doctor 0"No" 1"Yes"
label var assisted_doctor "Birth delivered by a doctor"
label val assisted_doctor assisted_doctor
svy: tab wealth assisted_doctor, percent format(%4.1f) row

** Nurse (I AM NOT SURE WHICH VARIABLE IS MEANT TO BE A PARAMEDIC)
cap drop nurse
gen nurse = .
replace nurse = 0 if m3b !=1
replace nurse = 0 if m3d !=1
replace nurse = 0 if m3e !=1
replace nurse = 1 if m3b ==1
replace nurse = 1 if m3d ==1
replace nurse = 1 if m3e ==1
svy: tab residence nurse, percent format(%4.1f) row

********************************************************************************

** SKILLED BIRTH ATTENDANT
gen skilled_birth	=	0
label define skilled_birth 0"Unskilled" 1"Skilled"
label var skilled_birth "Birth delivered by skilled birth attendant"
label val skilled_birth skilled_birth


** SKILLED BIRTH ATTENDANTS RECODE

foreach xvar of varlist m3a m3b m3d m3e {
replace skilled_birth=1 if `xvar'==1
}


*==============================================================================*

** DROP IF NOT WITHIN SAMPLE
qui regr m3a m3b m3d m3e if v208 >0 & v208 !=. [pw=weight]		
drop if e(sample)!=1	

********************************************************************************

** CHECK - DOES NOT MATCH WHAT'S IN THE REPORT
tab skilled_birth
svy: tab skilled_birth, count format(%4.0f)
svy: tab skilled_birth, percent format(%4.1f)

svy: tab residence skilled_birth, percent format(%4.1f) row

*==============================================================================*

exit







Re: Table 9.7 __ BDHS 2007 [message #12624 is a reply to message #12610] Sat, 24 June 2017 13:13 Go to previous messageGo to next message
Mlue
Messages: 26
Registered: February 2017
Location: Cape Town
Member
Hello,

Can anyone please assist with this?
Re: Table 9.7 __ BDHS 2007 [message #12691 is a reply to message #12624] Thu, 29 June 2017 12:30 Go to previous messageGo to next message
Liz-DHS
Messages: 1077
Registered: February 2013
Senior Member
Dear User, A response by senior research analyst, Dr. Lindsay Mallick,
Quote:

The Bangladesh 2007 questionnaire did not include a separate category for paramedic. Rather, the question reads,
"Who assisted with the delivery of (NAME)?"

And the response options are:

Health personnel qual. Doctor..........A
Nurse/Midwife/Paramedic................B
Family Welfare Visitor.........................C
Community Skilled Birth Attendant...D

Therefore, you will not be able to tease out births delivered by a paramedic. The second column in table 9.7 is then calculated using m3b (nurse/midwife/paramedic) and m3d (FWV).



Thank you!
Re: Table 9.7 __ BDHS 2007 [message #12707 is a reply to message #12691] Mon, 03 July 2017 03:34 Go to previous messageGo to next message
Mlue
Messages: 26
Registered: February 2017
Location: Cape Town
Member
Hi Liz,

Thank you for the response.

I have another challenge, I can't seem to be getting the total percentage (5.2%) for the second column Nurse/midwife/paramedic/FWV. Instead, my computation shows that about 16.3% of births were delivered by Nurse/midwife/paramedic/FWV.

Could you please tell me where I might be going wrong in the computation?

************************************************************ ************************************
The following Stata code is used to compute the variable for the second column of Table 9.7

gen nurse = 0

foreach xvar of varlist m3b m3d {
replace nurse=1 if `xvar'==1
}

**
svy: tab wealth nurse, percent format(%4.1f) row



Please find the full code below:


** BDHS 2007
clear all
use BDBR51FL, clear

***************************************************************************

** WEIGHT VARIABLE
gen weight = v005/1000000

**************************************************************************

** SURVEY SET
gen psu =    v021
gen strata = v023
svyset psu [pw = weight], strata(strata)

**************************************************************************

// RENAME

rename v190 wealth

///////////////////////////////////////////////////////////////////////////

// GENERATING DEPENDENT VARIABLES

qui regr m3a m3b m3d m3f if v208 >0 & v208 !=. [pw=weight]		
drop if e(sample)!=1	

** Doctor
recode m3a (1=1) (else=0), gen(assisted_doctor)
label define assisted_doctor 0"No" 1"Yes"
label var assisted_doctor "Birth delivered by a doctor"
label val assisted_doctor assisted_doctor
svy: tab wealth assisted_doctor, percent format(%4.1f) row

** Nurse

cap drop nurse
gen nurse = 0

foreach xvar of varlist m3b m3d {
replace nurse=1 if `xvar'==1
}

**
svy: tab wealth nurse, percent format(%4.1f) row

********************************************************************************

** SKILLED BIRTH ATTENDANT
cap drop skilled_birth
gen skilled_birth	=	0
label define skilled_birth 0"Unskilled" 1"Skilled"
label var skilled_birth "Birth delivered by skilled birth attendant"
label val skilled_birth skilled_birth


** SKILLED BIRTH ATTENDANTS RECODE

foreach xvar of varlist m3a m3b m3d m3f {
replace skilled_birth=1 if `xvar'==1
}
**

svy: tab wealth skilled_birth, percent format(%4.1f) row

*==============================================================================*


Re: Table 9.7 __ BDHS 2007 [message #12732 is a reply to message #12707] Wed, 05 July 2017 08:52 Go to previous messageGo to next message
Liz-DHS
Messages: 1077
Registered: February 2013
Senior Member
A response from senior research analyst, Lindsay Mallick:
Quote:

Dear user,

In the footnote of table 9.7, we see that "If the respondent mentioned more than one person attending during delivery, only the most qualified person is considered in this tabulation." So while your code accurately produces the percentage of births delivered by a nurse, some of those births were also delivered by a doctor.
You can add the line:
replace nurse = 0 if m3a==1
Then you will see that 778 cases reported also being delivered by a doctor and the percentage then becomes 5.2%, matching the final report.

The DHS Program has recently released a blog and a series of youtube videos on matching to the final report. You can find these here:
http://blog.dhsprogram.com/final-report-tables/ and here: https:// www.youtube.com/watch?list=PLagqLv-gqpTMU3avlnBDodTWCazURy4C T&v=tjuaPV4eC_E

Thanks,

Lindsay

Re: Table 9.7 __ BDHS 2007 [message #12734 is a reply to message #12732] Wed, 05 July 2017 09:28 Go to previous message
Mlue
Messages: 26
Registered: February 2017
Location: Cape Town
Member
Thank you very much Liz and Lindsay Mallick.

This issue has been resolved with your assistance. Thank you
Previous Topic: weighting adolescent dataset
Next Topic: Construction Methodology of DHS
Goto Forum:
  


Current Time: Tue Oct 17 03:50:17 Eastern Daylight Time 2017