Jan,
To reproduce the results in the report, the tabulation is run using the women's recode (IR) file. The following code will reproduce the proportion's ever m arried by age group:
* Set up svy paramaters
gen wt=v005/1000000
svyset v021 [pw=wt], strata(v023)
* All women factor
gen aw = awfactt/100
* Check the denominator
tab v013 [iw=aw*wt]
* Ever Married
gen evermarr = (v502 == 1 | v502 == 2)
* Use the ratio of ever married and all women
svy: ratio evermarr/aw, over(v013)
The important piece of information here is that with an ever-married sample you need to inflate the denominator by the all women factor to have all women as the denominator, but not inflate the numerator. The simplest way to do this is to use separate variables for the numerator and denominator and take the ratio of the two as above.
However, this does not really help you as you are looking for proportions ever married among 10-14 year old girls. For this you should use the household members (PR) file. As you already realized, you can't reproduce exactly the proportion ever married for the 15-19 year old girls given in the Bangladesh report, but you should be very close. Using the code below with the PR dataset should put you in the right direction for what you need. Note the selection in the svy: tab command - it is selecting for girls who slept in the household the previous night (de facto sample). Also note that all women factors are not needed with the household members (PR) file as you already have all women included in the file, whereas the women's recode (IR) file is restricted in Bangladesh to the sample of ever married women.
* Set up svy paramaters
gen wt=hv005/1000000
svyset hv021 [pw=wt], strata(hv023)
* Age groups
gen ageg = int(hv105/5)
replace ageg = 14 if hv105 >= 70
replace ageg = 99 if hv105 == 99
label define ageg 0 "0-4" 1 "5-9" 2 "10-14" 3 "15-19" 4 "20-24" 5 "25-29" ///
6 "30-34" 7 "35-39" 8 "40-44" 9 "45-49" 10 "50-54" 11 "55-59" 12 "60-64" ///
13 "65-59" 14 "70+" 99 "Missing"
label values ageg ageg
* Ever Married
gen evermarr = (hv116 == 1 | hv116 == 2)
* Tabulate
svy: tab ageg evermarr if (hv103==1 & hv104==2), row count
The DHS Program User Forum
Members
Search
Help
Register
Login
Home
