The DHS Program User Forum
Discussions regarding The DHS Program data and results
Home » Topics » Reproductive Health » Place of delivery & Assistance during delivery
Place of delivery & Assistance during delivery [message #15456] Tue, 24 July 2018 08:55 Go to next message
eejeta@yahoo.com is currently offline  eejeta@yahoo.com
Messages: 3
Registered: February 2018
Member
Hello,

I am working on individual data of Ethiopia 2016 DHS. I want to replicate table 9.8 about place of delivery and table 9.9 about assistant during delivery using stata. But the result that I found is different from the final report even the total number live birth in last 5 years is different. 7589 from my calculation but 11023 on the final report.

The stata command I used mentioned as following:

recode m15_1 (10 11 12 =1 "Home") (20/26 30/36 40/46 = 2 " Health facility") (96=3 "others"), gen(Place_Delviry)
replace Place_Delviry =. if v208 ==0
lab var Place_Delviry " Place of delivery for last birth"
tab Place_Delviry [iw=v005/1000000]

I am very happy if somebody help me.


Eshetu
Re: Place of delivery & Assistance during delivery [message #15459 is a reply to message #15456] Tue, 24 July 2018 15:17 Go to previous messageGo to next message
Mlue
Messages: 92
Registered: February 2017
Location: North West
Senior Member
Hi,

See the attached files... maybe they might help.

Good luck
Re: Place of delivery & Assistance during delivery [message #15463 is a reply to message #15456] Wed, 25 July 2018 03:27 Go to previous messageGo to next message
Mlue
Messages: 92
Registered: February 2017
Location: North West
Senior Member
Hello,

In case you trouble opening the attached files...
For 2016 DHS

FYI: Always read the tables on the final report as there may be information (footnotes)
that may assist you to derive the variables




** USE THE BIRTHS RECODE (ETBR70FL) **
** ETHIOPIA DHS 2016

clear all
set matsize 800
set maxvar 9000
set mem 1g
cd "..."
use "ETBR70FL", clear
set more off

********************************************************************************
** WEIGHT VARIABLE
gen weight = v005/1000000

**************************

** SURVEY SET
gen psu =    v021
gen strata = v023
svyset [pweight = weight], psu(psu) strata(strata) vce(linearized)
*svydes

********************************************************************************


// DELIVERY CARE = facility-based deliveries
recode m15 (21/46=1 "Facility-based deliveries") ///
(11/12 96=0 "Non-facility deliverie"), gen(facility_delivery)
label var facility_delivery "Facility-based deliveries"
label val facility_delivery facility_delivery

*******************

cap drop DHS_delivery
recode m15 (21/26=1 "Public sector") ///
(31/36=2 "Private sector") (41/46=3 "NGO") ///
(11/12=4 "Home") (96=5 "Other"), gen(DHS_delivery)
label var DHS_delivery "Place of delivery as in DHS eport"
label val DHS_delivery DHS_delivery

recode m15 (21/26=1 "Public sector") (31/36=2 "Private sector") ///
(41/46=3 "NGO") (11/12 96=4 "Elsewhere"), gen(DHS_deliveries)
label var DHS_deliveries "Replication of DHS table for facility-based deliveries"
label val DHS_deliveries DHS_deliveries

*==============================================================================*

** SKILLED BIRTH ATTENDANT

gen skilled_birth	=	0
label define skilled_birth 0"Unskilled" 1"Skilled"
label var skilled_birth "Birth delivered by skilled birth attendant"
label val skilled_birth skilled_birth

** SKILLED BIRTH ATTENDANTS RECODE

foreach xvar of varlist m3a m3b m3c m3d m3e {
replace skilled_birth=1 if `xvar'==1
}

**

*==============================================================================*

** DROP IF NOT WITHIN SAMPLE
qui regr DHS_delivery [pw=weight]		
drop if e(sample)!=1		

********************************************************************************
** CHECK: TABLE 9.8
tab facility_delivery [iw=weight], m

svy: tab facility_delivery, count format(%4.0f)
svy: tab facility_delivery, percent format(%4.1f) col

********************************************************************************

** CHECK: TABLE 9.9
tab skilled_birth [iw=weight], m

svy: tab skilled_birth, count format(%4.0f)
svy: tab skilled_birth, percent format(%4.1f) col

********************************************************************************
********************************************************************************
********************************************************************************

svy: tab v190 facility_delivery, percent format(%4.1f) miss row
svy: tab v190 skilled_birth, percent format(%4.1f) miss row

svy: tab DHS_deliveries skilled_birth, percent format(%4.1f) miss row

********************************************************************************

exit

************************************************************ ********************

For 2011 DHS

** USE THE BIRTHS RECODE (ETBR61FL) **
** ETHIOPIA DHS 2011

clear all
set matsize 800
set maxvar 9000
set mem 1g
cd "..."
use "ETBR61FL", clear
set more off

********************************************************************************
** WEIGHT VARIABLE
gen weight = v005/1000000

**************************

** SURVEY SET
gen psu =    v021
gen strata = v023
svyset [pweight = weight], psu(psu) strata(strata) vce(linearized)
*svydes

********************************************************************************
recode m15 (21/33=1 "Facility-based deliveries") ///
(11/12 96 99=0 "Non-facility deliverie"), gen(facility_delivery)
label var facility_delivery "Facility-based deliveries"
label val facility_delivery facility_delivery

*******************

cap drop DHS_delivery
recode m15 (21/24=1 "Public sector") ///
(31 32=2 "Private sector") (33=3 "NGO") ///
(11/12=4 "Home") (96 99=5 "Other"), gen(DHS_delivery)
label var DHS_delivery "Place of delivery as in DHS eport"
label val DHS_delivery DHS_delivery

recode m15 (21/24=1 "Public sector") (31/32=2 "Private sector") ///
(33=3 "NGO") (11/12 96 99=4 "Elsewhere"), gen(DHS_deliveries)
label var DHS_deliveries "Replication of DHS table for facility-based deliveries"
label val DHS_deliveries DHS_deliveries

*==============================================================================*

** SKILLED BIRTH ATTENDANT

gen skilled_birth	=	0
label define skilled_birth 0"Unskilled" 1"Skilled"
label var skilled_birth "Birth delivered by skilled birth attendant"
label val skilled_birth skilled_birth

** SKILLED BIRTH ATTENDANTS RECODE

foreach xvar of varlist m3a m3b {
replace skilled_birth=1 if `xvar'==1
}

**

*==============================================================================*

** DROP IF NOT WITHIN SAMPLE
qui regr facility_delivery [pw=weight]		
drop if e(sample)!=1		

********************************************************************************
** CHECK: TABLE 9.6
tab facility_delivery [iw=weight], m

svy: tab facility_delivery, count format(%4.0f)
svy: tab facility_delivery, percent format(%4.1f) col

********************************************************************************

** CHECK: TABLE 9.7
tab skilled_birth [iw=weight], m

svy: tab skilled_birth, count format(%4.0f)
svy: tab skilled_birth, percent format(%4.1f) col

********************************************************************************
********************************************************************************
********************************************************************************

svy: tab v190 facility_delivery, percent format(%4.1f) miss row
svy: tab v190 skilled_birth, percent format(%4.1f) miss row

svy: tab DHS_deliveries skilled_birth, percent format(%4.1f) miss row

********************************************************************************

exit

Re: Place of delivery & Assistance during delivery [message #15472 is a reply to message #15463] Fri, 27 July 2018 08:28 Go to previous message
eejeta@yahoo.com is currently offline  eejeta@yahoo.com
Messages: 3
Registered: February 2018
Member
Dear Mlue

Thank you for your useful help.


Eshetu
Previous Topic: Surveys with age at menarche collected
Next Topic: M61 Time spent at place of delivery
Goto Forum:
  


Current Time: Thu Mar 28 09:55:02 Coordinated Universal Time 2024