The DHS Program User Forum: HIV » comprehensive knowledge of HIV AIDS

Home » Topics » HIV » comprehensive knowledge of HIV AIDS

Show: Today's Messages :: Show Polls :: Message Navigator

comprehensive knowledge of HIV AIDS [message #6893]

Wed, 29 July 2015 15:30

cmjacob
Messages: 1
Registered: July 2015
Location: United Kingdom

Member

I am doing a secondary data analysis of Women's empowerment and HIV-KAB in Zambia and my outcome measure is 'comprehensive knowledge (CK) of HIV aids. I intend to use binary logistic regression for the study and have tried to create the CK variable on SPSS. However I am not able to create it as a 1/0 variable. I have found certain other studies that have used this variable as an outcome measure but they have used stata for the same.
I was wondering if it is possible to create a 1/0 variable on SPSS for comprehensive knowledge (I tried using Compute new variable - and gave the IF command to check if answers to the 5 questions about HIV, were answered correctly ; and also recode into new variable - but it did not work.)
If someone has created this variable on SPSS before it would be great if you could share the syntax with me.

Report message to a moderator

Re: comprehensive knowledge of HIV AIDS [message #6949 is a reply to message #6893]

Thu, 06 August 2015 10:34

Liz-DHS
Messages: 1516
Registered: February 2013

Senior Member

Dear User,
We have submitted your query to one of our experts. As soon as we have a response, we will post.
Thank you!

Report message to a moderator

Re: comprehensive knowledge of HIV AIDS [message #6953 is a reply to message #6949]

Thu, 06 August 2015 12:15

Trevor-DHS
Messages: 805
Registered: January 2013

Senior Member

Try the following code:

* A healthy-looking person can have the AIDS virus.
IF (V756 = 1) Healthy = 1.
VARIABLE LABELS Healthy "A healthy-looking person can have the AIDS virus".
VALUE LABELS Healthy 1 "A healthy-looking person can have the AIDS virus".

* The AIDS  virus cannot be transmitted by mosquito bites [COUNTRY SPECIFIC].
IF (V754JP = 0) Mosquito = 1.
VARIABLE LABELS Mosquito "The AIDS  virus cannot be transmitted by mosquito bites [COUNTRY SPECIFIC]".
VALUE LABELS Mosquito 1 "The AIDS  virus cannot be transmitted by mosquito bites [COUNTRY SPECIFIC]".

* The AIDS virus cannot be transmitted by supernatural means [COUNTRY SPECIFIC] .
IF (V823 = 0) SNmeans = 1.
VARIABLE LABELS SNmeans "The AIDS virus cannot be transmitted by supernatural means [COUNTRY SPECIFIC]".
VALUE LABELS SNmeans 1 "The AIDS virus cannot be transmitted by supernatural means [COUNTRY SPECIFIC]".

* A person cannot become infected by sharing food with a person who has the AIDS virus [COUNTRY SPECIFIC] .
IF (V754WP = 0) Sfood = 1.
VARIABLE LABELS SFood "A person cannot become infected by sharing food with a person who has the AIDS virus [COUNTRY SPECIFIC]".
VALUE LABELS SFood 1 "A person cannot become infected by sharing food with a person who has the AIDS virus [COUNTRY SPECIFIC]".

* The two most common local misconception.
* Need to pick the two most common misconceptions - typically mosquito bites and sharing food - but this can vary from survey to survey.
COUNT MSConcep = mosquito, Sfood (1).
*COUNT MSConcep = mosquito, SNMeans (1).

* A healthy-looking person can have the AIDS virus and who reject the two most common local misconceptions.
IF (Healthy = 1 & MSConcep = 2) MCReject = 1.
VARIABLE LABELS MCReject "".
VALUE LABELS MCReject 1 "Percentage who say that a healthy-looking person can have the AIDS virus and who reject the two most common local misconceptions".

* Percentage with a comprehensive knowledge about AIDS.
IF (V754CP = 1 & V754DP = 1 & Healthy = 1 & MSConcep = 2) knowAIDS = 1.
VARIABLE LABELS knowAIDS "".
VALUE LABELS knowAIDS 1 "Percentage with a comprehensive knowledge about AIDS".

Note that the selection for the two most common mis-conceptions in the middle of the code is survey specific, and will vary from country to country.

Report message to a moderator

Re: comprehensive knowledge of HIV AIDS [message #10653 is a reply to message #6953]

Thu, 25 August 2016 17:25

CKAllen
Messages: 7
Registered: April 2016
Location: London, UK

Member

Does anyone know what the two most common local misconceptions are for Zambia 2007?
On page xxvii of the ZDHS report, it reports 'sharing food' and 'mosquito bites' as the two most common local misconceptions.
On page 192 and 193, it reports 'supernatural means' and 'mosquito bites' as the two most common local misconceptions.

I found similar inconsistencies in 2013 ZDHS report.

Report message to a moderator

Re: comprehensive knowledge of HIV AIDS [message #10660 is a reply to message #10653]

Fri, 26 August 2016 14:33

Liz-DHS
Messages: 1516
Registered: February 2013

Senior Member

A response from Senior Technical Expert, Dr. Kia Reinis:
Quote:

Dear CK Allen,
Thank you for your question.

The misconceptions pertaining to means of transmission that are the two most common: people can get HIV from mosquito bites and people can get HIV from witchcraft or other supernatural means. This is true in both the 2007 and 2013-14, and the data in the chapter tables indicate such.

Footnote 8 in the MDG table in the 2007 report is in error, it should have referred to supernatural means, and not to sharing food.
The text on page 199 of the 2013-14 report is not correct. The excerpt from the report (shown below) that states sharing food is one of the two most common misconceptions is an error, it should have stated "that a person can get HIV via supernatural means" and not "by sharing food".

Thank you very much for bringing this to our attention.
We appreciate your use of DHS data.

Attachment: ZM2007pg199.jpg
(Size: 60.07KB, Downloaded 2160 times)

[Updated on: Fri, 26 August 2016 19:11] by Moderator

Report message to a moderator

Re: comprehensive knowledge of HIV AIDS [message #10662 is a reply to message #10660]

Sat, 27 August 2016 10:22

CKAllen
Messages: 7
Registered: April 2016
Location: London, UK

Member

Thank you, Dr. Reinis for such a quick response. This will clear up which variables to use. Very helpful!

Report message to a moderator

Re: comprehensive knowledge of HIV AIDS [message #11571 is a reply to message #6953]

Wed, 11 January 2017 11:01

enansubuga
Messages: 3
Registered: January 2017
Location: Uganda

Member

Dear Trevor,

Is it possible to have the STATA syntax for comprehensive knowledge. I guess I can better understand the recoding of variables in STATA.

Thank you.

Elizabeth

Report message to a moderator

Re: comprehensive knowledge of HIV AIDS [message #12350 is a reply to message #11571]

Wed, 03 May 2017 22:37

Trevor-DHS
Messages: 805
Registered: January 2013

Senior Member

Its a pretty easy conversion of the SPSS code to Stata, but here it is:

* A healthy-looking person can have the AIDS virus.
gen healthy = 1 if v756 == 1
label var healthy "A healthy-looking person can have the AIDS virus"
label def Healthy 1 "A healthy-looking person can have the AIDS virus"
label val healthy Healthy

* The AIDS virus cannot be transmitted by mosquito bites [COUNTRY SPECIFIC].
gen mosquito = 1 if v754jp == 0 
label var mosquito "The AIDS virus cannot be transmitted by mosquito bites [COUNTRY SPECIFIC]"
label def Mosquito 1 "The AIDS virus cannot be transmitted by mosquito bites [COUNTRY SPECIFIC]"
label val mosquito Mosquito

* The AIDS virus cannot be transmitted by supernatural means [COUNTRY SPECIFIC] .
gen snmeans = 1 if v823 == 0
label var snmeans "The AIDS virus cannot be transmitted by supernatural means [COUNTRY SPECIFIC]"
label def SNmeans 1 "The AIDS virus cannot be transmitted by supernatural means [COUNTRY SPECIFIC]"
label val snmeans SNmeans

* A person cannot become infected by sharing food with a person who has the AIDS virus [COUNTRY SPECIFIC] .
gen sfood = 1 if v754wp == 0 
label var sfood "A person cannot become infected by sharing food with a person who has the AIDS virus [COUNTRY SPECIFIC]"
label def SFood 1 "A person cannot become infected by sharing food with a person who has the AIDS virus [COUNTRY SPECIFIC]"
label val sfood SFood

* The two most common local misconception.
* Need to pick the two most common misconceptions - typically mosquito bites and sharing food - but this can vary from survey to survey.
gen msconcep = 0
replace msconcep = 1 if mosquito == 1
* if sharing food is more a more common misconception than supernatural means, use the next line
replace msconcep = msconcep + 1 if sfood == 1
* if supernatural means is a more common misconception than sharing food, use the next line instead
*replace msconcep = msconcep + 1 if snmeans == 1

* A healthy-looking person can have the AIDS virus and who reject the two most common local misconceptions.
gen mcreject = 0
replace mcreject = 1 if healthy == 1 & msconcep == 2
label var mcreject "Percentage who say that a healthy-looking person can have the AIDS virus and who reject the two most common local misconceptions"
label def MCReject 1 "Percentage who say that a healthy-looking person can have the AIDS virus and who reject the two most common local misconceptions"
label val mcreject MCReject

* Percentage with a comprehensive knowledge about AIDS.
gen knowaids = 0.
replace knowaids = 1 if v754cp == 1 & v754dp == 1 & healthy == 1 & msconcep == 2
label var knowaids "Percentage with a comprehensive knowledge about AIDS"
label def knowAIDS 1 "Percentage with a comprehensive knowledge about AIDS"
label val knowaids knowAIDS

For Zambia 2007 where supernatural means is a more common misconception than sharing food, comment out the replace command for sfood, and uncomment the replace command for snmeans instead.

Report message to a moderator

Re: comprehensive knowledge of HIV AIDS [message #16392 is a reply to message #6953]

Mon, 07 January 2019 00:37

kamal.chaulagain123@gmail is currently offline

kamal.chaulagain123@gmail
Messages: 4
Registered: January 2019

Member

Dear All,
Can I please get the STATA command for creating comprehensive knowledge on HIV/AIDS? Thank you in advance.

Report message to a moderator

Re: comprehensive knowledge of HIV AIDS [message #16394 is a reply to message #16392]

Mon, 07 January 2019 08:47

Mlue
Messages: 92
Registered: February 2017
Location: North West

Senior Member

Hello kamal.chaulagain123@gmail

Please see the code below... The code is a bit different to the ones shown above.

I assume you are looking for the code that replicates the figures in the Nepal DHS of 2016.

WOMEN

/*

	COMPREHENSIVE KNOWLEDGE ABOUT HIV
	WOMEN FILE
	NEPAL DHS 2016
	
*/

clear all
set more off
set maxvar 9000
set mem 1g
set matsize 800
cd "..."
use "NPIR7HFL", clear
set more off
version 14.2
dtaversion "NPIR7HFL.dta"
pwd

***************************************************************************
** WEIGHT VARIABLE
gen weight = v005/1000000

********************************************************************************

** SURVEY SET
gen psu =    v021
gen strata = v023

svyset psu [pw = weight], strata(strata) vce(linearized)

********************************************************************************
// RENAME

rename v013 age
rename v106 education
rename v190 wealth
rename v025 residence
rename v024 region
rename sdist district

////////////////////////////////////////////////////////////////////////////////

/*

** VARIABLES


v756		A healthy looking person can have HIV (women)
v754jp		Can get HIV from mosquito bites (women)
v754wp		Can get HIV by sharing food with person who has AIDS (women)
v823		Can get HIV by witchcraft or supernatural means (women)
v005		Woman's individual sample weight

********************************************************************************

mv756		A healthy looking person can have HIV (men)
mv754jp		Can get HIV from mosquito bites (men)
mv754wp		Can get HIV by sharing food with person who has AIDS (men)
mv823		Can get HIV by witchcraft or supernatural means (men)
mv005		Man's individual sample weigh

*/

cap drop age2
recode v012 (15/24=1 "15-24") (25/29=2 "25-29") (30/39=3 "30-39") (40/49=4 "40-49"), gen(age2)
label var age2 "Current age"
label val age2 age2

********************************************************************************

** INDICATORS

** 01. A HEALTHY-LOOKING PERSON CAN HAVE THE AIDS VIRUS
recode v756 (1=1 "Yes") (else=0 "No"), gen(healthy_look_HIV)
label var healthy_look_HIV "Knows that a healthy-looking person can have HIV"
label val healthy_look_HIV healthy_look_HIV

svy: tab age2 healthy_look_HIV, count format(%4.0f)
svy: tab age2 healthy_look_HIV, percent format(%4.1f) row

*****************

** 02. HIV CANNOT BE TRANSMITTED BY MOSQUITO BITES
recode v754jp (0=1 "Yes") (else=0 "No"), gen(transmit_mosquito_bites)
label var transmit_mosquito_bites "Knows that HIV cannot be transmitted by mosquito bites"
label val transmit_mosquito_bites transmit_mosquito_bites

svy: tab age2 transmit_mosquito_bites, count format(%4.0f)
svy: tab age2 transmit_mosquito_bites, percent format(%4.1f) row

*****************

/*
** 03. HIV CANNOT BE TRANSMITTED BY SUPERNATURAL MEANS
recode v823 (0=1 "Yes") (else=0 "No"), gen(transmit_witchcraft)
label var transmit_witchcraft "Knows that HIV cannot be transmitted by supernatural means (witchcraft)"
label val transmit_witchcraft transmit_witchcraft

svy: tab age2 transmit_witchcraft, count format(%4.0f)
svy: tab age2 transmit_witchcraft, percent format(%4.1f) row
*/

*****************

** 03. HIV CANNOT BE TRANSMITTED BY TOUCHING SOMEONE WHO HAS HIV
recode s1006 (0=1 "Yes") (else=0 "No"), gen(transmit_touching)
label var transmit_touching "Knows that HIV cannot be transmitted by touching someone who has HIV"
label val transmit_touching transmit_touching

svy: tab age2 transmit_touching, count format(%4.0f)
svy: tab age2 transmit_touching, percent format(%4.1f) row

*****************

** 04. A PERSON CANNOT BECOME INFECTED BY SHARING FOOD WITH A PERSON WHO HAS HIV
recode v754wp (0=1 "Yes") (else=0 "No"), gen(sharing_food_HIV)
label var sharing_food_HIV "Knows that a person cannot become infected by sharing food with a person who has HIV"
label val sharing_food_HIV sharing_food_HIV

svy: tab age2 sharing_food_HIV, count format(%4.0f)
svy: tab age2 sharing_food_HIV, percent format(%4.1f) row

*****************

** 05. Persons who say that a healthy looking person can have the AIDS virus and who reject the two most common local misconceptions
/* 
	Two most common local misconceptions: the AIDS virus can be transmitted by 
	mosquito bites and a person can become infected by sharing food with a 
	person who has AIDS. 
*/

gen reject_misconceptions = 0
replace reject_misconceptions = 1 if healthy_look_HIV == 1 & (transmit_mosquito_bites == 1 & sharing_food_HIV == 1)
label define reject_misconceptions 0"No" 1"Yes"
label var reject_misconceptions "A healthy looking person can have the AIDS virus - reject the two most common local misconceptions"
label val reject_misconceptions reject_misconceptions

svy: tab age2 reject_misconceptions, count format(%4.0f)
svy: tab age2 reject_misconceptions, percent format(%4.1f) row

** ========================================================================== **
** ========================================================================== **
** ========================================================================== **

** 06. HIV PREVENTION METHODS
cap drop prevention_methods
gen prevention_methods = 0
replace prevention_methods = 1 if v754cp == 1 & v754dp == 1
label define prevention_methods 0"No" 1"Yes"
label var prevention_methods "Knows both prevention methods"
label val prevention_methods reject_misconceptions

svy: tab age2 prevention_methods, count format(%4.0f)
svy: tab age2 prevention_methods, percent format(%4.1f) row

*****************

** 07. COMPEHENSIVE KNOWLEDGE ABOUT HIV
/* 
	Two most common local misconceptions: the AIDS virus can be transmitted by 
	mosquito bites and a person can become infected by sharing food with a 
	person who has AIDS. 
*/

cap drop comprehensive_HIV
gen comprehensive_HIV = 0
replace comprehensive_HIV = 1 if (prevention_methods == 1 & healthy_look_HIV == 1) & (transmit_mosquito_bites == 1 & sharing_food_HIV == 1)
label define comprehensive_HIV 0"No" 1"Yes"
label var comprehensive_HIV ""
label val comprehensive_HIV comprehensive_HIV

svy: tab age2 comprehensive_HIV, count format(%4.0f)
svy: tab age2 comprehensive_HIV, percent format(%4.1f) row

** ========================================================================== **

keep if healthy_look_HIV != .

** ========================================================================== **


exit

MEN

/*

	COMPREHENSIVE KNOWLEDGE ABOUT HIV
	MEN FILE
	NEPAL DHS 2016
	
*/

clear all
set more off
set maxvar 9000
set mem 1g
set matsize 800
cd "..."
use "NPMR7HFL", clear
set more off
version 14.2
dtaversion "NPMR7HFL.dta"
pwd

***************************************************************************
** WEIGHT VARIABLE
gen weight = mv005/1000000

********************************************************************************

** SURVEY SET
gen psu =    mv021
gen strata = mv023

svyset psu [pw = weight], strata(strata) vce(linearized)

********************************************************************************
// RENAME

rename mv013 age
rename mv106 education
rename mv190 wealth
rename mv025 residence
rename mv024 region
rename smdist district

////////////////////////////////////////////////////////////////////////////////

/*

** VARIABLES

mv756		A healthy looking person can have HIV (men)
mv754jp		Can get HIV from mosquito bites (men)
sm706		can get hiv by touching someone
mv754wp		Can get HIV by sharing food with person who has AIDS (men)
mv823		Can get HIV by witchcraft or supernatural means (men)
mv005		Man's individual sample weigh

*/

cap drop age2
recode mv012 (15/24=1 "15-24") (25/29=2 "25-29") (30/39=3 "30-39") (40/49=4 "40-49"), gen(age2)
label var age2 "Current age"
label val age2 age2

********************************************************************************

** INDICATORS

** 01. A HEALTHY-LOOKING PERSON CAN HAVE THE AIDS VIRUS
recode mv756 (1=1 "Yes") (else=0 "No"), gen(healthy_look_HIV)
label var healthy_look_HIV "Knows that a healthy-looking person can have HIV"
label val healthy_look_HIV healthy_look_HIV

svy: tab age2 healthy_look_HIV, count format(%4.0f)
svy: tab age2 healthy_look_HIV, percent format(%4.1f) row

*****************

** 02. HIV CANNOT BE TRANSMITTED BY MOSQUITO BITES
recode mv754jp (0=1 "Yes") (else=0 "No"), gen(transmit_mosquito_bites)
label var transmit_mosquito_bites "Knows that HIV cannot be transmitted by mosquito bites"
label val transmit_mosquito_bites transmit_mosquito_bites

svy: tab age2 transmit_mosquito_bites, count format(%4.0f)
svy: tab age2 transmit_mosquito_bites, percent format(%4.1f) row

*****************

/*
** 03. HIV CANNOT BE TRANSMITTED BY SUPERNATURAL MEANS
recode mv823 (0=1 "Yes") (else=0 "No"), gen(transmit_witchcraft)
label var transmit_witchcraft "Knows that HIV cannot be transmitted by supernatural means (witchcraft)"
label val transmit_witchcraft transmit_witchcraft

svy: tab age2 transmit_witchcraft, count format(%4.0f)
svy: tab age2 transmit_witchcraft, percent format(%4.1f) row
*/

*****************

** 03. HIV CANNOT BE TRANSMITTED BY TOUCHING SOMEONE WHO HAS HIV
recode sm706 (0=1 "Yes") (else=0 "No"), gen(transmit_touching)
label var transmit_touching "Knows that HIV cannot be transmitted by touching someone who has HIV"
label val transmit_touching transmit_touching

svy: tab age2 transmit_touching, count format(%4.0f)
svy: tab age2 transmit_touching, percent format(%4.1f) row

*****************

** 04. A PERSON CANNOT BECOME INFECTED BY SHARING FOOD WITH A PERSON WHO HAS HIV
recode mv754wp (0=1 "Yes") (else=0 "No"), gen(sharing_food_HIV)
label var sharing_food_HIV "Knows that a person cannot become infected by sharing food with a person who has HIV"
label val sharing_food_HIV sharing_food_HIV

svy: tab age2 sharing_food_HIV, count format(%4.0f)
svy: tab age2 sharing_food_HIV, percent format(%4.1f) row

*****************

** 05. Persons who say that a healthy looking person can have the AIDS virus and who reject the two most common local misconceptions
/* 
	Two most common local misconceptions: the AIDS virus can be transmitted by 
	mosquito bites and a person can become infected by sharing food with a 
	person who has AIDS. 
*/

gen reject_misconceptions = 0
replace reject_misconceptions = 1 if healthy_look_HIV == 1 & (transmit_mosquito_bites == 1 & sharing_food_HIV == 1)
label define reject_misconceptions 0"No" 1"Yes"
label var reject_misconceptions "A healthy looking person can have the AIDS virus - reject the two most common local misconceptions"
label val reject_misconceptions reject_misconceptions

svy: tab age2 reject_misconceptions, count format(%4.0f)
svy: tab age2 reject_misconceptions, percent format(%4.1f) row

** ========================================================================== **
** ========================================================================== **
** ========================================================================== **

** 06. HIV PREVENTION METHODS
cap drop prevention_methods
gen prevention_methods = 0
replace prevention_methods = 1 if mv754cp == 1 & mv754dp == 1
label define prevention_methods 0"No" 1"Yes"
label var prevention_methods "Knows both prevention methods"
label val prevention_methods reject_misconceptions

svy: tab age2 prevention_methods, count format(%4.0f)
svy: tab age2 prevention_methods, percent format(%4.1f) row

*****************

** 07. COMPEHENSIVE KNOWLEDGE ABOUT HIV
/* 
	Two most common local misconceptions: the AIDS virus can be transmitted by 
	mosquito bites and a person can become infected by sharing food with a 
	person who has AIDS. 
*/

cap drop comprehensive_HIV
gen comprehensive_HIV = 0
replace comprehensive_HIV = 1 if (prevention_methods == 1 & healthy_look_HIV == 1) & (transmit_mosquito_bites == 1 & sharing_food_HIV == 1)
label define comprehensive_HIV 0"No" 1"Yes"
label var comprehensive_HIV ""
label val comprehensive_HIV comprehensive_HIV

svy: tab age2 comprehensive_HIV, count format(%4.0f)
svy: tab age2 comprehensive_HIV, percent format(%4.1f) row

** ========================================================================== **

keep if healthy_look_HIV != .

** ========================================================================== **


exit

Report message to a moderator

Re: comprehensive knowledge of HIV AIDS [message #16395 is a reply to message #16394]

Mon, 07 January 2019 10:32

Trevor-DHS
Messages: 805
Registered: January 2013

Senior Member

Note that the misconceptions are survey specific. In the example given, the code assumes that the two most common misconceptions are: the AIDS virus can be transmitted by mosquito bites and a person can become infected by sharing food with a person who has AIDS. However, the misconceptions must be verified for each survey, and the two most common are used. See the
Guide to DHS Statistics and search for "misconception" to find "Comprehensive Knowledge about HIV (Total and Youth)" for more information on this indicator. Note that some survey specific misconceptions are included in a few surveys too.

Report message to a moderator

Re: comprehensive knowledge of HIV AIDS [message #16396 is a reply to message #16394]

Mon, 07 January 2019 11:51

kamal.chaulagain123@gmail
Messages: 4
Registered: January 2019

Member

Thank you so much. It helped me lot!!!

Report message to a moderator

Re: comprehensive knowledge of HIV AIDS [message #20472 is a reply to message #11571]

Sat, 07 November 2020 21:56

Jayanta
Messages: 28
Registered: September 2017

Member

Dear Trevor,

I have used the stata syntax that you provided for calculating the comprehensive knowledge of HIV/AIDS for NFHS 2015-16 India IR data but the result seems to be different from the DHS report. Could you please help me with how it has been calculated in the case of NFHS 2015-16 data.

Thank you in advance for your help in this regards.

Regards,
Jayanta

Report message to a moderator

Previous Topic:	Women/Children HIV/TB Status Tracking Variable (Nigeria)
Next Topic:	Maternal and Child HIV status

Goto Forum:

-=] Back to Top [=-

[ Syndicate this forum (XML) ] [

] [

]

Current Time: Wed Dec 11 18:47:41 Coordinated Universal Time 2024