The DHS Program User Forum: Bangladesh » BDHS2014-bdkr data set- Children nutrition- table 11.6 in BDHS report, 4+food group

Home » Countries » Bangladesh » BDHS2014-bdkr data set- Children nutrition- table 11.6 in BDHS report, 4+food group

Show: Today's Messages :: Show Polls :: Message Navigator

BDHS2014-bdkr data set- Children nutrition- table 11.6 in BDHS report, 4+food group [message #10664]

Sun, 28 August 2016 17:41

syedaishraazim
Messages: 3
Registered: August 2016
Location: USA

Member

Working with child nutrition, using bdkr data set of BDHS 2014.

I was creating a Minimum Dietary Diversity variable, where we need to use variables V411-V414V(not all but most of these) to recode and then create the minimum dietary diversoty(4+ food group). Minimum Dietary Diversity in the report is written as 4+ food group and is reported in the table 11.6.

My percentage is not matching with the ones in table 11.6. I did not stratify them by breast feeding status, Hence was expecting it to match the "among all children age 6-23 months". My percentages are 5.22,18.53,26.60,39.93 for age groups 6-8,9-11,12-17 and 18-23 respectively. Also the Number of all children 6-23 months did not match.
I used weights at the last while I ran the frequency for 4+ food group.

To recode and calculate MDD I did the following steps:
1. recoded variable V414A V414E V414F V414G V414H V414I V414J V414K V414L V414M V414N V414O V414P V414V V411 V412A to ".","9","8" as missing, 1 as 1 and 0 as 0.

2. These were the food groups I used.
grainroottuber = (bread/V414E)+(potatoes/V414F)+(fortified/V412A);
legumenut= (beans/V414O);
dairy=(tinned/V411)+(cheese/V414P)+(yogurt/V414V);
fleshfood=(meat/V414H)+(liver/V414M)+(V414N/fish);
neggs=(V414g/eggs);
VitA=(pumpkinV414I)+(darkgreenV414J)+(mangoes/V414K);
Otherfruit=(V414L/otherfruits);

3.If they ate any 4 from these group the child was considered to have the 4+ food group

Did I missed anything while calculating? I already checked Guide to DHS statistics and this calculation was not there.

Attachment: MDD.PNG
(Size: 17.73KB, Downloaded 802 times)

[Updated on: Sun, 28 August 2016 18:09]

Report message to a moderator

Re: BDHS2014-bdkr data set- Children nutrition- table 11.6 in BDHS report, 4+food group [message #10690 is a reply to message #10664]

Tue, 30 August 2016 10:56

Bridgette-DHS
Messages: 3208
Registered: February 2013

Senior Member

Following is a response from DHS Senior Research Associate, Shireen Assaf:

To match the figure in table 11.6 in the BDHS report of 2442 children with 27.6% having consumed 4+ food groups, you need to select for the youngest child living with the mother between the age of 6 and 23 months. This is not so straight forward as you will need to find the youngest child for each mother. The below code will allow you to do this.

*** Find the youngest child living with mother age 6-23 months ******
use BDKR70FL.DTA, clear
*keep only children that are living with the mother
keep if b9==0
sort for the merge later
sort v001 v002 v003 bidx
save temp.dta, replace

*finding the youngest child for each mother
collapse (min) bidx, by(v001 v002 v003)
sort v001 v002 v003 bidx
merge v001 v002 v003 bidx using temp.dta

gen ageC=v008-b3
keep if ageC>=6 & ageC<=23

keep if _merge==3
drop _merge

*** creating the variable diet4 (4 +food groups)

* food groups
gen grains=1 if v412a==1| v414e==1|v414f==1
label value grains grains
label variable grains "GRAINS, ROOTS and TUBER"
tab grains

gen lagumes=1 if v414o==1
label value lagumes lagumes
label variable lagumes "LEGUMES and NUTS"

gen dairyp=1 if v411==1 | v411a==1 | v414p==1 |v414v==1
label value dairyp dairyp
label variable dairyp "DAIRY PRODUCTS"

gen fleshf=1 if v414h==1 | v414m==1 | v414n==1
label value fleshf fleshf
label variable fleshf "FLESH FOODS"

gen eggs=1 if v414g==1
label value eggs eggs
label variable eggs "EGGS"

gen vitama=1 if v414i==1|v414j==1|v414k==1
label value vitama vitama
label variable vitama "VITAMIN -A"

gen ofruits=1 if v414l==1
label value ofruits ofruits
label variable ofruits "OTHER fruits"

egen dietindC = rsum(grains lagumes dairyp fleshf vitama ofruits eggs) if grains~=.| lagumes~=.| dairyp~=.| fleshf~=.| vitama~=.| ofruits~=.| eggs~=.
label variable dietindC "Minimum dietary diversity children"

recode dietindC (1/3 .=0 "No") (4/7=1 "Yes"), gen(diet4)
ta diet4 [iw=v005/1000000]

*this gives 27.6% and 2442 children as in the report

Report message to a moderator

Re: BDHS2014-bdkr data set- Children nutrition- table 11.6 in BDHS report, 4+food group [message #10705 is a reply to message #10664]

Thu, 01 September 2016 16:54

syedaishraazim
Messages: 3
Registered: August 2016
Location: USA

Member

Thanks for the codes, it was very helpful.

From the BDHS 2014 report,it is already mentioned that infant feeding information were only collected from the youngest child of the respondent. I assume, then for the other children it will be missing by default, as there is no data.

Then why do we need to select the youngest child living with mother between the age of 6-23 months, and do the analysis?

I am currently working with SAS, Do you have the SAS codes of the following command? It will be very helpful.

keep if b9==0
sort for the merge later
sort v001 v002 v003 bidx
save temp.dta, replace

*finding the youngest child for each mother
collapse (min) bidx, by(v001 v002 v003)
sort v001 v002 v003 bidx
merge v001 v002 v003 bidx using temp.dta

gen ageC=v008-b3
keep if ageC>=6 & ageC<=23

keep if _merge==3
drop _merge

Thanks,
Ishra

Report message to a moderator

Re: BDHS2014-bdkr data set- Children nutrition- table 11.6 in BDHS report, 4+food group [message #10709 is a reply to message #10705]

Sat, 03 September 2016 13:30

Bridgette-DHS
Messages: 3208
Registered: February 2013

Senior Member

Another response from Tom Pullum:

If you want to match table 11.6 in the BDHS report, then you have to select the cases as described, or in some other way that accomplishes the same objective. The requirement that the child lives with the mother is made because we have good evidence that the responses are much more accurate for such children. The interval from 6 to 23 months is used in order to match with indicators established by UN agencies.

Sometimes DHS data are collected for subpopulations that are larger than what will actually go into the tables. If these restrictions were applied in the field, rather than during data processing, we know that interviewers would tend to reduce their workload by shifting children or respondents out of the specified subpopulation. For example, if the interviewers were only required to collect the data on children 6-23 months of age, I'm sure we would find a tendency for children's ages to be shifted down or up to avoid the questions. These shifts can be very subtle, especially when the interviewers don't have really firm birthdates and ages for the children. It is only natural that they will tend to reduce their workload when there is ambiguity, no matter how well-trained they are.

You are certainly free to use all the children for whom data are in the files, but if you deviate from the UN indicators, you may have difficulty making comparisons with other data sources or getting your results published.

We cannot translate the Stata code into SAS. Stata commands are pretty intuitive and you should be able to figure out the logic. "keep if _merge==3" identifies the cases that are in both of the files that you are merging. "collapse (min) bidx, by(v001 v002 v003)" identifies the case with the smallest value of bidx, among the cases that have the same value of v001 and v002 and v003--that is, the woman's youngest child.

Report message to a moderator

Re: BDHS2014-bdkr data set- Children nutrition- table 11.6 in BDHS report, 4+food group [message #10727 is a reply to message #10709]

Tue, 06 September 2016 12:27

syedaishraazim
Messages: 3
Registered: August 2016
Location: USA

Member

Thanks a lot for the explanation. :)

Report message to a moderator

Re: BDHS2014-bdkr data set- Children nutrition- table 11.6 in BDHS report, 4+food group [message #14281 is a reply to message #10709]

Sun, 18 March 2018 06:08

SAK_Nepal
Messages: 5
Registered: March 2018
Location: Kathmandu

Member

Hi Bridgette,

I used the same command to calculate Minimum Dietary Diversity Score for the Nepal DHS 2016 but I am getting the different result from the table 11.6 and the total number is also not matching. Would appreciate your help.

Thanks

Attachment: Minimum Dietary Diveristy.do
(Size: 2.60KB, Downloaded 821 times)

SAK

Report message to a moderator

Re: BDHS2014-bdkr data set- Children nutrition- table 11.6 in BDHS report, 4+food group [message #14303 is a reply to message #14281]

Tue, 20 March 2018 16:48

Bridgette-DHS
Messages: 3208
Registered: February 2013

Senior Member

Following is a response by DHS Technical Specialist, Benedict Rukundo:

Thanks for your query, there are some differences in the Nepal 2016 and BD2014 report that may account for some of the differences you are noting. In Nepal, the age variable is b19 and no longer needs to be calculated as done in BD2014. The code below uses b19 and should give the correct n in the report. If you run your previous code (**creating the variable diet4) to calculate MDD, it should now match the Nepal report.

*Generate weight variable**
gen wgt=v005/1000000

*Generate age, keep those <2 years
gen age=b19
keep if age<24
*keep only those children alive 
ta b5
keep if b5==1
*children must be the youngest child and living with mother
*keep only those living with mother
keep if b9==0
* finding the youngest child living with the mother
bysort v001 v002 v003: egen minbidx=min(bidx) 
* keep only children less than 2 years 
keep if age<24
ta bidx minbidx 
* need to drop those that are bidx==2 and minbidx==1
drop if bidx>minbidx

*drop those under 6 months
drop if age<6

*Generate age groups
recode age (6/8=1 "6-8")(9/11=2 "9-11")(12/17=3 "12-17")(18/23=4 "18-23"), gen (age_months)
ta age_month [iw=wgt]

Report message to a moderator

Re: BDHS2014-bdkr data set- Children nutrition- table 11.6 in BDHS report, 4+food group [message #14313 is a reply to message #14303]

Wed, 21 March 2018 11:45

SAK_Nepal
Messages: 5
Registered: March 2018
Location: Kathmandu

Member

Thank you for the response. It works now with DHS 2016 dataset.

SAK

Report message to a moderator

Re: BDHS2014-bdkr data set- Children nutrition- table 11.6 in BDHS report, 4+food group [message #14666 is a reply to message #14313]

Thu, 26 April 2018 13:44

Hassen
Messages: 121
Registered: April 2018
Location: Ethiopia,Africa

Senior Member

Dear my respected DHS forum users, All the above explanations make me more confused on how to construct the Minimum Dietary Diversity score from KR file? Thus How can I construct the Minimum Dietary Diversity Score, Minimum Meal Frequency and Minimum Acceptable Diet from KR file Using SPSS Version 24?
Thank you in advance, Hassen

Hassen Ali(Chief Public Health Professional Specialist)

Report message to a moderator

Previous Topic:	How to create media exposure?
Next Topic:	Creating Nutritional intake

Goto Forum:

-=] Back to Top [=-

[ Syndicate this forum (XML) ] [

] [

]

Current Time: Wed Dec 11 17:28:56 Coordinated Universal Time 2024