|child mortality rate per women's empowerment indicator [message #3534]
||Sun, 28 December 2014 10:42
Registered: November 2014
I'm trying to calculate child's mortality rates per women's empowerment indicator by using BDHS 2011. Unfortunately the commands I use on Stata produce results not matching the ones in the DHS report.
I guess I'm committing some mistake in the use of empowerment indicators, since the "general" mortality rate I calculated agrees with the one provided in the report... anyway, I'm posting here the procedure I used hoping there's someone able to tell me what I'm doing wrong and to suggest me the right procedure.
Thanks in advance for your help.
use "BDBR61FL.DTA", clear
*generate "hypage" variable), indicating the age of the child at interview date if he/she's alive and the age that the child would be if he/she was alive if he's dead*.
. gen hypage=(v008-b3)/12
*generate the surviving time (in years), "timeyears" for each child in the survey and an indicator of wether the child is dead*
. gen timeyears=.
. replace timeyears=hypage
. replace timeyears=b7/12 if b5==0
. gen dead= (b5==0)
.ltable timeyears dead if hypage <=5 , int(.5) failure
*Unify the various dimensions of empowerment indicator 1: number of reasons for which wife beating is justified (v744a,b,c,d,e)*
clonevar v744a_dummy= v744a
replace v744a_dummy=. if v744a==8
clonevar v744b_dummy = v744b
replace v744b_dummy=. if v744b==8
clonevar v744c_dummy= v744c
replace v744c_dummy=. if v744c==8
clonevar v744d_dummy= v744d
replace v744d_dummy=. if v744d==8
clonevar v744e_dummy= v744e
replace v744e_dummy=. if v744e==8
egen numjustbeatingreasons=rowtotal (v744a_dummy v744b_dummy v744c_dummy v744d_dummy v744e_dummy)
*generate a new variable, tab1311, to have the wmpowerment indicator divided as it is in the report (table 13.11)*
clonevar tab1311 = numjustbeatingreasons
replace tab1311 =1 if numjustbeatingreasons==2
replace tab1311 =3 if numjustbeatingreasons==4
*lifetable by number of reasons for which beating wife is justified: it displays mortality rates per empowerment indicator different by the ones in the report*
ltable timeyears dead if hypage <=5 , int(.5) failure by (tab1311)
*unify dimensions of empowerment indicator 2: number of reasons in which women can partecipate*
clonevar v743a_dummy= v743a
replace v743a_dummy=0 if v743a>2
replace v743a_dummy=1 if v743a==2
lab def v743a_dummy 1" respondent alone and/or with husband" 0 "don't participate"
lab val v743a_dummy v743a_dummy
clonevar v743b_dummy= v743b
replace v743b_dummy=0 if v743b>2
replace v743b_dummy=1 if v743b==2
lab def v743b_dummy 1" respondent alone and/or with husband" 0 "don't participate"
lab val v743b_dummy v743b_dummy
clonevar v743d_dummy= v743d
replace v743d_dummy=0 if v743d>2
replace v743d_dummy=1 if v743d==2
lab def v743d_dummy 1" respondent alone and/or with husband" 0 "don't participate"
lab val v743d_dummy v743d_dummy
egen numdecisionpartecipate=rowtotal (v743a_dummy v743b_dummy v743d_dummy )
*lifetable by number of reasons in which women can partecipate: it displays mortality rates per empowerment indicator different by the ones in the report*
ltable timeyears dead if hypage <=5 , int(.5) failure by (numdecisionpartecipate)
|Re: child mortality rate per women's empowerment indicator [message #3659 is a reply to message #3534]
||Fri, 23 January 2015 11:18
Registered: February 2013
Following is a response from Senior DHS Stata Specialist, Tom Pullum|
This query has two parts. One of them is about the DHS calculation of under-five mortality rates with covariates, and the other is about the construction of the two empowerment indicators.
The calculation of under-five mortality rates with covariates requires software that is only distributed in response to individual requests, and has been sent directly to the user.
The two empowerment indicators in the Bangladesh 2011 report are calculated in Stata with the following lines:
use "C:\...\BDIR61FL.DTA", clear /*set correct filepath*/
**Panel 1 -- Decisionmaking -- uses vars v743a, v743b, v743d, s823
recode v743a (1/2=1) (4/9=0), g(dmrhealth) /*This turns the vars into dichotomous variables & handles missing/odd values*/
recode v743b (1/2=1) (4/9=0), g(dmbuy)
recode v743d (1/2=1) (4/9=0), g(dmvisit)
recode s823 (1/2=1) (4/9=0), g(dmchealth)
label def yesno 0 "no" 1 "yes"
lab val dm* yesno
gen dmnum = dmrhealth + dmbuy + dmvisit + dmchealth /*This provides a count of # of decisions Respondent makes*/
recode dmnum (0=0) (1/2=1) (3=3) (4=4) /*This collapses into the categories in the final report*/
lab def dmnum 1 "1-2"
lab val dmnum dmnum
lab var dmnum "Number of decisions in which women participate"
tab dmnum [iw=wt] /*Check that results match final report Table 13.8*/
**Panel 2 -- Wife beating attitudes -- uses v744a-e
recode v744a (8=0), g(v744a_r) /*This handles don't know values*/
recode v744b (8=0), g(v744b_r)
recode v744c (8=0), g(v744c_r)
recode v744d (8=0), g(v744d_r)
recode v744e (8=0), g(v744e_r)
gen wfbnum = v744a_r + v744b_r + v744c_r + v744d_r + v744e_r /*This provides a count of # of wife beating reasons Respondent agrees with*/
recode wfbnum (1/2=1) (3/4=3) /*This collapses into the categories in the final report*/
lab def wfbnum 1 "1-2" 3 "3-4"
lab val wfbnum wfbnum
lab var wfbnum "Number of reasons for which wife beating is justified"
tab wfbnum if v502==1 [iw=wt] /*Check that results match Final Report Table 13.8*/