| Re: Postnatal care for mother [message #25532 is a reply to message #25498] |
Fri, 04 November 2022 16:00  |
Janet-DHS
Messages: 880
Registered: April 2022
|
Senior Member |
|
|
Following is a response from DHS staff member Tom Pullum:
Tables 8.22 and 8.23 in the NFHS-5 final report are not easy to construct. They are limited to the latest birth in the past five years (the birth with bidx=1 in the KR file). You must be sure to use the variables for post-natal care of the woman, NOT of the child. There is a groups of s variables (see s474) that are NOT used. The following code will construct the final panel of table 8.22 and the final panel of table 8.23, which are the most difficult panels. With this code, you can easily construct the other panels. Good luck!
* Tables 8.22 and 8.23, post-natal care for the woman, NFHS-5 final report
use "... IAKR7DFL.DTA", clear
* Find the relevant variables
describe m62-m68
* Crucial distinction between m62=1 and m66=1
* synthesize m63, m67 (time interval)
gen mint_raw=.
replace mint_raw=m63 if m62==1
replace mint_raw=m67 if m66==1
* synthesize m64, m68 (provider)
gen provider_raw=.
replace provider_raw=m64 if m62==1
replace provider_raw=m68 if m66==1
gen provider=.
replace provider=1 if provider_raw==11
replace provider=2 if provider_raw==12
replace provider=3 if provider_raw==13
replace provider=4 if provider_raw==22
replace provider=5 if provider_raw==21
replace provider=6 if provider_raw==96
replace provider=7 if provider==.
label variable provider "Provider of post-natal care for the woman"
label define provider 1 "Doctor" 2 "Nurse/midwife" 3 "Other health personnel" 4 "Dai" 5 "ASHA" 6 "Other" 7 "DK/Missing"
label values provider provider
gen mint=.
label variable mint "Interval from birth to first PNC check, mother"
replace mint=1 if (mint_raw>=0 & mint_raw<=103 & provider_raw<96)
replace mint=2 if (mint_raw>=104 & mint_raw<=200 & provider_raw<96)
replace mint=3 if (mint_raw>=201 & mint_raw<=202 & provider_raw<96)
replace mint=4 if (mint_raw>=203 & mint_raw<=300 & provider_raw<96)
replace mint=5 if (mint_raw>=301 & mint_raw<=305 & provider_raw<96)
replace mint=6 if (mint_raw==998 & provider_raw<960)
replace mint=7 if mint==.
label define mint 1 "<4 hours" 2 "4-23 hours" 3 "1-2 days" 4 "3-6 days" 5 "7-41 days" 6 "DK" 7 "None"
label values mint mint
gen mint_2days=0 if mint<.
replace mint_2days=1 if mint<=3
gen place=.
replace place=1 if m15>20 & m15<30
replace place=2 if m15==33
replace place=3 if m15==31 | m15==32
replace place=4 if m15==11
replace place=5 if m15==13
replace place=6 if m15==12
replace place=7 if place==.
label define place 1 "Public health facility" 2 "NGO/trust hosp/clinic" 3 "Private health facility" 4 "Own home" 5 "Parent home" 6 "Other home" 7 "Other/DK/missing"
label values place place
* Table 8.22
* Last panel only of table 8.22
* Cols 1-7 of last panel of table 8.22
tab place mint [iweight=v005/1000000] if bidx==1, row
* Col 9 of last panel of table 8.22
tab place mint_2days [iweight=v005/1000000] if bidx==1, row
* Table 8.23
* For this table, provider is changed so last column includes no post-natal care within 6 weeks
gen provider_rev=provider
replace provider_rev=7 if mint==7
label variable provider_rev "Provider of post-natal care for the woman"
label define provider_rev 1 "Doctor" 2 "Nurse/midwife" 3 "Other health personnel" 4 "Dai" 5 "ASHA" 6 "Other" 7 "DK/Missing/None"
label values provider_rev provider_rev
* Last panel only of table 8.23
tab place provider_rev [iweight=v005/1000000] if bidx==1, row
|
|
|
|
The DHS Program User Forum
Members
Search
Help
Register
Login
Home
