* Program to calculate table 18.6 in the Nigeria 2018 report
* Circumcision of girls age 0-14

* This program does not include covariates; it just shows how to calculate the indicator
* Apart from having to do a merge with a change of index, there are two main complications:
*   The FGC questions were only asked for a subsample (about 1/3) and the analysis must be
*      limited to the subsample with g100=0 or g100=1 (remove if g100=.)
*   All the daughters age 0-14 must be in the denominator, including those whose mothers have
*      g100=0; just those with g121=1 go into numerator
*      the numerator


* PREPARE THE IR FILE
set more off
use v001 v002 v003 gidx_* g121_* using NGIR7AFL.DTA , clear

rename *_0* *_*

* RESHAPE THE IR FILE SO THERE IS ONE RECORD PER DAUGHTER
reshape long gidx_ g121_, i(v001 v002 v003) j(sequence)
drop sequence
rename *_ *
drop if gidx==.
rename gidx bidx
gen in_IR=1

sort v001 v002 v003 bidx
save NGIRtemp.dta, replace

* PREPARE THE BR FILE
use NGBR7AFL.DTA , clear
* Identify girls, living and age 0-14 (b15==1 is redundant)
keep if b4==2 & b5==1 & b8<=14

* Crucial line to drop the mothers and daughters who did not get the long questionnaire
* drop the girl if the g question were not asked of her mother
drop if g100==.

keep v001 v002 v003 v005 bidx b8
gen age5=1+int(b8/5)
label define age5 1 "0-4" 2 "5-9" 3 "10-14"
label values age5 age5

* in_BR identifies a daughter who is eligible for a g121 code
gen in_BR=1

* MERGE THE BR FILE WITH THE RESHAPED IR FILE
sort v001 v002 v003 bidx
merge v001 v002 v003 bidx using NGIRtemp.dta
tab _merge
drop _merge

label define g121 0 "No" 1 "Yes"
label values g121 g121

* Some girls in the BR file do not have a value on g121 because their mothers had not heard of fgc.
* Crucial line to get the correct denominator
replace g121=0 if in_IR==. & in_BR==1

* Unweighted
tab age5 g121,m

* Weighted
tab age5 [iweight=v005], summarize(g121)