| KDHS 2014 : Percentage of men who have ever experienced physical violence since age 15 [message #28149] |
Sun, 19 November 2023 00:04  |
sokiya
Messages: 78
Registered: May 2017
Location: Nairobi
|
Senior Member |
|
|
Hi
I am trying to generate the indicator reported in the first column of the Table 16.1.2 - Percentage who have ever experienced physical violence since age 15 using the syntax below
use "KEMR72FL.DTA", clear
cap gen dwt = md005/1000000
cap label define yesno 0 "no" 1 "yes" //for all yes/no binary variables
**EXPERIENCED PHYSICAL VIOLENCE
//ever
gen dv_phy = 0 if mv044==1
foreach z in a b c d e f g h i j k l m n {
replace dv_phy = 1 if md105`z'>=1 & md105`z'<=4 //violence by current partner
}
replace dv_phy = 1 if md130a>=1 & md130a<=4 //violence by former partner
replace dv_phy = 1 if md115y==0 //violence by anyone other than partner
*replace dv_phy = 1 if d118y==0 //violence during pregnancy
label var dv_phy "Experienced physical violence since age 15"
label val dv_phy yesno
//in the last 12 months
gen dv_phy_12m = 0 if mv044==1
foreach z in a b c d e f g h i j k l m n {
replace dv_phy_12m = 1 if md105`z'==1 | md105`z'==2
}
replace dv_phy_12m = 1 if md117a==1 | md117a==2 | md130a==1
label val dv_phy_12m yesno
label var dv_phy_12m "Experienced physical violence in past 12 mos"
replace dv_phy = 100 if dv_phy == 1
tabstat dv_phy [aw=dwt] if inrange(mv013, 1, 7), statistics(mean) save
I am finding the value 44.32217 for those aged 15-49 whereas the table reports 43.9.
Any help will be appreciated. Thanks in advance
|
|
|
|
| Re: KDHS 2014 : Percentage of men who have ever experienced physical violence since age 15 [message #28166 is a reply to message #28149] |
Tue, 21 November 2023 09:13  |
Bridgette-DHS
Messages: 3199
Registered: February 2013
|
Senior Member |
|
|
Following is a response from Senior DHS staff member, Tom Pullum:
Here is the Stata code for the first column of table 16.1.2 in the Kenya 2014 report. The code for women (table 16.1.1) is the same except the mv variables for men are v variables for women. I had to go back to the original CSPro code. For some covariates, there is one category for which my estimate is a little lower than the final report. There may still be something missing but I cannot put more time into this. You can modify this to get the other columns of the table.
* Kenya 2014, Domestic Violence Module
* MEN: Table 16.1.2
use "C:\Users\26216\ICF\Analysis - Shared Resources\Data\DHSdata\KEMR72FL.DTA", clear
* Construct indicator for first column, ever violence
gen dv_phy=0 if mv044==1
foreach ll in a b c d e f {
replace dv_phy=1 if md105`ll'<. & md105`ll'>0
}
replace dv_phy=1 if md115y==0
replace dv_phy=1 if md118y==0
replace dv_phy=1 if md130a<. & md130a>0
* Some recodes of covariates
gen age5=mv013
replace age5=4 if mv013>4
replace age5=5 if mv013>5
label define age5 1 "15-19" 2 "20-24" 3 "25-29" 4 "30-39" 5 "40-49"
label values age5 age5
gen marstat=mv501
replace marstat=1 if mv501==2
replace marstat=2 if mv501>2
label define marstat 0 "Never married" 1 "Married" 2 "Divorced, etc."
label values marstat marstat
* Distributions for first column (not complete)
tab age5 dv_phy if mv013<=7 [iweight=md005/1000000], row
tab mv130 dv_phy if mv013<=7 [iweight=md005/1000000], row
tab mv025 dv_phy if mv013<=7 [iweight=md005/1000000], row
tab mv024 dv_phy if mv013<=7 [iweight=md005/1000000], row
tab marstat dv_phy if mv013<=7 [iweight=md005/1000000], row
tab mv149 dv_phy if mv013<=7 [iweight=md005/1000000], row
tab mv190 dv_phy if mv013<=7 [iweight=md005/1000000], row
summarize dv_phy if mv013==8 [iweight=md005/1000000]
summarize dv_phy [iweight=md005/1000000]
|
|
|
|
|
|
The DHS Program User Forum
Members
Search
Help
Register
Login
Home
