The DHS Program User Forum
Discussions regarding The DHS Program data and results
Home » Topics » Fertility » Informed Choice (Method Information Index)
Informed Choice (Method Information Index) [message #24560] Wed, 01 June 2022 03:10 Go to next message
Sourav_ is currently offline  Sourav_
Messages: 20
Registered: January 2021
Member
I want to replicate Table 5.12 Informed choice of NFHS-5 of India. I have used the variables v3a02-v3a06 but unable to do it. Please help me out by telling how to do it or by giving STATA code. Thank you.

[Updated on: Wed, 01 June 2022 03:11]

Report message to a moderator

Re: Informed Choice (Method Information Index) [message #24584 is a reply to message #24560] Fri, 03 June 2022 09:58 Go to previous messageGo to next message
Janet-DHS is currently offline  Janet-DHS
Messages: 658
Registered: April 2022
Senior Member
Following is a response from DHS Research & Data Analysis Director, Tom Pullum:

The Stata code for the indicators in Table 5.12 is given on our GitHub site (https://github.com/DHSProgram/DHS-Indicators-Stata). The generic chapter for family planning is chapter 7. These lines are extracted from "FP_USE.do".


//Informed of side effects
gen fp_info_sideff = 0 if inlist(v312,1,2,3,6,11) & (v008-v317<60)
replace fp_info_sideff = 1 if (v3a02==1 | v3a03==1) & inlist(v312,1,2,3,6,11) & (v008-v317<60)
label var fp_info_sideff "Informed about side effects or problems among female sterilization, pill, IUD, injectables, and implant users"

//Informed of what to do
gen fp_info_what_to_do = 0 if inlist(v312,1,2,3,6,11) & (v008-v317<60)
replace fp_info_what_to_do = 1 if v3a04==1 & inlist(v312,1,2,3,6,11) & (v008-v317<60)
label var fp_info_what_to_do "Informed of what to do if experienced side effects among female sterilization, pill, IUD, injectables, and implant users"

//Informed of other methods to use
gen fp_info_other_meth = 0 if inlist(v312,1,2,3,6,11) & (v008-v317<60)
replace fp_info_other_meth = 1 if (v3a05==1 | v3a06==1) & inlist(v312,1,2,3,6,11) & (v008-v317<60)
label var fp_info_other_meth "Informed of other methods by health or FP worker among female sterilization, pill, IUD, injectables, and implant users"

//Informed of all three (method information index)
gen fp_info_all = 0 if inlist(v312,1,2,3,6,11) & (v008-v317<60)
replace fp_info_all = 1 if ((v3a02==1 | v3a03==1) & v3a04==1 & (v3a05==1 | v3a06==1)) & inlist(v312,1,2,3,6,11) & (v008-v317<60)
label var fp_info_all "Informed of all three (method information index) among female sterilization, pill, IUD, injectables, and implant users"
Re: Informed Choice (Method Information Index) [message #24588 is a reply to message #24584] Sat, 04 June 2022 03:38 Go to previous messageGo to next message
Sourav_ is currently offline  Sourav_
Messages: 20
Registered: January 2021
Member
But using this code also, the table 5.12 is not exactly matching. total number of women is coming as 66521 whereas in table that is 65839. Please help.
Re: Informed Choice (Method Information Index) [message #24601 is a reply to message #24588] Mon, 06 June 2022 14:31 Go to previous message
Shireen-DHS is currently offline  Shireen-DHS
Messages: 140
Registered: August 2020
Location: USA
Senior Member
Dear Janet,

The code provided is our standard code but sometimes this can sometimes differ slightly for each country/survey. You always need to check the table notes in the final report. In Table 5.12 you can know which women were selected from the note below the table. According to the note we should only select for women using the female sterilization, pill, or IUD and remove women who received their method from friends/relative or husband. To adjust the code you need to change the categories selected for v312 and also add a line to replace missing if v326 (source of method) is 32 or 33. See below. You can do the same for the remaining indicators.

I checked this and it matches the final report.

//Informed of side effects
gen fp_info_sideff = 0 if inlist(v312,1,2,6) & (v008-v317<60)
replace fp_info_sideff = 1 if (v3a02==1 | v3a03==1) & inlist(v312,1,2,6) & (v008-v317<60)
replace fp_info_sideff=. if v326==32 | v326==33
label var fp_info_sideff "Informed about side effects or problems among female sterilization, pill, IUD, injectables, and implant users"

gen wt=v005/1000000
ta fp_info_sideff [iw=wt]


Thank you.
Best,
Shireen Assaf
The DHS Program
Previous Topic: Estimation of Age specific fertility rates for 3 years preceding survey
Next Topic: R code for TFR estimation -SAE perspective
Goto Forum:
  


Current Time: Thu Mar 28 13:00:14 Coordinated Universal Time 2024