The DHS Program User Forum
Discussions regarding The DHS Program data and results
Home » Data » Dataset use in Stata » DHS 2013 Philippines
DHS 2013 Philippines [message #12241] Fri, 14 April 2017 13:27 Go to next message
ibchoa is currently offline  ibchoa
Messages: 2
Registered: April 2017
Member
Good day!

I am doing a research about the factors determining the prevalence of Tuberculosis in the Philippines using the 2013 survey.
I just know if I am on the right track here. I am using the PR data, and i used the variable sh204d because i thought that is the count for the people with TB.

First, I used rao scott using sampling weights with the ff command:

generate wgt = hv005/1000000
tab hv005[iweight=wgt]
svyset hv021 [pweight = wgt], strata( hv023 )
svy: tab sh204d hv270 , row

and so on.

However, I noticed that there is only 71 out of 14,339 self reported TB cases. Is it still possible to conduct my study given that low count?

Thank you.

[Updated on: Tue, 18 April 2017 09:59] by Moderator

Report message to a moderator

Re: DHS 2013 Philippines [message #12262 is a reply to message #12241] Tue, 18 April 2017 10:08 Go to previous message
Bridgette-DHS is currently offline  Bridgette-DHS
Messages: 3013
Registered: February 2013
Senior Member
Following is a response from Senior DHS Stata Specialist, Tom Pullum:


I think there are something like 367 unweighted self-reported cases of TB in that survey. That figure would include all ages, men and women. You need to do some reshaping of the data. The line numbers of the "sick persons" are given by sh203*.
367 cases would be enough for a simple analysis. 71 would not be. But I don't know how you got 71. The lines you gave do not work for me.

The following lines will do what you want. They will do all illnesses, not just TB. You will have to change the path to the data file. Let me know if you have other questions.

use e:\DHS\DHS_data\PR_files\PHPR61FL.dta, clear

* Revise the following line to keep whatever variables you want
keep hv001 hv002 hvidx sh204*

* change index 01 to 1, 02 to 2, etc
rename sh204*_0* sh204*_*

local letterlist a b c d e f g h i j k l m n o p q x
foreach ll of local letterlist {
scalar sl="`ll'"
scalar list sl

gen sh204`ll'=.
label values sh204`ll' SH204A

  local li=1
  quietly while `li'<=12 {
  replace sh204`ll'= sh204`ll'_`li' if `li'==hvidx
  local li=`li'+1
  }

}

drop sh204*_*

label variable sh204a "Illness: Diabetes"
label variable sh204b "Illness: Cancer"
label variable sh204c "Illness: Hypertestion"
label variable sh204d "Illness: TB"
label variable sh204e "Illness: Acute respiratory infection"
label variable sh204f "Illness: Acute gastro-enteritis"
label variable sh204g "Illness: Common cold/ cough/flu/ fever"
label variable sh204h "Illness: Cut/ Wound"
label variable sh204i "Illness: Burn"
label variable sh204j "Illness: Fracture/ broken bone"
label variable sh204k "Illness: Dislocation/ slipped disk"
label variable sh204l "Illness: Surgery"
label variable sh204m "Illness: Diarrhea"
label variable sh204n "Illness: Dengue fever"
label variable sh204o "Illness: Measles"
label variable sh204p "Illness: Chikungunya"
label variable sh204q "Illness: Amoebiasis"
label variable sh204x "Illness: Other"


egen illnesses=rowtotal(sh204*)
tab illnesses,m
replace illnesses=9 if illnesses>4 & illnesses<.
label define illnesses 9 "missing"
label values illnesses illnesses
label variable illnesses "Nummber of illnesses"
Previous Topic: Convert DHS (SPSS?) missing value codes to Stata codes in Stata dataset
Next Topic: How to merge KR with PR
Goto Forum:
  


Current Time: Tue Mar 19 03:45:37 Coordinated Universal Time 2024