* Construction of NFHS-5 Table 2.29

use "C:\Users\26216\ICF\Analysis - Shared Resources\Data\DHSdata\IAPR7DFL.DTA", clear

* Up to four people in the household may have a disability 
* The line numbers of person a, b, c, d are given by sh33a, sh33b, sh33c, sh33d
* All the variables are repeated for all members of the household

gen dis_any=0
local letters a b c d e x
foreach ll of local letters {
gen dis_`ll'=0
replace dis_`ll'=sh33a1`ll' if hvidx==sh33a
replace dis_`ll'=sh33b1`ll' if hvidx==sh33b
replace dis_`ll'=sh33c1`ll' if hvidx==sh33c
replace dis_`ll'=sh33d1`ll' if hvidx==sh33d
replace dis_`ll'=100*dis_`ll'
replace dis_any =100 if dis_`ll'==100
}

label variable dis_any "Any"
label variable dis_a "Hearing"
label variable dis_b "Speech"
label variable dis_c "Visual"
label variable dis_d "Mental"
label variable dis_e "Locomotor"
label variable dis_x "Other"

gen age=0
replace age=1 if hv105>=5
replace age=2 if hv105>=15
replace age=3 if hv105>=25
replace age=4 if hv105>=35
replace age=5 if hv105>=50
replace age=6 if hv105>=70
replace age=7 if hv105>95

label define age 0 "0-4" 1 "5-14" 2 "15-24" 3 "25-34" 4 "35-49" 5 "50-69" 6 "70+" 7 "DK/missing" 
label values age age

tabstat dis_* if hv102==1 [fweight=hv005], statistics(mean) by(hv025)
tabstat dis_* if hv102==1 [fweight=hv005], statistics(mean) by(age)

* Repeat for hv104=1, 2, 3
forvalues lsex=1/3 {
tabstat dis_* if hv102==1 & hv104==`lsex' [fweight=hv005], statistics(mean) by(hv025)
tabstat dis_* if hv102==1 & hv104==`lsex' [fweight=hv005], statistics(mean) by(age)
}