* Calculate still births in the last 5 years
gen stillbirths = 0
gen births = 0
gen nlbirths = 0

* Set length of calendar to use
gen callen = v018 + 59
* If calendar is aligned right (as in original dataset), use the following:
gen beg = v018
gen end = callen
* If calendar is aligned left (as it appears to be), use the following:
*gen beg = 1
*gen end = 60

* Loop through calendar summing births, non-live pregnancies and stillbirths
forvalues i = 1/80 {
*   Restrict to 60 months preceding survey
    replace births = births+1 if `i' >= beg & `i' <= end & substr(vcal_1,`i',1) == "B"
    replace nlbirths = nlbirths+1 if `i' >= beg & `i' <= end & substr(vcal_1,`i',1) == "T"
    replace stillbirths = stillbirths+1 if `i' >= beg & `i' <= end & substr(vcal_1,`i',7) == "TPPPPPP" 
} 

* total pregnancies in last 5 years
gen totpreg5 = births+nlbirths
* total pregnancies of 7+ months in last 5 years (all live births, plus the stillbirths)
gen totpreg7m = births+stillbirths

* Create weight variable.
gen wgt = v005/1000000

* Set up svyset parameters for complex samples.
svyset v021 [pweight=wgt], strata(v023)

* Produce number of stillbirths
svy: tab stillbirths, cell count

* Compute additional twins in the last 5 years.  One is counted in totpreg7m already, this just counts the 2nd and 3rd, etc.
* First rename birth history variables to facilitate forvalues loop
rename b*_0* b*_* 
gen twins = 0
* loop through the birth history counting the additional twins in the last 5 years
forvalues i = 1/20 {
  * only count second, third, etc. of twins if born in the last 5 years
  replace twins = twins+1 if b3_`i' != . & b3_`i' >= v008-59 & b0_`i' >= 2
}
replace totpreg7m = totpreg7m+twins
tab totpreg7m [iw=wgt]