The DHS Program User Forum: Biomarkers

Home » Topics » Biomarkers » BMI (Missing data on BMI)

Show: Today's Messages :: Show Polls :: Message Navigator

Re: BMI [message #19382 is a reply to message #19355]

Mon, 08 June 2020 17:34

Trevor-DHS
Messages: 805
Registered: January 2013

Senior Member

Calculating the BMI to match the South Africa report figure 17.1 is unfortunately not that simple. In this survey the BMI is calculated for women age 15+, not just woman age 15-49 (which is the standard approach used by DHS). In this survey an additional Adult Health module was included in a sample of roughly half of the households. The data for the adult health module can be found in the file ZAAH71DT.zip. In this file you will find two datasets - one for women (ZAAHW71FL.dta) and one for men (ZAAHM71FL.dta). You will need to use the women's file and link it to the IR file, and then again to the PR file to produce the estimate that you want. See the code below:

cd "your working directory"
* use the Adult Health module data
use "ZAAHW71FL.DTA", clear

* merge in data from IR file to get v213, v208 and b19_01 that are needed below
merge 1:1 caseid using "ZAIR71FL.dta"
rename _merge merge1

* create a household id and line number for matching to the PR file
gen hhid = substr(caseid,1,12)
gen hvidx = v003

* merge the PR file into the Adult Health module data
merge 1:1 hhid hvidx using "ZAPR71FL.DTA"
drop if _merge != 3

* calculate obesity for women who are not pregnant and have not had a birth in the prior 2 months (and have a valid BMI)
* for women older than 49 the assumption is that they are not pregnant and have not had a birth in the past 2 months
gen obese = (ha40>=3000 & ha40<=6000) if v213!=1 & (v208 == 0 | b19_01 >= 2) & (ha40>=1200 & ha40<=6000) 

* tabulate obesity for the total sample of women and for women 15-49 alone.
tab obese [iw=sweight/1000000]
tab obese [iw=sweight/1000000] if v012 < 50

You will notice also that a different weight has been used here (sweight). This is a weight used for the subsample for the Adult Health module.

Report message to a moderator

[Message index]

		BMI By: Nomvelo on Tue, 07 May 2019 14:35
		Re: BMI By: Liz-DHS on Fri, 15 November 2019 12:12
		Re: BMI By: Frankfeng on Wed, 03 June 2020 11:57
		Re: BMI By: Liz-DHS on Wed, 03 June 2020 12:12
		Re: BMI By: Frankfeng on Thu, 04 June 2020 05:30
		Re: BMI By: Trevor-DHS on Mon, 08 June 2020 17:34
		Re: BMI By: Frankfeng on Tue, 09 June 2020 06:27
		Re: BMI By: Trevor-DHS on Tue, 09 June 2020 13:13

Previous Topic:	Anemia variable in MR
Next Topic:	Diabetes in SADHS 2016

Goto Forum:

-=] Back to Top [=-

[ Syndicate this forum (XML) ] [

] [

]

Current Time: Tue Aug 12 09:21:04 Coordinated Universal Time 2025