The DHS Program User Forum
Discussions regarding The DHS Program data and results
Home » Countries » Nigeria » chap 11(Nutrition indicator) (table 11.7 minimum acceptable diet among non breastfed)
chap 11(Nutrition indicator) [message #25774] Wed, 07 December 2022 10:19 Go to next message
anum.ali is currently offline  anum.ali
Messages: 6
Registered: September 2022
Member
Hello

My query is my estimates for table 11.7 Among nonbreastfed children age 6-23 months, percentage fed for minimum acceptable diet are not coming same as in Nigeria dhs 2018 report for example values for sex of child generated are (male: 9, female: 14.9) whereas for residence are (urban: 15.7, rural: 7.1) these are different then the report although the total coming is fine and estimates for rest of the table are correct I am confused where am I making mistake for minimum acceptable diet help will be appreciated, thank you

//currently breastfed
gen bf_curr= m4==95
label values bf_curr yesno
label var bf_curr "Currently breastfeeding"

//Fed milk or milk products
gen milkf = 0
replace milkf=milkf + v469e if v469e<8
replace milkf=milkf + v469f if v469f<8
replace milkf=milkf + v469x if v469x<8
gen fed_milk= ( milkf>=2 | m4==95) if inrange(b19,6,23)
label values fed_milk yesno
label var fed_milk "Child given milk or milk products"

//Min dietary diversity
* 8 food groups

*1. breastmilk
gen group1= m4==95

*2. foods made from grains, roots, tubers, and bananas/plantains, including porridge and fortified baby food from grains
gen group2= grains==1 | root_tubers==1 | forti_bbyfood==1

*3. legumes and nuts
gen group3= legumes_nuts==1

*4. infant formula, milk other than breast milk, cheese or yogurt or other milk products
gen group4= inf_formula==1 | othr_milk==1 | dairy==1

*5. meat, poultry, fish, and shellfish (and organ meats)
gen group5= meatfish==1

*6. eggs
gen group6= eggs==1

*7. vitamin A-rich fruits and vegetables
gen group7= vita==1

*8. other fruits and vegetables
gen group8= othr_frtveg==1


* add the food groups
egen foodsum = rsum(group1 group2 group3 group4 group5 group6 group7 group8)
recode foodsum (1/4 .=0 "No") (5/8=1 "Yes"), gen(mdd)
replace mdd=. if b19<6
label values mdd yesno
label var mdd "Child with minimum dietary diversity, 5 out of 8 food groups- last-born 6-23 months"

//Min meal frequency
gen feedings=milkf
replace feedings= feedings + m39 if m39>0 & m39<8
gen mmf = (m4==95 & inrange(m39,2,7) & inrange(b19,6,8)) | (m4==95 & inrange(m39,3,7) & inrange(b19,9,23)) | (m4!=95 & feedings>=4 & inrange(b19,6,23))
replace mmf=. if b19<6
label values mmf yesno
label var mmf "Child with minimum meal frequency- last-born 6-23 months"

//Min acceptable diet
egen foodsum2 = rsum(grains root_tubers legumes_nuts meatfish vita othr_frtveg eggs)
gen mad = (m4==95 & mdd==1 & mmf==1) | (m4!=95 & foodsum2>=4 & mmf==1 & milkf>=2)
replace mad=. if b19<6
label values mad yesno
label var mad "Child with minimum acceptable diet- last-born 6-23 months"

*child's sex
tab b4 mad if bf_curr==0 [iw=wt], row nofreq

*residence
tab v025 mad if bf_curr==0 [iw=wt], row nofreq

Re: chap 11(Nutrition indicator) [message #25864 is a reply to message #25774] Thu, 22 December 2022 09:00 Go to previous message
Shireen-DHS is currently offline  Shireen-DHS
Messages: 140
Registered: August 2020
Location: USA
Senior Member
Hello,

Thank you for your question. The reason is that there has been a change to how the food groups are constructed. For example baby food is no longer included in group3. The updated code below will give you a match.

Thank you.
Best,
Shireen Assaf
The DHS Program


******


*** Minimum feeding indicators ***

//Min dietary diversity - min of 5 out of 8 food groups
*1. breastmilk
gen group1= m4==95

*2. infant formula, milk other than breast milk, cheese or yogurt or other milk products
gen group2= v411a==1 | v411==1 | v413a==1 | v414v==1 | v414p==1

*3. foods made from grains and roots, tubers, and bananas/plantains
gen group3= nt_grains==1 | nt_root==1

*4. vitamin A-rich fruits and vegetables
gen group4= nt_vita==1

*5. other fruits and vegetables
gen group5= nt_frtveg==1

*6. eggs
gen group6= nt_eggs==1

*7. meat, poultry, fish, and shellfish (and organ meats)
gen group7= nt_meatfish==1

*8. legumes and nuts
gen group8= nt_nuts==1

* add the food groups
egen foodsum = rsum(group1 group2 group3 group4 group5 group6 group7 group8)
recode foodsum (1/4 .=0 "No") (5/8=1 "Yes"), gen(nt_mdd)
replace nt_mdd=. if age<6
label values nt_mdd yesno
label var nt_mdd "Child with minimum dietary diversity - youngest 6-23 months"

//Fed milk or milk products
gen totmilkf = 0
replace totmilkf=totmilkf + v469e if v469e<8
replace totmilkf=totmilkf + v469f if v469f<8
replace totmilkf=totmilkf + v469x if v469x<8
gen nt_milkfeeds= ( totmilkf>=2 | m4==95) if inrange(age,6,23)
replace nt_milkfeeds=. if m4==95
label values nt_milkfeeds yesno
label var nt_milkfeeds "Non-breastfed child given at least two milk feeds in day/night before survey- youngest child age 6-23 months"

//Min meal frequency
gen feedings=totmilkf
replace feedings= feedings + m39 if m39>0 & m39<8
gen nt_mmf = (m4==95 & inrange(m39,2,7) & inrange(age,6,8)) | (m4==95 & inrange(m39,3,7) & inrange(age,9,23)) | (m4!=95 & feedings>=4 & inrange(age,6,23))
replace nt_mmf=. if age<6
label values nt_mmf yesno
label var nt_mmf "Child with minimum meal frequency- youngest child 6-23 months"

//Min acceptable diet
egen foodsum2 = rsum(group3 group4 group5 group6 group7 group8)
gen nt_mad = (m4==95 & nt_mdd==1 & nt_mmf==1) | (m4!=95 & foodsum2>=4 & nt_mmf==1 & totmilkf>=2)
replace nt_mad=. if age<6
label values nt_mad yesno
label var nt_mad "Child with minimum acceptable diet- youngest child 6-23 months"


***
tab b4 nt_mad if m4!=95 [iw=wt], row
* this gives 7.4% for males and 13.5% for females and 10.2% total among non-breastfed children as in the final report.
Previous Topic: chap 9 reproductive health
Next Topic: Inquiry regarding DHS 2018 analysis using R
Goto Forum:
  


Current Time: Fri Mar 29 02:02:18 Coordinated Universal Time 2024