The DHS Program User Forum
Discussions regarding The DHS Program data and results
Home » Countries » Ethiopia » Replicating table 8.4: ETHIOPIA DHS 2000 (Calculating perinatal mortality using the ETHIOPIA DHS 2000 data)
Replicating table 8.4: ETHIOPIA DHS 2000 [message #20271] Sun, 18 October 2020 09:28 Go to next message
Melese is currently offline  Melese
Messages: 17
Registered: August 2019
Member
Dear Expert, greetings. I tried to replicate table 8.4 "Perinatal mortality rate" using the 2000 Ethiopia DHS. "vcal_1" doesn't exist the ETHIOPIA 2000 DHS data. Can anyone help with the STATA SYNTAX to calculate perinatal mortality rate using the ETHIOPIA 2000 data in the same way as mentioned in the GitHub: "https://github.com/DHSProgram/DHS-Indicators-Stata" " https://github.com/DHSProgram/DHS-Indicators-Stata/tree/mast er/Chap08_CM"?
Regards
Melese
Re: Replicating table 8.4: ETHIOPIA DHS 2000 [message #20297 is a reply to message #20271] Tue, 20 October 2020 15:53 Go to previous messageGo to next message
Bridgette-DHS is currently offline  Bridgette-DHS
Messages: 3017
Registered: February 2013
Senior Member
Please see the following guidance from DHS Senior Technical Director: Trevor Croft:

See https://userforum.dhsprogram.com/index.php?t=msg&th=5153 &goto=9859&#msg_9859 for an existing discussion.

This also refers to https://userforum.dhsprogram.com/index.php?t=msg&th=4692 &goto=8657&#msg_8657 which provides code for Nepal, but the principle is the same for Ethiopia 2000.

See also the attached snippet of code.

Note that we don't have vcal_1, but we have a pregnancy history, so can get the same information out of the pregnancy history.

[Updated on: Mon, 26 October 2020 08:22]

Report message to a moderator

Re: Replicating table 8.4: ETHIOPIA DHS 2000 [message #20342 is a reply to message #20297] Sun, 25 October 2020 09:10 Go to previous messageGo to next message
Melese is currently offline  Melese
Messages: 17
Registered: August 2019
Member
Hi Bridgette, greetings again and thank you for the reply. Unfortunately, I couldn't still generate the table 8.4: for EDHS 2000 which I easily did using EDHS 2005 and above data. I followed the discussions and failed to have the appropraite syntax. I used the following syntax with EDHS 2000 IR data file.

"keep caseid v001 v002 v003 v005 v008 v011 v013 v017 v018 v019 v021 v022 v023 v* s231ac_* s231c_*
rename *_0* *_*
reshape long s231ac_ s231c_, i(caseid) j(i)
drop if s231ac_==.
keep if s231ac_ > v008-60 & s231c>=7
rename s231ac_ b3"

merging with BR file using v001 v002 v003 creates error.

Can you help with fixing the merging and syntax for generating the variables "stillbirths", "early neonatal mortality", ang "perinatal mortality",please?
Kindest regards
Melese
Re: Replicating table 8.4: ETHIOPIA DHS 2000 [message #21857 is a reply to message #20297] Thu, 31 December 2020 23:42 Go to previous messageGo to next message
Melese is currently offline  Melese
Messages: 17
Registered: August 2019
Member
Hi Bridgette, greetings again. I have been waiting for your responses for this long time. I have strictly followed the discussions so far but non of them explicitly mention some syntax to replicate table 8.4 from EDHS 2000. Examaple:- which variable should I use to replace the vcal_1 (which is important to calculate the perinatal mortality rate)in the IR data file, s231ac_1 or s231c_1?? I want to calculate stillbirths, early neonatal mortality and perinatal mortality rates as the same time using the 2000 EDHS data. Any help, please?
Regards.
Re: Replicating table 8.4: ETHIOPIA DHS 2000 [message #21873 is a reply to message #21857] Mon, 04 January 2021 12:57 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 787
Registered: January 2013
Senior Member
You nearly had it with your code! A couple of fixes for you:
1) You don't need the rename following the keep statement as there are less than 10 entries in the non-live pregnancy history, and thus no cases with a leading 0.
2) You had successfully isolated the stillbirths, but you also needed to drop the cases that were missing on s231c_

I added in code to extract just the births in the last 5 years from the birth history (at the beginning), and then added code to combine the files (at the end) using append (not merge as you are appending births and stillbirths, not merging them together).

* select cases and variables of interest from the birth history
use "ETBR41FL.DTA", clear
 
keep caseid v001 v002 v003 v005 v008 v011 v013 v017 v018 v019 v021 v022 v023 b3 b6
* keep births in the last 5 years
keep if b3 > v008-60

save births, replace

* select cases and variables of interest from the non-live pregnancy history
use "ETIR41FL.DTA", clear

keep caseid v001 v002 v003 v005 v008 v011 v013 v017 v018 v019 v021 v022 v023 s231ac_* s231c_*

* convert to long format to match birth history 
reshape long s231ac_ s231c_, i(caseid) j(i)

* keep only pregnancies in the last 5 years of 7 month duration or longer
drop if s231ac_==.
keep if s231ac_ > v008-60 & s231c_ >=7 & s231c_ != .

* rename cmc date of pregnancy to match birth history
rename s231ac_ b3

* combine births and non-live pregnancies of 7+ months
append using births

* set weight variable
gen wt = v005/1000000

* capture stillbirths - those with a duration of pregnancy in s231c_
gen stillbirth = (s231c_ != .)
tab stillbirth [iw=wt]

* capture early neonatal deaths (deaths in the first 7 days [0-6] = b6 < 107)
gen earlyneonatal = (b6 < 107)
tab earlyneonatal [iw=wt]

* perinatal mortality is stillbirths or early neonatal deaths
gen perinatal = (stillbirth | earlyneonatal)
tab perinatal [iw=wt]
This shows 234 stillbirths, 421 early neonatal deaths, and a perinatal mortality rate of 5.25 percent, equivalent to 52.5 per thousand (the last digit is slightly different and I don't have an explanation why).
Re: Replicating table 8.4: ETHIOPIA DHS 2000 [message #21894 is a reply to message #21873] Wed, 06 January 2021 06:53 Go to previous message
Melese is currently offline  Melese
Messages: 17
Registered: August 2019
Member
Trevor, thank you very much. Thank you for the help to fix my questions. Thank you very much.
Previous Topic: childhood acute respiratoty tract infection and associated factors by usingEDHS2016
Next Topic: children mortality rate for Ethiopia's KR file
Goto Forum:
  


Current Time: Thu Mar 28 15:45:26 Coordinated Universal Time 2024