There are three columns for Table 8.5: Percent of births by risk category, relative risk category, and percent of married women by risk category.
There are single and multiple risk categories (rows of the table). For the third column, the risks categories are those that women would have if they became pregnant. Therefore, women who have no children and are between 17 years, 3 months of age and 34 years, 2 months of age would be those for question 1 (risk category 2).
Question 2: For the first two columns, the preceding birth interval is standard recode variable b11 <24 if there were 2 or more births (months of the preceding birth interval--twins, triplets have the same value to the birth of a preceding pregnancy). For the third column, the preceding birth interval is standard recode variable v222<15 if there were 1 or more births (months between last birth and interview).

Here is the CSPRO code for Table 8.5
for ch in REC21_EDT do
months = V008 - B3(ch);
if months < 60 then { For all children born }
agemoth = int( (B3-V011)/12 ); { in the last five years }
agemo18 = ( agemoth < 18 );
agemo34 = ( agemoth > 34 );
inter24 = 0;
if !special(B11) then
inter24 = ( B11 < 24 );
endif;
{ adjust multiple births to give the same order as that of the first of the multiples }
xorder = BORD;
if B0 > 1 then xorder = BORD - B0 + 1 endif;
bord3 = ( xorder > 3 );
frstb = ( xorder = 1 );
box agemo18 : agemo34 : inter24 : bord3 : frstb => rowt805;
0 : 0 : 0 : 0 : 0 => 1; { no risk }
0 : 0 : 0 : 0 : 1 => 2; { unavoidable risk }
1 : 0 : 0 : 0 : => 3; { single risk }
0 : 1 : 0 : 0 : => 4;
0 : 0 : 1 : 0 : => 5;
0 : 0 : 0 : 1 : => 6;
1 : 0 : 1 : 0 : => 7; { multiple risk }
1 : 0 : 0 : 1 : => 7;
1 : 0 : 1 : 1 : => 7;
0 : 1 : 1 : 0 : => 8;
0 : 1 : 0 : 1 : => 9;
0 : 1 : 1 : 1 : => 10;
0 : 0 : 1 : 1 : => 11;
: : : : => default;
endbox;
box rowt805 => norisk;
1 => rowt805;
=> notappl;
endbox;
box rowt805 => unavoid;
2 => rowt805 - 1;
=> notappl;
endbox;
box rowt805 => singrisk;
3-6 => rowt805 - 2;
=> notappl;
endbox;
box rowt805 => multrisk;
7-11 => rowt805 - 6;
=> notappl;
endbox;
currmar1 = notappl;
colt805 = 1;
xtab( t805, rweight );
if B5 <> 1 then { For dead children }
colt805 = 2;
xtab( t805, rweight );
endif;
endif;
enddo;

if V502 = 1 then { For currently married women }
colt805 = notappl;
currmar1 = 1;
agemoth = V008 - V011;
agemo18 = ( agemoth < 17*12+3 );
agemo34 = ( agemoth > 34*12+2 );
inter24 = 0;
if V201 > 0 then
inter24 = ( V222 < 15 );
endif;
bord3 = ( V201 > 2 );
frstb = ( V201 = 0 );
box agemo18 : agemo34 : inter24 : bord3 : frstb => rowt805;
0 : 0 : 0 : 0 : 0 => 1; { no risk }
0 : 0 : 0 : 0 : 1 => 2; { unavoidable risk }
1 : 0 : 0 : 0 : => 3; { single risk }
0 : 1 : 0 : 0 : => 4;
0 : 0 : 1 : 0 : => 5;
0 : 0 : 0 : 1 : => 6;
1 : 0 : 1 : 0 : => 7; { multiple risk }
1 : 0 : 0 : 1 : => 7;
1 : 0 : 1 : 1 : => 7;
0 : 1 : 1 : 0 : => 8;
0 : 1 : 0 : 1 : => 9;
0 : 1 : 1 : 1 : => 10;
0 : 0 : 1 : 1 : => 11;
: : : : => default;
endbox;
if V312 = 6 then rowt805 = 1 endif;
box rowt805 => norisk;
1 => rowt805;
=> notappl;
endbox;
box rowt805 => unavoid;
2 => rowt805 - 1;
=> notappl;
endbox;
box rowt805 => singrisk;
3-6 => rowt805 - 2;
=> notappl;
endbox;
box rowt805 => multrisk;
7-11 => rowt805 - 6;
=> notappl;
endbox;
xtab( t805, rweight );
endif;

HIGH-RISK FERTILITY BEHAVIOR RISK RATIOS
Statistics: Ratio of Children in Elevated Fertility Behavior Risk Categories to Children in
Non-Elevated Risk Category
Definition
A. Coverage:
1. Population base: Children born to all women.
2. Time period: Births in the five years preceding the survey.
B. Numerator: Proportion of dead children born in the five years preceding the survey by risk
category.
C. Denominator: Proportion dead of children in non-elevated risk category.
D. Elevated-behavior fertility risk categories:
1. Children born to mothers under age 18 years.
2. Children born to mothers 35 years and older.
3. Children of birth order 4 or higher.
4. Children born less than 24 months since a preceding birth.
E. Unavoidable elevated risk category--First birth order children born to mothers between ages 18
and 34 years.
F. Children not in any elevated risk category
1. Second- and third-birth-order children born to mothers between ages 18 and 34 years
2. The elevated risk categories are also combined into two-way and three-way combinations of
elevated risk.
Calculation
A. To calculate relative risk ratios by categories of elevated risk due to fertility behavior, first the
proportions dead for each category need to be calculated. For each proportion--
1. Numerator: Number of children born in the five years preceding the survey who died at
any age.
2. Denominator: Number of children born in the five years preceding the survey.
3. Proportion dead: Numerator divided by denominator.

B. Then the ratio of the proportions need to be calculated:
1. Risk ratio Numerator: Proportion dead among children in each risk category.
2. Risk ratio denominator: Proportion dead among children not in any elevated risk category
(see definition above).
3. Relative risk ratios: Risk category numerators divided by the non-elevated risk category
denominator.
Handling of Missing Values
None of the information needed to calculate relative risk ratios is allowed to have missing or unknown
data. Note that age at death is not used, only survival status at the time of the survey.
Notes and Considerations
To provide a more robust estimate of the elevated relative risk, proportions dead are used instead of
period mortality rates in the calculation of relative risk, since period mortality rates have higher sampling
errors. In DHS reports, risk ratios are not shown where the proportion dead is based on fewer than 25
births. Risk ratios where the proportion dead is based on 25 to 49 births are placed in parentheses to
indicate large variability due to sampling.
Assumptions
It is assumed that the number of births and death rates do not vary substantially by time period within the
preceding five years.
Changes over Time
Originally, the denominator for the risk ratio included the unavoidable risk category of first-order births to
mothers between 18 and 24 years of age.

For children's level analysis, use the Children's Recode (KR). This dataset has one record for every child of eligible women, born in the last five years. It contains the information related to the child's pregnancy and postnatal care and immunization and health. The data for the mother of each of these children is included. This file is used to look at child health indicators such as immunization coverage, vitamin A supplementation, and recent occurrences of diarrhea, fever, and cough for young children and treatment of childhood diseases. The unit of analysis (case) in this file is the children of women born in the last 5 years (0-59 months).

For births' level analysis, use the All Children's Recode (BR). This dataset has one record for every child ever born of eligible women. Essentially, it is the full birth history of all women interviewed including its information on pregnancy and postnatal care as well as immunization and health for children born in the last 5 years. Data for the mother of each of these children is also included. This file can be used to calculate health indicators as well as fertility and mortality rates. The unit of analysis (case) in this file is the children ever born of eligible women.