The DHS Program User Forum
Discussions regarding The DHS Program data and results
Home » Countries » Nepal » Replicating table 8.4- Nepal DHS 2011
Replicating table 8.4- Nepal DHS 2011 [message #8598] Thu, 19 November 2015 21:05 Go to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Hi,

I was trying to replicate table 8.4 and tried both IR and BR data sets but still can not calculate total pregnancy 7 plus months (which is 5444). Can anyone help me sorting this out?

Thanks

Sam
Re: Replicating table 8.4- Nepal DHS 2011 [message #8605 is a reply to message #8598] Fri, 20 November 2015 16:11 Go to previous messageGo to next message
Liz-DHS
Messages: 1516
Registered: February 2013
Senior Member
Dear User,
Here is a response from Senior data processing expert, Mr. Albert Themme:
Quote:
Column 4 in table 8.4 (pregnancies of 7+ months) is based on all births in the birth history (all births are considered to have a duration of 7+ months) and all stillbirths following a pregnancy of 7 months or more based on the calendar. The relevant parts of the syntax are marked yellow and the code is CSPro.

Re: Replicating table 8.4- Nepal DHS 2011 [message #8607 is a reply to message #8605] Fri, 20 November 2015 16:37 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Thank you so much for the information. Since i am using STATA, is there any help i can get to calculate number of pregnancies 7 plus months using stata?

Many thanks
Re: Replicating table 8.4- Nepal DHS 2011 [message #8608 is a reply to message #8607] Fri, 20 November 2015 16:51 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 787
Registered: January 2013
Senior Member
See message 3648 and also message 3727 further down.
Re: Replicating table 8.4- Nepal DHS 2011 [message #8614 is a reply to message #8605] Fri, 20 November 2015 22:16 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Hi, can you please help me how to merge Nepal DHS- BR and IR data sets?
Re: Replicating table 8.4- Nepal DHS 2011 [message #8616 is a reply to message #8614] Sat, 21 November 2015 13:56 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 787
Registered: January 2013
Senior Member
Why do you want to merge BR and IR files? The BR files already contain almost all of the women's data in the IR file.
Re: Replicating table 8.4- Nepal DHS 2011 [message #8618 is a reply to message #8616] Sat, 21 November 2015 16:54 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
I was trying to merge because i thought the variable vcal(calendar)was needed to calculate total number of still births which is in IR data set only.

If i reshape IR data set, the number of still births will be more than double than reported.

Can i calculate still births using BR data set? if so can you please assist me how to do that using STATA?

Many thanks

S
Re: Replicating table 8.4- Nepal DHS 2011 [message #8621 is a reply to message #8618] Sun, 22 November 2015 17:43 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 787
Registered: January 2013
Senior Member
vcal is in the IR dataset. You need to use just the IR dataset to calculate the number of stillbirths as in the thread I linked too in message 3648. There is no need to merge the datasets to calculate the number of stillbirths, nor to reshape the dataset - just use the code I gave.

You cannot calculate the stillbirths using the BR file - its unit of analysis is live births and it does not contain the stillbirths.

The Nepal surveys, in contrast to most of the other DHS surveys, does include a pregnancy history. You can reshape the pregnancy history (see idx92_01 to s220ab_20) in the IR file, and should be able to also calculate the number of stillbirths from those data, although I can't say that I have tried.
Re: Replicating table 8.4- Nepal DHS 2011 [message #8623 is a reply to message #8621] Sun, 22 November 2015 18:32 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Thank you so much for the information.

Re: Replicating table 8.4- Nepal DHS 2011 [message #8624 is a reply to message #8623] Sun, 22 November 2015 20:08 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Hi,

I tried the coding you gave and the total number of still births(53) is absolutely matched with the Nepal DHS report 2011. But the total number of pregnancies 7 plus months (all live births and stillbirths) five years preceeding the survey is very low- 4140. The report says 5444.

Can you please help me how to calculate total number of still births and total number of pregnancies 7 plus months five year preceding the survey using IR data file?

I am trying to match total number of stillbirths (53) and total pregnancies 7 plus months (5444) using same IR data file.

Thank you so much

S
Re: Replicating table 8.4- Nepal DHS 2011 [message #8625 is a reply to message #8624] Sun, 22 November 2015 21:06 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 787
Registered: January 2013
Senior Member
I don't see where you get 4140 from, but I think you are miscalculating. If you use the code in message 3648 plus the code in message 3727, you should get the following result:
----------------------------------
totpreg7m |      count  proportion
----------+-----------------------
        0 |       8507       .6712
        1 |       3015       .2379       1 * 3015  = 3015
        2 |       1036       .0818       2 * 1036  = 2072
        3 |      111.6       .0088       3 * 111.6 =  334.8
        4 |      1.093     8.6e-05       4 * 1.093 =    4.372
        5 |      3.547     2.8e-04       5 * 3.547 =   17.375
          | 
    Total |    1.3e+04           1           Sum   = 5443.907     
----------------------------------
totpreg7m contains the total number of pregnancies of 7 months or more (including twins), and when you multiply this out with the number of cases you get 5444 pregnancies of 7 months or more in total.

[Updated on: Sun, 22 November 2015 21:06]

Report message to a moderator

Re: Replicating table 8.4- Nepal DHS 2011 [message #8626 is a reply to message #8625] Mon, 23 November 2015 04:38 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Thank you so much!
It is so helpful.
Re: Replicating table 8.4- Nepal DHS 2011 [message #8638 is a reply to message #8626] Mon, 23 November 2015 18:23 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Hi,

Can you please assist me how to keep only those observations (which is all pregnancies 7 months or more)that should come up 5444?

If i do the following:
keep if totpreg7m>=1 & totpreg7m<=5

I will end up limiting the observations into 4140 only instead of 5444.

I want to limit my observations into 5444 (This is the number reported in 2011 Nepal DHS report)

Thank you so much for the help.

S
Re: Replicating table 8.4- Nepal DHS 2011 [message #8639 is a reply to message #8598] Mon, 23 November 2015 18:45 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 787
Registered: January 2013
Senior Member
It is not really a matter of limiting the observations. If you want 5444 cases, then these are 5444 pregnancies, and that is a different unit of analysis than women (which is what you have in the IR file). Each woman can have multiple pregnancies that are 7 months or more, so you need to convert your file to a file of pregnancies. I'm not sure what you want to do with that file, though. Are there characteristics of each pregnancy that you want to use? What do you ultimately want to do with this file?

[Updated on: Mon, 23 November 2015 18:46]

Report message to a moderator

Re: Replicating table 8.4- Nepal DHS 2011 [message #8640 is a reply to message #8639] Mon, 23 November 2015 19:02 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
I want to create a variable XX where
1= total stillbirths(53)
2= total pregnancies 7 months or more(5444)

Thanks heaps

S
Re: Replicating table 8.4- Nepal DHS 2011 [message #8641 is a reply to message #8640] Mon, 23 November 2015 19:10 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 787
Registered: January 2013
Senior Member
I'm not sure what you are intending with this, but try:
collapse (sum) stillbirths totpreg7m [iw=wgt]
and then browse to see the data which will look like:
stillbirths	totpreg7m
53.03819	5444.41
Re: Replicating table 8.4- Nepal DHS 2011 [message #8642 is a reply to message #8641] Mon, 23 November 2015 19:40 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member

Hi,

I was trying to see the risk factors of stillbirths in all pregnancies lasting seven or more months.

Thats why i was trying to limit the observations into 5444.

when i do- collapse (sum) stillbirths totpreg7m [iw=wgt], the freq. will be 1.

May be as you said, i need to convert this into a file of pregnancy. Can you please advise me how to convert IR file into pregnancy file?

Thank you so much

S











Re: Replicating table 8.4- Nepal DHS 2011 [message #8643 is a reply to message #8642] Tue, 24 November 2015 03:58 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Hi

I was also trying to pool data from Nepal DHS 2001, 2006 and 2011 to calculate Stillbirths with the code you gave earlier. But there are missing information including calendar and v018 in 2001 IR data file.

In this situation, how am i supposed to pool three Nepal DHS data and calculate stillbirths?

Many thanks

S
Re: Replicating table 8.4- Nepal DHS 2011 [message #8646 is a reply to message #8642] Tue, 24 November 2015 19:19 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 787
Registered: January 2013
Senior Member
The following code reshapes the IR dataset into pregnancies and keeps pregnancies of 7 months duration.

* Using Nepal DHS 2011
use "C:\Data\DHS_Stata\NPIR60FL.DTA" , clear
gen pregs = 0

forvalues i = 1/80 {
  gen cmc`i' = v017 + 80 - `i'
  gen event`i' = substr(vcal_1, `i', 1)
  gen type`i' = .
  replace type`i' = 1 if substr(vcal_1,`i',1) == "B"
  replace type`i' = 3 if substr(vcal_1,`i',1) == "T"
  replace type`i' = 2 if substr(vcal_1,`i',7) == "TPPPPPP" 
  replace pregs = pregs+1 if (substr(vcal_1,`i',1) == "B" | substr(vcal_1,`i',1) == "T")
}
* Drop cases with no pregnancies
drop if pregs == 0

* Decide what variables you want to keep first before the reshape, modify this list as you need to add extra variables.
keep caseid v001 v002 v003 v005 v008 v011 v013 v017 v018 v019 v021 v022 v023 cmc* event* type* 

* The reshape is really really really slow if you don't select variables and cases first, and will most likely fail otherwise.
reshape long cmc event type, i(caseid) j(ix)

lab def type 1 "Birth" 2 "Stillbirth" 3 "Miscarriage/abortion"
lab val type type
lab var type "Type of pregnancy"
lab var cmc "Century month code of event"
lab var event "Calendar event code"

* Set length of calendar to use
gen callen = v018 + 59
* If calendar is aligned right (as in original dataset), use the following:
gen beg = v018
gen end = callen
* If calendar is aligned left (as it is in some datasets), use the following:
*gen beg = 1
*gen end = 60

* Include only the five year period
keep if ix >= beg & ix <= end

* check the pregnancy types 
tab type [iw=v005/1000000]

* Note that this will not match the 5444 pregnancies of 7+ months as that includes twins.
* This file excludes twins, but i believe that is what you really need.

* keep only births and stillbirths
keep if type == 1 | type == 2

Note that this excludes twins so it does not match the 5444, but I think this is actually more useful for your needs.
Re: Replicating table 8.4- Nepal DHS 2011 [message #8648 is a reply to message #8646] Tue, 24 November 2015 19:38 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 787
Registered: January 2013
Senior Member
If you want the twins, you can add the following code to the end:
* sort by case identifiers and century month code of pregnancy end
sort v001 v002 v003 cmc
* save this file
save "pregnancies of 7 months or more.dta"

* Open birth history
use "C:\Data\DHS_Stata\NPBR60FL.DTA", clear
* Sort according to ID and CMC of birth
clonevar cmc = b3
sort v001 v002 v003 cmc
save "births.dta"

* Reopen the pregnancies files and merge in the twins
use "pregnancies of 7 months or more.dta",clear
merge 1:m v001 v002 v003 cmc using "births.dta", keep(master match) keepusing(b*)

tab type [iw=v005/1000000]

This will give you the 5444 cases of pregnancies of 7 months or more, including counting twins separately.
Re: Replicating table 8.4- Nepal DHS 2011 [message #8649 is a reply to message #8648] Tue, 24 November 2015 19:42 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 787
Registered: January 2013
Senior Member
Pramesh, producing something similar for the 2001 survey without the calendar is a completely different process. I'll take a look at what is possible, but I may not be able to respond immediately.
Re: Replicating table 8.4- Nepal DHS 2011 [message #8650 is a reply to message #8646] Tue, 24 November 2015 19:43 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
This is so useful.

Thanks Trevor for the great effort.

It would be great to see your comment on my previous message of obtaining total pooled stillbirths using Nepal DHS 2001, 2006 and 2011. I can not find variables such as calendar(vcal) and v018 in 2001 IR data file.

Once again, thanks heaps.
Re: Replicating table 8.4- Nepal DHS 2011 [message #8651 is a reply to message #8649] Tue, 24 November 2015 19:44 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Thats ok,

Please take your time.

Cheers!
Re: Replicating table 8.4- Nepal DHS 2011 [message #8653 is a reply to message #8651] Tue, 24 November 2015 20:28 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 787
Registered: January 2013
Senior Member
I realized that I could get you on the right track fairly easily. Here is code to reshape Nepal 2001 pregnancy history data into a file of pregnancies
* Open the Nepal 2001 dataset
use "C:\Data\DHS_Stata\NPIR41FL.DTA", clear

* keep just a set of useful variables.  If you keep too many this process gets really really slow and may fail due to memory
keep caseid v001 v002 v003 v005 v008 v011 v013 v017 v018 v019 v021 v022 v023 ///
  idx92_* bord9_* b0_92_* b1_92_* b2_92_* b3_92_* b4_92_* b5_92_* b6_92_* b7_92_* ///
  b8_92_* b9_92_* b10_9_* b11_9_* b12_9_* b13_9_* b16_9_* s216_* s217_* s227_* s228_* s229_*

* rename variables for reshaping
rename *_0* *_*
  
* reshape the pregnancy history into a filee of pregnancies
reshape long idx92_ bord9_ b0_92_ b1_92_ b2_92_ b3_92_ b4_92_ b5_92_ b6_92_ b7_92_ ///
  b8_92_ b9_92_ b10_9_ b11_9_ b12_9_ b13_9_ b16_9_ s216_ s217_ s227_ s228_ s229_, i(caseid) j(i)

* drop empty entries that contain no data
drop if idx92_==.  

* rename variables to easier names
rename *_92_ *  
rename *_9_ *  
rename idx92_ idx
rename bord9_ bord
rename  s*_ s*
* rename the b variables to p variables as these are for pregnancies and not for births, 
* just to avoid confusion with the birth history variables.
rename b* p*

* Restrict to all pregnancies in the last 5 years
keep if p3 > v008-60

* Check the results of the pregnancies
tab s227 s216 [iw=v005/1000000],m

* There are a couple of cases that seem inconsistent here.  Here is a suggestion for editing them:
* This case looks to have died on the first day rather than being a still birth
replace s216=1 if s227==. & s216==2
* This case looks to have been misrecorded as born died rather than lost before full term
replace s216=3 if s227==3 & s216==2

* To keep just the pregnancies of 7+ months duration, use the following:
keep if s227 == . | s227 >= 7
* I would then recode s216 into "born alive" and "stillbirth" (all of the others).
recode s216 (1=1 "Live birth")(2/3=2 "Stillbirth"), gen(type)

You can then rename and recode any variables you need to match the other files.

[Updated on: Wed, 25 November 2015 00:54]

Report message to a moderator

Re: Replicating table 8.4- Nepal DHS 2011 [message #8654 is a reply to message #8653] Tue, 24 November 2015 23:49 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Hi,

I used the coding you gave and the number of stillbirths was nearly same as 2001 report but the total pregnancies 7 months or more looks pretty high. The 2001 Nepal DHS report says the total preg 7 plus months is 7134.

RECODE of
s216 Freq. Percent Cum.

Live birth 7,095.8901 97.83 97.83
Stillbirth 157.600695 2.17 100.00

Total 7,253.4908 100.00


Any advice to sort this issue?

Thanks
Re: Replicating table 8.4- Nepal DHS 2011 [message #8655 is a reply to message #8653] Wed, 25 November 2015 00:42 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member

And calculating stillbirths from 2001 IR file without converting into pregnancy file would be also the great help from you.

Cheers
Re: Replicating table 8.4- Nepal DHS 2011 [message #8656 is a reply to message #8655] Wed, 25 November 2015 00:58 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 787
Registered: January 2013
Senior Member
I made one mistake in the codes above for 2001. the line:
keep if p3 >= v008-60

should be
keep if p3 > v008-60

then the results match the report.
Re: Replicating table 8.4- Nepal DHS 2011 [message #8657 is a reply to message #8656] Wed, 25 November 2015 01:15 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 787
Registered: January 2013
Senior Member
And here is the code to calculate the total births, stillbirths and pregnancies of 7 or more months directly from the IR file without reshaping:
* Open the Nepal 2001 dataset
use "C:\Data\DHS_Stata\NPIR41FL.DTA", clear

* rename to facilitate looping
ren b?_92_0* b?_92_* 
ren b??_9_0* b??_9_* 
ren s2*_0* s2*_*

* Calculate still births in the last 5 years
gen stillbirths = 0
gen births = 0

forvalues i = 1/20 {
* 	Data fixes
* 	This case looks to have died on the first day rather than being a still birth
	replace s216_`i'=1 if s227_`i'==. & s216_`i'==2
* 	This case looks to have been misrecorded as born died rather than lost before full term
	replace s216_`i'=3 if s227_`i'==3 & s216_`i'==2

*   Restrict to 60 months preceding survey
    replace births = births+1 if b3_92_`i' > v008-60 & s216_`i'==1
    replace stillbirths = stillbirths+1 if b3_92_`i' > v008-60 & s227_`i' != . & s227_`i' >= 7
}
gen totpreg7m = births+stillbirths

tab births [iw=v005/1000000]
tab stillbirths [iw=v005/1000000]
tab totpreg7m [iw=v005/1000000]
Re: Replicating table 8.4- Nepal DHS 2011 [message #8658 is a reply to message #8657] Wed, 25 November 2015 01:38 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
So much help,

Thanks heaps

Cheers
Re: Replicating table 8.4- Nepal DHS 2011 [message #8664 is a reply to message #8646] Wed, 25 November 2015 23:22 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member

Hi Trevor,

I used this coding for Nepal DHS 2006. Total number of stillbirths came accurate as report(126) but total pregnancies 7 months or more came 5627 instead of 5671.

Is there any coding i have to alter here?

Thanks
Re: Replicating table 8.4- Nepal DHS 2011 [message #8665 is a reply to message #8646] Thu, 26 November 2015 05:02 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Sorry, i forgot to count the twins.
All good!
Re: Replicating table 8.4- Nepal DHS 2011 [message #8666 is a reply to message #8646] Thu, 26 November 2015 17:43 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Hi Trevor,

I was interested in following variables:m1, m14, m10, m46, m45, bord and b11 and when i tried to reshape these variables, i got unusual looking numbers, what is the right way to reshape variables such as m10_1 or m10_01 that can be added into the file of pregnancy?

Thanks
Re: Replicating table 8.4- Nepal DHS 2011 [message #8671 is a reply to message #8646] Fri, 27 November 2015 18:26 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Hi,

Can you please help how to calculate PREVIOUS PREGNANCY INTERVAL in MONTHS using pregnancy data file for 2001, 2006 and 2011? the number i produced did not match the report.

I used the variable v212 to calculate mothers age at birth but again the number did not match the report too.

All other variable's numbers match the report.

Many thanks

Re: Replicating table 8.4- Nepal DHS 2011 [message #8680 is a reply to message #8648] Tue, 01 December 2015 01:58 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Hi,

How am i supposed to include pregnancy order number for those cases which turned into stillbirths? the code you have given excludes pregnancy order number for stillbirths for 2006 and 2011 pregnancy file. But the code worked fine when 2001 IR file was converted into pregnancy file.

Thank you
Re: Replicating table 8.4- Nepal DHS 2011 [message #8690 is a reply to message #8666] Wed, 02 December 2015 09:45 Go to previous messageGo to next message
Liz-DHS
Messages: 1516
Registered: February 2013
Senior Member
Dear User,
Your queries are in the queue. As soon as we have responses, we will post. Thank you!
Re: Replicating table 8.4- Nepal DHS 2011 [message #8708 is a reply to message #8648] Thu, 03 December 2015 15:55 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Hi Trevor,

I also tried to count twins in stillbirths seperately using this coding but finding hard.

Is there any way I can also find the number of miscarriage and spontenious abortion? Because there must be induced abortion cases which I would like to know seperately.

Many thanks.
Re: Replicating table 8.4- Nepal DHS 2011 [message #8997 is a reply to message #8708] Mon, 25 January 2016 15:12 Go to previous messageGo to next message
Liz-DHS
Messages: 1516
Registered: February 2013
Senior Member
Dear User,
Do you still need assistance with this post?
Thank you!
Re: Replicating table 8.4- Nepal DHS 2011 [message #9008 is a reply to message #8997] Tue, 26 January 2016 17:04 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Dear Liz,

Yes please. It would be great to get assistance on my previous post.

Many thanks

S
Re: Replicating table 8.4- Nepal DHS 2011 [message #9016 is a reply to message #8997] Wed, 27 January 2016 05:42 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Dear Liz,

i also wanted to calculate the pregnancy order which has been shown in table number 9.19 of Nepal DHS 2011, and whether or not that pregnancy was wanted. Assistance on that would be so much help.

Thanks heaps!

Re: Replicating table 8.4- Nepal DHS 2011 [message #9504 is a reply to message #9016] Tue, 05 April 2016 20:12 Go to previous message
pramesh is currently offline  pramesh
Messages: 41
Registered: November 2015
Location: australia
Member
Dear Liz,

It has been quite a while. Is there any clues that someone will assist me by answering all my questions since last year?

Thank you so much!
Previous Topic: Variable Construction
Next Topic: Table 2.11 Clarification
Goto Forum:
  


Current Time: Thu Mar 28 13:39:49 Coordinated Universal Time 2024