The DHS Program User Forum
Discussions regarding The DHS Program data and results
Home » Topics » Domestic Violence » DHS Malawi - domestic violence among women 15-19
DHS Malawi - domestic violence among women 15-19 [message #2019] Mon, 14 April 2014 16:39 Go to next message
malayaka is currently offline  malayaka
Messages: 18
Registered: March 2014
Member
Hello,

I am using STATA 11.2 and having difficulty generating the DHS Malawi 2010 domestic violence figures for:

1) Women ages 15-19 who ever experienced sexual violence (%)
2) Women ages 15-19 who ever experienced physical violence since age 15 (%)

Below are the STATA codes I used for "sexual violence (please see attached pdf)." I then plan to crosstab by wealth, residence (urban/rural), and region. I am also at a loss at what to do for "ever experienced physical violence since age 15" -- which variables do I use (or need to combine - similar to "sexual violence") to get "ever experienced physical violence?"

Can someone please help with the correct code to use?

STATA Code:

use v005 v012 v013 v021 v022 v023 v024 v025 v044 v101 v102 v106 v149 v155
v190 v201 v212 v313 v384a v384b v384c v463z v501 v502 v511 v536 v613 v714
v717 v731 v739 v763a d005 d108 d124 d125 using "/Users/Desktop/MWIR61FL.DTA


******************************
* DOMESTIC VIOLENCE (SEXUAL)
******************************
generate dweight = d005/1000000
svyset [iweight=dweight], psu(v021) strata(v023)

* Generate new variable (anysv = any sexual violence)
generate anysv=.
replace anysv=0 if d108==0|d124==0|d125==0
replace anysv=1 if d108==1|d124==1|d125==1

* Age group (15-19 yrs) and experience of sexual violence
svy: tabulate v013 anysv, row

* Age group (15-19 yrs) and experience of sexual violence
svy: tabulate anysv v190 if v013==1

* By age group (15-19 yrs), experience of sexual violence and place of
residence (urban/rural)
svy: tabulate anysv v102 if v013==1

* By age group (15-19 yrs), experience of sexual violence and region
(North, Central, South)
svy: tabulate anysv v101 if v013==1

Thank you in advance.
Re: DHS Malawi - domestic violence among women 15-19 [message #2021 is a reply to message #2019] Mon, 14 April 2014 18:07 Go to previous messageGo to next message
Reduced-For(u)m
Messages: 292
Registered: March 2013
Senior Member


One quick thing - I think you should be using the "subpop" command here instead of the "if".

http://www.stata.com/manuals13/svysubpopulationestimation.pd f

***
Subpopulation estimation involves computing point and variance estimates for part of the population.
This is not the same as restricting the estimation sample to the collection of observations within
the subpopulation because variance estimation for survey data measures sample-to-sample variability,
assuming that the same survey design is used to collect the data
***

So maybe try:
svy, subpop(v013) anysv v101

I'd be interested to know if that did the trick.
Re: DHS Malawi - domestic violence among women 15-19 [message #2022 is a reply to message #2021] Mon, 14 April 2014 20:21 Go to previous messageGo to next message
user-rhs is currently offline  user-rhs
Messages: 132
Registered: December 2013
Senior Member
If you use subpop, the subpop variable has to be an indicator variable (0/1). Otherwise, Stata treats everyone with value !=0 of that variable as ==1.

From the help file for svy:

subpop(subpop) specifies that estimates be computed for the single subpopulation identified by subpop, which is

[varname] [if]

Thus the subpopulation is defined by the observations for which varname!=0 that also meet the if conditions. Typically, varname=1 defines the subpopulation, and varname=0 indicates observations not belonging to the subpopulation. For observations whose subpopulation status is uncertain, varname should be set to a missing value; such observations are dropped from the estimation sample.


[Updated on: Mon, 14 April 2014 20:22]

Report message to a moderator

Re: DHS Malawi - domestic violence among women 15-19 [message #2023 is a reply to message #2022] Mon, 14 April 2014 20:24 Go to previous messageGo to next message
user-rhs is currently offline  user-rhs
Messages: 132
Registered: December 2013
Senior Member
A bit dated, but still useful:

Stata FAQ
How can I analyze a subpopulation of my survey data in Stata?
http://www.ats.ucla.edu/stat/stata/faq/svy_stata_subpop.htm
Re: DHS Malawi - domestic violence among women 15-19 [message #2111 is a reply to message #2019] Tue, 29 April 2014 18:56 Go to previous message
Liz-DHS
Messages: 1516
Registered: February 2013
Senior Member
Dear User,
Here is a response from one of our experts Kerry MacQuerrie (also please see her attachment)
**Tips for matching DV tables - Malawi 2010

*Open file:
cd "C:\Users\kerry.macquarrie\Documents\HIV-DV - local\PAA2014\DV Forms\Data\" /*specify your directory location*/
use "MWIR61FL.DTA", clear

*Weight data:
g wt=d005/1000000 /*This is the domestic violence weight, not the women's weight*/

*If adjusting for sampling design:
g strata=v023
svyset [pw=wt], psu(v021) strata(strata) singleunit(center)

*Table 18.1 Experience of physical violence
/*"Ever experienced physical violence" draws from multiple variables:
Set 1: d105a-d105g & d105j. Women who answer 'yes' to these items are reporting her current/most recent ///
husband/partner perpetuated this act of physical violence. They are then asked how frequently in ///
the last 12 months. Take response codes 1-4 to any of these variables. ///
Set 2: d115y. Women who answer 'no' this variable are reporting that they have ever been physically hurt ///
by someone other than their spouse since age 15. (It's reverse coded.) Take response code 0. ///
Set 3: d118y. Women who answer 'no' to this variable are reporting that they have been physically hurt ///
during a pregnancy. (It's also reverse coded.) Take response code 0. */

lab def yesno 0 "no" 1 "yes"

*create composite physical violence variable
g pvever=.
replace pvever=0 if v044==1
replace pvever=1 if inrange(d105a,1,4) | inrange(d105b,1,4) | inrange(d105c,1,4) | inrange(d105d,1,4) | ///
inrange(d105e,1,4) | inrange(d105f,1,4) | inrange(d105g,1,4) | inrange(d105j,1,4)
replace pvever=1 if d115y==0 | d118y==0
lab var pvever "Ever experienced physical violence"
lab val pvever yesno

*Check total
tab pvever [iw=wt] /*the results match the total reported in Table 18.1*/
*Restrict to 15-19 year olds
tab pvever if v013==1 [iw=wt]

*Table 18.4 Experience of sexual violence
/*"Ever experienced sexual violence" also draws from multiple variables:
Set 1: d105h and d105i captures sexual violence by current/most recent husband/partner ///
Take response codes 1-4.
Set 2: d123 captures if first sexual intercourse was forced. Take response code 2. ///
Set 3: d124 and d125 capture if anyone other than spouse forced sex in last 12 months or forced sex acts. ///
Take response code 1 to either. */

*create composite sexual violence variable
g svever=.
replace svever=0 if v044==1
replace svever=1 if inrange(d105h,1,4) | inrange(d105i,1,4)
replace svever=1 if d123==2
replace svever=1 if d124==1 | d125==1
lab var svever "Ever experienced sexual violence"
lab val svever yesno

*Check total
tab svever [iw=wt] /*matches total reported in Table 18.4*/
*Restrict to 15-19 year olds
tab svever if v013==1 [iw=wt]

*If you want to crosstab by background characteristics, check the DHS recode manual for a list of variables.
*Code would take the following form (I use age, v013, as an example):
tab v013 svever [iw=wt], row




Previous Topic: Calculation of prevalence using STATA command
Next Topic: Missing cases in Severe Burn question- NFHS India
Goto Forum:
  


Current Time: Sun Jun 20 17:42:57 Coordinated Universal Time 2021