/*
	HOUSEHOLDRECODE: BDHR72FL
	BDHS 2014

	BY: MLULEKI TSAWE - (University of the Western Cape, South Africa)

*/

/* BDHS HOUSEHOL FILE (BDHR72FL) */

** OPEN THE HOUSEHOLD FILE = BDHR72FL

clear all
use "BDHR72FL", clear
set more off

gen hh_weight = hv005/1000000

********************************************************************************

** PLACE FOR COOKING (Table 2.6 Cooking amenity)
recode hv241 (1=1 "In the house") (2=2 "In a separate building") ///
(3=3 "Outdoors") (else=4 "No food cooked in household"), gen(place4cook)
label variable place4cook "Place used by household for cooking"
label values place4cook place4cook

tab place4cook hv025 [iw=hh_weight], miss
tab place4cook hv025 [iw=hh_weight], miss col nof

********************************************************************************

** PLACE FOR COOKING (Table 2.6 Cooking amenity)
recode hv226 (1=1 "Electricity") (2/4=2 "LPG/natural gas/biogas") (5=3 "Kerosene") ///
(6=4 "Coal/lignite") (7=5 "Charcoal") (8=6 "Wood") (9=7 "Straw/shrubs/grass") ///
(10=8 "Agricultural crop") (11=9 "Animal dung") (96=10 "Other") ///
(else=11 "No food cooked in household"), gen(cook_fuel)
label variable cook_fuel "Type of cooking fuel used by household for cooking"
label values cook_fuel cook_fuel

tab cook_fuel hv025 [iw=hh_weight], miss
tab cook_fuel hv025 [iw=hh_weight], miss col nof

********************************************************************************

** SOLID FUEL
recode hv226 (6/11 = 1 "Yes") (else = 0 "No"), gen(solid_fuel)
*label variable solid_fuel "Household uses solid fuel for cooking"
*label values solid_fuel solid_fuel

tab solid_fuel hv025 [iw=hh_weight], miss
tab solid_fuel hv025 [iw=hh_weight], miss col nof

********************************************************************************

keep hhid hv001 hv002 hv003 place4cook cook_fuel solid_fuel

rename hv001 v001
rename hv002 v002
rename hv003 v003

***************************

sort v001 v002

************ MERGE WITH KIDS RECODE FILE ***************************************

** MERGE WITH KR FILE BDKR72FL
merge 1:m v001 v002 using "C:\Users\MlulekiT\Documents\BANGLADESH DHS 2014\BDKR72FL", keep(match master)
keep if _merge ==3
drop _merge

/** ======================================================================== **/

** WEIGHT VARIABLE
gen weight = v005/1000000

/** ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ **/ 

** SURVEY SET
gen psu =    v021
gen strata = v023
svyset psu [pw = weight], strata(strata)

////////////////////////////////////////////////////////////////////////////////

tab place4cook v025 [iw=weight], miss /* 1,218 kids live in a household where food is cooked in outdoors */

svy: tab v013 place4cook, percent format(%4.1f) row
svy: tab v190 place4cook, percent format(%4.1f) row

**********

save "merged_HH_and_KR_file", replace

exit