The DHS Program User Forum
Discussions regarding The DHS Program data and results
Home » Topics » Fertility » high-risk fertility behaviour
high-risk fertility behaviour [message #3640] Tue, 20 January 2015 21:40 Go to next message
lizzy_nnena@yahoo.com is currently offline  lizzy_nnena@yahoo.com
Messages: 4
Registered: January 2015
Location: Nigeria
Member
pls help me with the calculations on the high-risk fertility behaviour categories so that i will be able to match the figure in the nigeria DHS final report 2013.

Question1: how do i calculate first order birth for women between ages 18 and 34 years.

Question 2: help me with the calculations of birth interval between births. i have studied the DHS guide i still have difficulties in the calculations.

thanks
Re: high-risk fertility behaviour [message #3664 is a reply to message #3640] Fri, 23 January 2015 13:25 Go to previous messageGo to next message
Liz-DHS
Messages: 1516
Registered: February 2013
Senior Member
Dear User,
Here is a response from one of our technical experts, Dr. Shea Rutstein:
Quote:
There are three columns for Table 8.5: Percent of births by risk category, relative risk category, and percent of married women by risk category.
There are single and multiple risk categories (rows of the table). For the third column, the risks categories are those that women would have if they became pregnant. Therefore, women who have no children and are between 17 years, 3 months of age and 34 years, 2 months of age would be those for question 1 (risk category 2).
Question 2: For the first two columns, the preceding birth interval is standard recode variable b11 <24 if there were 2 or more births (months of the preceding birth interval--twins, triplets have the same value to the birth of a preceding pregnancy). For the third column, the preceding birth interval is standard recode variable v222<15 if there were 1 or more births (months between last birth and interview).

Here is the CSPRO code for Table 8.5
for ch in REC21_EDT do
months = V008 - B3(ch);
if months < 60 then { For all children born }
agemoth = int( (B3-V011)/12 ); { in the last five years }
agemo18 = ( agemoth < 18 );
agemo34 = ( agemoth > 34 );
inter24 = 0;
if !special(B11) then
inter24 = ( B11 < 24 );
endif;
{ adjust multiple births to give the same order as that of the first of the multiples }
xorder = BORD;
if B0 > 1 then xorder = BORD - B0 + 1 endif;
bord3 = ( xorder > 3 );
frstb = ( xorder = 1 );
box agemo18 : agemo34 : inter24 : bord3 : frstb => rowt805;
0 : 0 : 0 : 0 : 0 => 1; { no risk }
0 : 0 : 0 : 0 : 1 => 2; { unavoidable risk }
1 : 0 : 0 : 0 : => 3; { single risk }
0 : 1 : 0 : 0 : => 4;
0 : 0 : 1 : 0 : => 5;
0 : 0 : 0 : 1 : => 6;
1 : 0 : 1 : 0 : => 7; { multiple risk }
1 : 0 : 0 : 1 : => 7;
1 : 0 : 1 : 1 : => 7;
0 : 1 : 1 : 0 : => 8;
0 : 1 : 0 : 1 : => 9;
0 : 1 : 1 : 1 : => 10;
0 : 0 : 1 : 1 : => 11;
: : : : => default;
endbox;
box rowt805 => norisk;
1 => rowt805;
=> notappl;
endbox;
box rowt805 => unavoid;
2 => rowt805 - 1;
=> notappl;
endbox;
box rowt805 => singrisk;
3-6 => rowt805 - 2;
=> notappl;
endbox;
box rowt805 => multrisk;
7-11 => rowt805 - 6;
=> notappl;
endbox;
currmar1 = notappl;
colt805 = 1;
xtab( t805, rweight );
if B5 <> 1 then { For dead children }
colt805 = 2;
xtab( t805, rweight );
endif;
endif;
enddo;

if V502 = 1 then { For currently married women }
colt805 = notappl;
currmar1 = 1;
agemoth = V008 - V011;
agemo18 = ( agemoth < 17*12+3 );
agemo34 = ( agemoth > 34*12+2 );
inter24 = 0;
if V201 > 0 then
inter24 = ( V222 < 15 );
endif;
bord3 = ( V201 > 2 );
frstb = ( V201 = 0 );
box agemo18 : agemo34 : inter24 : bord3 : frstb => rowt805;
0 : 0 : 0 : 0 : 0 => 1; { no risk }
0 : 0 : 0 : 0 : 1 => 2; { unavoidable risk }
1 : 0 : 0 : 0 : => 3; { single risk }
0 : 1 : 0 : 0 : => 4;
0 : 0 : 1 : 0 : => 5;
0 : 0 : 0 : 1 : => 6;
1 : 0 : 1 : 0 : => 7; { multiple risk }
1 : 0 : 0 : 1 : => 7;
1 : 0 : 1 : 1 : => 7;
0 : 1 : 1 : 0 : => 8;
0 : 1 : 0 : 1 : => 9;
0 : 1 : 1 : 1 : => 10;
0 : 0 : 1 : 1 : => 11;
: : : : => default;
endbox;
if V312 = 6 then rowt805 = 1 endif;
box rowt805 => norisk;
1 => rowt805;
=> notappl;
endbox;
box rowt805 => unavoid;
2 => rowt805 - 1;
=> notappl;
endbox;
box rowt805 => singrisk;
3-6 => rowt805 - 2;
=> notappl;
endbox;
box rowt805 => multrisk;
7-11 => rowt805 - 6;
=> notappl;
endbox;
xtab( t805, rweight );
endif;
Re: high-risk fertility behaviour [message #3724 is a reply to message #3664] Mon, 02 February 2015 09:43 Go to previous messageGo to next message
lizzy_nnena@yahoo.com is currently offline  lizzy_nnena@yahoo.com
Messages: 4
Registered: January 2015
Location: Nigeria
Member
pls, i don't understand the package cspro, could you please re-send this in STATA format. thanks alot
Re: high-risk fertility behaviour [message #3725 is a reply to message #3724] Mon, 02 February 2015 11:39 Go to previous messageGo to next message
Liz-DHS
Messages: 1516
Registered: February 2013
Senior Member
Dear User,
At this time we do not have this code in STATA format for distribution. There is an entire section dedicated to this topic in The Guide to DHS Statistics. The document is bookmarked. The section on HIGH-RISK FERTILITY BEHAVIOR RISK RATIOS begin on page 98. You can download the Guide to DHS Statistics here:http:// dhsprogram.com/publications/publication-dhsg1-dhs-questionna ires-and-manuals.cfm
Quote:
HIGH-RISK FERTILITY BEHAVIOR RISK RATIOS
Statistics: Ratio of Children in Elevated Fertility Behavior Risk Categories to Children in
Non-Elevated Risk Category
Definition
A. Coverage:
1. Population base: Children born to all women.
2. Time period: Births in the five years preceding the survey.
B. Numerator: Proportion of dead children born in the five years preceding the survey by risk
category.
C. Denominator: Proportion dead of children in non-elevated risk category.
D. Elevated-behavior fertility risk categories:
1. Children born to mothers under age 18 years.
2. Children born to mothers 35 years and older.
3. Children of birth order 4 or higher.
4. Children born less than 24 months since a preceding birth.
E. Unavoidable elevated risk category--First birth order children born to mothers between ages 18
and 34 years.
F. Children not in any elevated risk category
1. Second- and third-birth-order children born to mothers between ages 18 and 34 years
2. The elevated risk categories are also combined into two-way and three-way combinations of
elevated risk.
Calculation
A. To calculate relative risk ratios by categories of elevated risk due to fertility behavior, first the
proportions dead for each category need to be calculated. For each proportion--
1. Numerator: Number of children born in the five years preceding the survey who died at
any age.
2. Denominator: Number of children born in the five years preceding the survey.
3. Proportion dead: Numerator divided by denominator.

B. Then the ratio of the proportions need to be calculated:
1. Risk ratio Numerator: Proportion dead among children in each risk category.
2. Risk ratio denominator: Proportion dead among children not in any elevated risk category
(see definition above).
3. Relative risk ratios: Risk category numerators divided by the non-elevated risk category
denominator.
Handling of Missing Values
None of the information needed to calculate relative risk ratios is allowed to have missing or unknown
data. Note that age at death is not used, only survival status at the time of the survey.
Notes and Considerations
To provide a more robust estimate of the elevated relative risk, proportions dead are used instead of
period mortality rates in the calculation of relative risk, since period mortality rates have higher sampling
errors. In DHS reports, risk ratios are not shown where the proportion dead is based on fewer than 25
births. Risk ratios where the proportion dead is based on 25 to 49 births are placed in parentheses to
indicate large variability due to sampling.
Assumptions
It is assumed that the number of births and death rates do not vary substantially by time period within the
preceding five years.
Changes over Time
Originally, the denominator for the risk ratio included the unavoidable risk category of first-order births to
mothers between 18 and 24 years of age.

Re: high-risk fertility behaviour [message #3748 is a reply to message #3640] Wed, 04 February 2015 20:12 Go to previous messageGo to next message
lizzy_nnena@yahoo.com is currently offline  lizzy_nnena@yahoo.com
Messages: 4
Registered: January 2015
Location: Nigeria
Member
thanks a lot for the assistance. Is it possible for me to have it in the SPSS format? Also, I want to know if you used the birth record or the women data or the kids recode.thanks in anticipation.
Re: high-risk fertility behaviour [message #3752 is a reply to message #3748] Thu, 05 February 2015 09:21 Go to previous messageGo to next message
Liz-DHS
Messages: 1516
Registered: February 2013
Senior Member
Dear User,
All our programs are done in CSPro. We currently do not have SPSS or STATA programs for distribution.
Thank you!

[Updated on: Thu, 05 February 2015 16:38]

Report message to a moderator

Re: high-risk fertility behaviour [message #3755 is a reply to message #3748] Thu, 05 February 2015 16:50 Go to previous messageGo to next message
Liz-DHS
Messages: 1516
Registered: February 2013
Senior Member
Dear User,
Here is some information regarding datasets:
Quote:
For children's level analysis, use the Children's Recode (KR). This dataset has one record for every child of eligible women, born in the last five years. It contains the information related to the child's pregnancy and postnatal care and immunization and health. The data for the mother of each of these children is included. This file is used to look at child health indicators such as immunization coverage, vitamin A supplementation, and recent occurrences of diarrhea, fever, and cough for young children and treatment of childhood diseases. The unit of analysis (case) in this file is the children of women born in the last 5 years (0-59 months).

For births' level analysis, use the All Children's Recode (BR). This dataset has one record for every child ever born of eligible women. Essentially, it is the full birth history of all women interviewed including its information on pregnancy and postnatal care as well as immunization and health for children born in the last 5 years. Data for the mother of each of these children is also included. This file can be used to calculate health indicators as well as fertility and mortality rates. The unit of analysis (case) in this file is the children ever born of eligible women.


If you still have additional questions, please post again.
Thank you!
Re: high-risk fertility behaviour [message #3757 is a reply to message #3755] Thu, 05 February 2015 21:10 Go to previous messageGo to next message
mmr-UMICH is currently offline  mmr-UMICH
Messages: 21
Registered: February 2015
Location: A2, MI
Member
Hello Liz-DHS:

I quote from 3rd sentence " ... to the child's pregnancy and postnatal care ...". is it okay? or we have to read it as "... to the child's prenatal and postnatal care ..." or " ... to the woman's pregnancy and postnatal care ...".

Is there any way to access your entire CSPro code for Bangladesh? so that we can translate parts of the code whatever require into other language such as SAS, SPSS, Stata, and R etc of our choice. Appreciate in advance. Two things come together as we also learn CSPro and we re-program correct CSPro code using correct variables etc; moreover this will save time of us and you. Thanking you.

Moshiur

[Updated on: Thu, 05 February 2015 21:26]

Report message to a moderator

Re: high-risk fertility behaviour [message #3759 is a reply to message #3757] Thu, 05 February 2015 23:37 Go to previous messageGo to next message
Liz-DHS
Messages: 1516
Registered: February 2013
Senior Member
Dear Moshiur,
I will refer your post to one of our experts for a response.
Thank you!
Re: high-risk fertility behaviour [message #3764 is a reply to message #3759] Fri, 06 February 2015 09:26 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 774
Registered: January 2013
Senior Member
Dear Moshiur,
In relation to your comment about "child's pregnancy and postnatal care", this isn't strictly accurate as you point out, but it is describing the child file, and the information about the pregnancy that resulted in the child. Hopefully it is still clear enough as it is.

Currently we do not distribute the CSPro code used in the surveys.
Re: high-risk fertility behaviour [message #3775 is a reply to message #3757] Mon, 09 February 2015 21:36 Go to previous messageGo to next message
lizzy_nnena@yahoo.com is currently offline  lizzy_nnena@yahoo.com
Messages: 4
Registered: January 2015
Location: Nigeria
Member
pls i urgently need a result of the already written CSpro-do file analyzed results on High-risk fertility behaviour since that is the only available codes for now. pls use Nigeria DHS 2013 data set. pls indicate either it is the NGIR6FL or NGkR6FL or NGBR6FL or either you are merging any of the data files together.


Alternatively, any one who has the STATA codes for high-risk fertility behaviour categories can also help forward it to me.

thank you.
Re: high-risk fertility behaviour [message #3780 is a reply to message #3640] Tue, 10 February 2015 11:38 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 774
Registered: January 2013
Senior Member
The results can be found on page 124 of the Nigeria DHS 2013 final report. The first two columns are based on NGKR61FL or NGBR61FL (you can use either file, just need to limit to births in the last 5 years). The last column is based on NGIR61FL.

[Updated on: Tue, 10 February 2015 11:39]

Report message to a moderator

Re: high-risk fertility behaviour/ high-risk births [message #9755 is a reply to message #3725] Fri, 13 May 2016 08:56 Go to previous messageGo to next message
adesoji is currently offline  adesoji
Messages: 9
Registered: May 2016
Location: Oye-Ekiti
Member
please i want to create high risk births variable from Nigeria DHS IR & BR recodes
i need your help am using stata 13 for the analysis.
thank you for willing to help me

Adesoji.
Re: high-risk fertility behaviour/ high-risk births [message #9757 is a reply to message #9755] Fri, 13 May 2016 09:54 Go to previous messageGo to next message
Liz-DHS
Messages: 1516
Registered: February 2013
Senior Member
Dear User,
The Guide to DHS Statistics http:// www.dhsprogram.com/publications/publication-dhsg1-dhs-questi onnaires-and-manuals.cfm has a section "HIGH-RISK FERTILITY BEHAVIOR RISK RATIOS" starting on Page 98. In addition you can find descriptions of the various datasets here:http://www.dhsprogram.com/data/Dataset-Types.cfm#CP_JUMP_6014 There is a whole section on our website called "Using Datasets for Analysis" here:http://www.dhsprogram.com/data/Using-Datasets-for-Analysis.cfm
For Stata tutorials: http://www.cpc.unc.edu/research/tools/data_analysis/statatutorial Thank you!
Defining categories of high risk fertility [message #9766 is a reply to message #9755] Mon, 16 May 2016 07:09 Go to previous messageGo to next message
adesoji is currently offline  adesoji
Messages: 9
Registered: May 2016
Location: Oye-Ekiti
Member


pls i urgently need a result of the already written stata-do file analyzed results on High-risk fertility behaviour since that is the only available codes for now. pls use Nigeria DHS 2013 data set. pls indicate either it is the NGIR6FL or NGkR6FL or NGBR6FL or either you are merging any of the data files together.


Alternatively, any one who has the STATA codes for high-risk fertility behaviour categories can also help forward it to me.

thank you.

[Updated on: Wed, 18 May 2016 20:49] by Moderator

Report message to a moderator

Defining categories of high risk fertility [message #9790 is a reply to message #9766] Wed, 18 May 2016 20:45 Go to previous messageGo to next message
Bridgette-DHS is currently offline  Bridgette-DHS
Messages: 2549
Registered: February 2013
Senior Member
Following is a response from Senior DHS Stata Specialist, Tom Pullum:


Here is a Stata program to define the high-risk categories. This will match the numbers in the first column of table 8.5 in the main report on the Nigeria 2013 DHS survey. It works with only the KR file.

* Stata program to identify the high risk birth categories in table 8.5 of the
* Nigeria 2013 DHS survey

set more off
use e:\DHS\DHS_data\KR_files\NGKR6AFL.dta, clear

* Check the total number of weighted cases
tab b5 [iweight=v005/1000000]

gen age_of_mother=int((b3-v011)/12)

* Adjustment for multiple births to give the same order as that of the first in multiples;
* b0 is sequence in the multiple birth IF part of a multiple birth; b0=0 if not a multiple birth;
* only shift the second (or later) birth within a multiple birth.

gen bord_adj=bord
*replace bord_adj=bord-1 if b0==2
*replace bord_adj=bord-2 if b0==3

replace bord_adj=bord-b0+1 if b0>1


* Single risk categories, initial definition

* Four basic criteria
gen young=0
gen old=0
gen soon=0
gen many=0

replace young=1 if age_of_mother<18
replace old=1 if age_of_mother>34
replace soon=1 if b11<24
replace many=1 if bord_adj>3

gen unavoidable_risk=0
replace unavoidable_risk=1 if bord_adj==1 & young==0 & old==0

* Construct the four single-risk categories
gen too_young=0
gen too_old=0
gen too_soon=0
gen too_many=0

replace too_young=1 if young==1 & old==0 & soon==0 & many==0
replace too_old =1 if young==0 & old==1 & soon==0 & many==0
replace too_soon =1 if young==0 & old==0 & soon==1 & many==0
replace too_many =1 if young==0 & old==0 & soon==0 & many==1

* Pooling of single risk categories
gen single_risk=0
replace single_risk=1 if too_young+too_old+too_soon+too_many>0

* Construct the five multiple-risk categories
gen too_young_too_soon=0
gen too_old_too_soon=0
gen too_old_too_many=0
gen too_old_too_soon_too_many=0
gen too_soon_too_many=0

replace too_young_too_soon =1 if young==1 & old==0 & soon==1 & many==0
replace too_old_too_soon =1 if young==0 & old==1 & soon==1 & many==0
replace too_old_too_many =1 if young==0 & old==1 & soon==0 & many==1
replace too_old_too_soon_too_many=1 if young==0 & old==1 & soon==1 & many==1
replace too_soon_too_many =1 if young==0 & old==0 & soon==1 & many==1

* Pooling of multiple risk categories
gen multiple_risk=0
replace multiple_risk=1 if too_young_too_soon+too_old_too_soon+too_old_too_many+too_old _too_soon_too_many+too_soon_too_many >0

* Pooling of any avoidable risk
gen any_avoidable_risk=0
replace any_avoidable_risk=1 if single_risk+multiple_risk>0

* Give results
format %6.3f too* single* multiple* any* un*
mean un too* single* multiple* any [iweight=v005/1000000]
Re: Defining categories of high risk fertility [message #9815 is a reply to message #9790] Wed, 25 May 2016 06:31 Go to previous messageGo to next message
adesoji is currently offline  adesoji
Messages: 9
Registered: May 2016
Location: Oye-Ekiti
Member
thanks Bridgette but i want stata code for generating high risk categories by merging individual recode IR and birth recode BR so that it will involve every births
Re: Defining categories of high risk fertility [message #9996 is a reply to message #9815] Tue, 14 June 2016 15:19 Go to previous messageGo to next message
Bridgette-DHS is currently offline  Bridgette-DHS
Messages: 2549
Registered: February 2013
Senior Member
Following is a response from Senior DHS Stata Specialist, Tom Pullum:

Here is a Stata routine to do what you want. It is for births in the past five years and therefore can be done completely with the KR file.

* Stata program to identify the high risk birth categories in table 8.5 of the
* Nigeria 2013 DHS survey

set more off
use e:\DHS\DHS_data\KR_files\NGKR6AFL.dta, clear

* Check the total number of weighted cases
tab b5 [iweight=v005/1000000]

gen age_of_mother=int((b3-v011)/12)

* Adjustment for multiple births to give the same order as that of the first in multiples;
* b0 is sequence in the multiple birth IF part of a multiple birth; b0=0 if not a multiple birth;
* only shift the second (or later) birth within a multiple birth.

gen bord_adj=bord
*replace bord_adj=bord-1 if b0==2
*replace bord_adj=bord-2 if b0==3

replace bord_adj=bord-b0+1 if b0>1


* Single risk categories, initial definition

* Four basic criteria
gen young=0
gen old=0
gen soon=0
gen many=0

replace young=1 if age_of_mother<18
replace old=1 if age_of_mother>34
replace soon=1 if b11<24
replace many=1 if bord_adj>3

gen unavoidable_risk=0
replace unavoidable_risk=1 if bord_adj==1 & young==0 & old==0

* Construct the four single-risk categories
gen too_young=0
gen too_old=0
gen too_soon=0
gen too_many=0

replace too_young=1 if young==1 & old==0 & soon==0 & many==0
replace too_old =1 if young==0 & old==1 & soon==0 & many==0
replace too_soon =1 if young==0 & old==0 & soon==1 & many==0
replace too_many =1 if young==0 & old==0 & soon==0 & many==1

* Pooling of single risk categories
gen single_risk=0
replace single_risk=1 if too_young+too_old+too_soon+too_many>0

* Construct the five multiple-risk categories
gen too_young_too_soon=0
gen too_old_too_soon=0
gen too_old_too_many=0
gen too_old_too_soon_too_many=0
gen too_soon_too_many=0

replace too_young_too_soon =1 if young==1 & old==0 & soon==1 & many==0
replace too_old_too_soon =1 if young==0 & old==1 & soon==1 & many==0
replace too_old_too_many =1 if young==0 & old==1 & soon==0 & many==1
replace too_old_too_soon_too_many=1 if young==0 & old==1 & soon==1 & many==1
replace too_soon_too_many =1 if young==0 & old==0 & soon==1 & many==1

* Pooling of multiple risk categories
gen multiple_risk=0
replace multiple_risk=1 if too_young_too_soon+too_old_too_soon+too_old_too_many+too_old _too_soon_too_many+too_soon_too_many >0

* Pooling of any avoidable risk
gen any_avoidable_risk=0
replace any_avoidable_risk=1 if single_risk+multiple_risk>0

* Give results
format %6.3f too* single* multiple* any* un*
mean un* too* single* multiple* any [iweight=v005/1000000]

Re: Defining categories of high risk fertility [message #10568 is a reply to message #9790] Tue, 09 August 2016 10:27 Go to previous messageGo to next message
adesoji is currently offline  adesoji
Messages: 9
Registered: May 2016
Location: Oye-Ekiti
Member
hello bridgette, pls i want to get how to pool the code into no risk, unavoidable risk and avoidable risk. i will really appreciate your timely response
Re: Defining categories of high risk fertility [message #10581 is a reply to message #10568] Fri, 12 August 2016 13:02 Go to previous messageGo to next message
Liz-DHS
Messages: 1516
Registered: February 2013
Senior Member
Response from Dr. Tom Pullum:
It appears that you are asking for the addition of a "no risk" variable. You only need to replace the last three lines of what I sent earlier with the following:
* No risk is the residual
gen no_risk=0
replace no_risk=1 if unavoidable_risk==0 & any_avoidable_risk==0

* Give results
format %6.3f too* single* multiple* any* un* no*
mean no un too* single* multiple* any [iweight=v005/1000000]


Re: Defining categories of high risk fertility [message #10796 is a reply to message #10581] Thu, 15 September 2016 06:42 Go to previous messageGo to next message
adesoji is currently offline  adesoji
Messages: 9
Registered: May 2016
Location: Oye-Ekiti
Member
please i still need to get how to generate the "no risk" "unavoidable risk" and "avoidable risk" categories. please it is urgent thank you
Re: Defining categories of high risk fertility [message #10797 is a reply to message #10581] Thu, 15 September 2016 07:42 Go to previous messageGo to next message
adesoji is currently offline  adesoji
Messages: 9
Registered: May 2016
Location: Oye-Ekiti
Member
thank you Tom pullum please i need the stata code that will categorize high risk births into no risk, unavoidable risk avoidable risk and compress all the single risk, multiple risks into no risk, unavoidable risk avoidable risk. please it is urgent
Re: Defining categories of high risk fertility [message #10798 is a reply to message #10797] Thu, 15 September 2016 09:32 Go to previous messageGo to next message
Liz-DHS
Messages: 1516
Registered: February 2013
Senior Member
Dear User,
Please see the attached file from Senior Technical Specialist, Dr. Tom Pullum. Please also review other posts in this thread. Thank you!
Re: Defining categories of high risk fertility [message #10814 is a reply to message #10798] Tue, 20 September 2016 06:33 Go to previous messageGo to next message
adesoji is currently offline  adesoji
Messages: 9
Registered: May 2016
Location: Oye-Ekiti
Member
thanks your message well delivered but i still have challenges to compressing the high risk fertility to no risk, avoidable risk and unavoidable risk. please i need headway. thank you
Re: Defining categories of high risk fertility [message #14787 is a reply to message #10814] Sun, 06 May 2018 05:11 Go to previous message
Hassen
Messages: 121
Registered: April 2018
Location: Ethiopia,Africa
Senior Member
Thanks all!!!

Hassen Ali(Chief Public Health Professional Specialist)
Previous Topic: Ideal fertility sons and daughters v613 v627 v628
Next Topic: Colombia 2010- Revising unmet need for contraception
Goto Forum:
  


Current Time: Mon Aug 15 11:37:05 Coordinated Universal Time 2022