Re: Births protection against neonatal tetanus [message #15150 is a reply to message #15014] |
Fri, 08 June 2018 12:47 ![Go to previous message Go to previous message](/theme/default/images/up.png) ![Go to next message Go to previous message](/theme/default/images/down.png) |
Bridgette-DHS
Messages: 3139 Registered: February 2013
|
Senior Member |
|
|
Following is a response from DHS Senior Research Associate, Lindsay Mallick:
Please see attached and below for the Stata program for coding tetanus protection.
*Generate weight
gen wt=v005/1000000
*generate age in months variable
gen agemo = v008 - b3
label variable agemo "Age of child in months or months since birth"
****Tetanus****
*two injections alst pregnancy
gen tet2lastp = 0
replace tet2lastp =1 if m1 >1 & m1<8
label var tet2lastp "Had 2 or more tetanus shots during last pregnancy"
/*New variable includes mothers with two injections during the pregnancy of their last birth or two or
more injections (the last within 3 years of the last live birth), three or more injections (the
last within 5 years of the last birth), four or more injections (the last within 10 years of the
last live birth), or five or more injections at any time prior to the last birth.*/
*variables used: m1 is total tet injections during the most recent pregnancy
*m1a is total tet injections before the pregnancy
*m1e is the data in CMCs of last injection before pregnancy, may be m1d like in nepal
**Full tetanus
*first calculate total tetanus shots
g totet=0
g ttprotect = 0
replace totet=m1 if m1>0 & m1<8
replace totet= m1a + totet if (m1a > 0 & m1a < 8)
label val totet yesno
*now generating variable for date of last injection - will be 0 for women with at least 1 injection at last pregnancy
*use b19, new CDC age var
g lastinj= 9999
replace lastinj = 0 if m1>0 & m1 <8
gen int age = (agemo)/12
replace lastinj = m1d - age if m1d <20 & (m1==0|(m1>7 & m1<9996)) // years ago of last shot - (age at of child), yields some negatives
*now generate summary variable for protection against neonatal tetanus
replace ttprotect = 1 if tet2lastp ==1
replace ttprotect=1 if totet>=2 & lastinj<=2 //at least 2 shots in last 3 years
replace ttprotect=1 if totet>=3 & lastinj<=4 //at least 3 shots in last 5 years
replace ttprotect=1 if totet>=4 & lastinj<=9 //at least 4 shots in last 10 years
replace ttprotect=1 if totet>=5 //at least 2 shots in lifetime
*replace ttprotect=0 if ttprotect==.
lab var ttprotect "Full Neonatal Tetanus Protection"
ta ttprotect if bidx==1 [iw=wt]
-
Attachment: tetanus.do
(Size: 2.06KB, Downloaded 407 times)
[Updated on: Fri, 08 June 2018 12:52] Report message to a moderator
|
|
|