|
|
|
|
|
|
| Re: respondents not visiting health facility [message #25420 is a reply to message #25384] |
Mon, 17 October 2022 12:14   |
Bridgette-DHS
Messages: 3188
Registered: February 2013
|
Senior Member |
|
|
Following is a response from DHS staff member, Tom Pullum:
You already asked about Table 11.20, in August. As I said then, this table is based on s361 and s368 in the IR file, and sm320 in the MR file. The questions are about individuals, not households. To construct a household-level version, you would have to allow for the possibility that there are no women, or no men, in the household. There can be more than one women or more than one man. The individual women or men will give different responses. The men are in a 1/6 subsample of households. In the households for which men were not sampled, the household-level classification would depend solely on the responses for women.
I can help if you will be more specific. How about calculating the following?
"Percentage of households with at least one woman who had any contact with a health worker in the past 3 months"
"Percentage of households with at least one woman who visited a health facility or camp in the past 3 months"
"Percentage of households with at least one man who visited a health facility or camp in the past 3 months"
If that's what you want, I can show you how to do it.
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
| Re: respondents not visiting health facility [message #25480 is a reply to message #25479] |
Wed, 26 October 2022 11:46 |
Bridgette-DHS
Messages: 3188
Registered: February 2013
|
Senior Member |
|
|
Following is a response from DHS staff member, Tom Pullum:
I think the problem is that v024 (or other covariates) must be included in the "collapse" command, after "(first)". Otherwise the covariate is lost. The following should do what you want.
use "...IAIR7DFL.DTA",clear
gen reg=v024
gen cluster=v001
gen hh=v002
gen line=v003
gen s361_yes=1 if s361==1
gen s361_no =1 if s361==0
gen s368_yes=1 if s368==1
gen s368_no =1 if s368==0
* Collapse to get the numbers of yes and no responses within households
collapse (sum) s361_* s368_* (first) v005 v024, by(reg cluster hh)
* Must re-attach the values label after the collapse
label values v024 V024
* The units of analysis are households with at least one woman who has a response to s361
tab s361_yes s361_no [iweight=v005/1000000]
gen s361_yes_1plus=0 if s361_yes+s361_no>0
replace s361_yes_1plus=1 if s361_yes>1
tab v024 s361_yes_1plus [iweight=v005/1000000], row
* The units of analysis are households with at least one woman who has a response to s368
tab s368_yes s368_no [iweight=v005/1000000]
gen s368_yes_1plus=0 if s368_yes+s368_no>0
replace s368_yes_1plus=1 if s368_yes>1
tab v024 s368_yes_1plus [iweight=v005/1000000], row
use "...IAMR7DFL.DTA",clear
gen reg=mv024
gen cluster=mv001
gen hh=mv002
gen line=mv003
gen sm320_yes=1 if sm320==1
gen sm320_no =1 if sm320==0
* Collapse to get the numbers of yes and no responses within households
collapse (sum) sm320_* (first) mv005 mv024, by(reg cluster hh)
* Must re-attach the values label after the collapse
label values mv024 MV024
* The units of analysis are households with at least one man who has a response to sm320
tab sm320_yes sm320_no [iweight=mv005/1000000]
gen sm320_yes_1plus=0 if sm320_yes+sm320_no>0
replace sm320_yes_1plus=1 if sm320_yes>1
tab mv024 sm320_yes_1plus [iweight=mv005/1000000], row
|
|
|
|
|
|
The DHS Program User Forum
Members
Search
Help
Register
Login
Home
