The DHS Program User Forum: Ethiopia » matching data with the report

Home » Countries » Ethiopia » matching data with the report

Show: Today's Messages :: Show Polls :: Message Navigator

matching data with the report [message #14834]

Tue, 08 May 2018 11:49

Fana
Messages: 3
Registered: May 2018
Location: Belgium

Member

Hello,

I am using the 2005,2011 and 2016 Ethiopian DHS to see the factors associated with Micro nutrient intake of children from 6-23 month from diet and 6-59 month from supplementation(for vitamin A and Iron) as well as iodine intake from the salt using the KR file. However I am having difficulties matching the total number of children with the report table using SPSS version 25. I have applied the weight V005/1000000 and created a variable to get the age of children in month(v008-b3).
my second question is if the amount of foods consumed is collected and which variable is it because I could not find it.

Thank you,

Report message to a moderator

Re: matching data with the report [message #14984 is a reply to message #14834]

Wed, 23 May 2018 13:37

Bridgette-DHS
Messages: 3215
Registered: February 2013

Senior Member

Following is a response from DHS Technical Specialist, Rukundo Benedict:

Dear User,

It sounds like you need ensure that you are selecting the sample correctly. The code below provides some guidance. Also note that for the 2016 Ethiopia DHS you will need to use b19 for age (i.e. months=b19).

For diet, the sample is among youngest children 6-23mo living with the mother
*// Age of the child in months .
COMPUTE months = (V008 - B3 ). 
RECODE Months (0,1 = 1) (2,3 = 2) (4,5=3) (6,7,8=4) (9 thru 11 = 5) (12 thru 17=6) (18 thru 23=7) (24 thru 35 = 8) (36 thru 47=9) (48 thru 59=10) INTO ChAge.
VARIABLE LABELS ChAge "Age in months".
VALUE LABELS ChAge 1"0-1" 2"2-3" 3"4-5" 4"6-8" 5"9-11" 6"12-17" 7"18-23" 8"24-35" 9"36-47" 10"48-59".

*// Selecting living children 6-59 .
SELECT IF ( months >= 6 & months <= 59 & B5 = 1).

*// Weighting table.
COMPUTE rweight = V005 / 1000000.
WEIGHT BY rweight.
   
*// eggs, any meat, organ meat, fish/shellfish.
IF ( V414G=1 | V414H=1 | V414M=1 | V414N=1) MeatF = 1.
*// fruits & vegetables rich in vitamin A.
IF ( V414I = 1 | V414J =1 | V414K=1 ) Fruits = 1.

*// Percentage who consumed foods rich in vitamin A in past 24 hours1 .
IF ( Fruits = 1 | MeatF ) VitaminA = 1.
VARIABLE LABELS VitaminA "Percentage who consumed foods rich in vitamin A in past 24 hours1".
*// Percentage who consumed foods rich in iron in past 24 hours 2.
IF ( MeatF = 1 ) Iron = 1.
VARIABLE LABELS Iron "Percentage who consumed foods rich in iron in past 24 hours2".
*// Number of children 6-23.
IF ( Youngest > 0 ) Chld623 = 1.
VARIABLE LABELS chld623  "".
VALUE LABELS chld623  1"Number of children".
IF ( Youngest > 0 ) Label1 = 1.
VARIABLE LABELS Label1  "".
VALUE LABELS Label1  1"Among youngest children age 6-23 months living with the mother:".

For supplements, the sample is all children age 6-59 months 
*//  Vitamin A date in months .
IF ( H33M >= 1 & H33M <= 12 & H33Y >= 2006 & H33Y <= 2020) VAdate = V008 - (( H33Y-1900) *12 + H33M).
IF ( VAdate <= 6 ) LastVA = 1.
*//  vitamin A and salt for living children .
+ IF ( LastVA = 1 | H34 = 1 ) VAsupple = 1.
VARIABLE LABELS VAsupple "Percentage given vitamin A supplements in past 6 months".
*// Percentage given iron supple- ments in past 7 days.
+ IF ( H42= 1 ) Iron7day = 1.
VARIABLE LABELS Iron7day "Percentage given iron supple- ments in past 7 days".
IF ( Months >= 6 & Months <= 59 & B5 = 1 ) Chld659 = 1.
VARIABLE LABELS Chld659 "Number of children".

For iodized salt, it is only children 6-59 months living in a household tested for iodized salt:
*//  children 6-59 & household salt tested.
+ IF (HV234A = 1) Iodine = 1.
VARIABLE LABELS Iodine "Percentage living in house holds with iodized salt4".
*// Number of children 6-59 living in HH tested for iodine.
IF ( Months >= 6 & Months <= 59 & B5 = 1 & HV234A >= 0 & HV234A <= 1 ) IodineHH = 1.
VARIABLE LABELS IodineHH "".
VALUE LABELS IodineHH 1"Number of children".
IF ( Months >= 6 & Months <= 59 & B5 = 1 & HV234A >= 0 & HV234A <= 1 ) Label3 = 1.
VARIABLE LABELS Label3  "".
VALUE LABELS Label3  1"Among children age 6-59 months living in households tested for iodized salt:".

In response to your second question, the DHS does not collect data on the quantity of food consumed by children 6-23months; we collect data only on the types of foods and liquids consumed by children in the previous 24hrs.

Report message to a moderator

Re: matching data with the report [message #15009 is a reply to message #14984]

Thu, 24 May 2018 21:58

Hassen
Messages: 121
Registered: April 2018
Location: Ethiopia,Africa

Senior Member

Thank you all!! I have learned more from this post.

Hassen Ali(Chief Public Health Professional Specialist)

[Updated on: Thu, 24 May 2018 21:59]

Report message to a moderator

Re: matching data with the report [message #15089 is a reply to message #14984]

Thu, 31 May 2018 09:26

Fana
Messages: 3
Registered: May 2018
Location: Belgium

Member

Dear,

Thank you for the response but the code below is not working because there is no variable with the name the 'youngest' in the children's dataset.
*// Number of children 6-23.
IF ( Youngest > 0 ) Chld623 = 1.
VARIABLE LABELS chld623 "".
VALUE LABELS chld623 1"Number of children".
IF ( Youngest > 0 ) Label1 = 1.
VARIABLE LABELS Label1 "".
VALUE LABELS Label1 1"Among youngest children age 6-23 months living with the mother:".

so my question is how do I select the youngest children?

Thanks

Report message to a moderator

Re: matching data with the report [message #15113 is a reply to message #15089]

Tue, 05 June 2018 07:50

Bridgette-DHS
Messages: 3215
Registered: February 2013

Senior Member

Following is a response from Senior DHS Stata Specialist, Tom Pullum:

I can only say how we do this in Stata. Open the KR file (ETKR70FL.dta) and paste the following lines into the command window:

* restrict to children living with the mother
keep if b9==0

* the youngest child will be the one with the lowest value of bidx
sort v001 v002 v003 bidx
egen sequence=seq(), by(v001 v002 v003)

tab sequence bidx,m
keep if sequence==1

Stata has some "egen" ("extensions to generate") commands that are very helpful. This one, "seq()", as used here, will sequence the children who have the same mother (identified with v001 v002 v003) in the order of bidx. This is used AFTER the KR file has been reduced to children who are living with the mother (no need to do a separate check on whether they are alive), given with b9=0. If SPSS does not have a command similar to seq(), you will have to find some other way to do this. Perhaps another SPSS user can help.

Report message to a moderator

Re: matching data with the report [message #17552 is a reply to message #15113]

Sun, 14 April 2019 19:22

abebe
Messages: 10
Registered: February 2019

Member

Hello,
I have a few questions on the code given above for identifying the iodized salt intake

1, which data set do I have to use( I tried the children one but the variable HV234A doesn't exist in the children dataset?
2. if it is the household member dataset then the variable B5( child is alive) is not there.
3. with the code I can only find children that has taken iodized salt intake so how can I get the total number who were included in the interview

Thanks

Report message to a moderator

Re: matching data with the report [message #17610 is a reply to message #17552]

Fri, 26 April 2019 10:37

Bridgette-DHS
Messages: 3215
Registered: February 2013

Senior Member

Following is a response from Senior DHS Stata Specialist, Tom Pullum:

Please provide more information. I can assume that you are working with the Ethiopia 2016 survey, but are you trying to match a table in the main report on this survey? If so, please give the number of the table and what numbers IN the table you are trying to match. Are you trying to relate iodine to child survival? Otherwise, why would you want b5? There may not be any information on the relationship between iodine and survival.

Report message to a moderator

Re: matching data with the report [message #17615 is a reply to message #17610]

Fri, 26 April 2019 11:46

abebe
Messages: 10
Registered: February 2019

Member

I am trying to see an association with the sociodemographic characteristics of the household with iodine intake of children. In 2016 EDHS report, page 211 the table for the percentage of children living in households with iodized salt shows a total of 8993 children aged 6-59 month. I want to get this number but I am not sure which dataset to use. I am asking about B5 because your colleague above give this recommended code for another person with the same question which Is shown below. However, in this recommended code it is a bit confusing which dataset to use. I tried to use the children(KR) dataset but the variable HV234A doesn't exist. I also tried to use the household member(PR) dataset but the variable B5 doesn't exist. I tried it without the b5 but I got a total of 9471 children instead of 8993. so my question is which dataset do I have to use and how do I get the number 8993?

For iodized salt, it is only children 6-59 months living in a household tested for iodized salt:
*// children 6-59 & household salt tested.
+ IF (HV234A = 1) Iodine = 1.
VARIABLE LABELS Iodine "Percentage living in house holds with iodized salt4".
*// Number of children 6-59 living in HH tested for iodine.
IF ( Months >= 6 & Months <= 59 & B5 = 1 & HV234A >= 0 & HV234A <= 1 ) IodineHH = 1.
VARIABLE LABELS IodineHH "".
VALUE LABELS IodineHH 1"Number of children".
IF ( Months >= 6 & Months <= 59 & B5 = 1 & HV234A >= 0 & HV234A <= 1 ) Label3 = 1.
VARIABLE LABELS Label3 "".
VALUE LABELS Label3 1"Among children age 6-59 months living in households tested for iodized salt:".

Report message to a moderator

Re: matching data with the report [message #17759 is a reply to message #17615]

Wed, 22 May 2019 19:16

abebe
Messages: 10
Registered: February 2019

Member

Dear,
It has been more than a month since I asked my question but didn't get a response. I am unable to proceed with my work so can you please give me a response? Thank you!

Report message to a moderator

Re: matching data with the report [message #17819 is a reply to message #17759]

Sun, 16 June 2019 06:33

Bridgette-DHS
Messages: 3215
Registered: February 2013

Senior Member

We emailed you but have not received a reply. Which statistical package are you using?

Report message to a moderator

Re: matching data with the report [message #17827 is a reply to message #17819]

Tue, 18 June 2019 16:33

Bridgette-DHS
Messages: 3215
Registered: February 2013

Senior Member

Following is a response from Senior DHS Data Processing Specialist, Ladys Ortiz:

I will be helping you to solve the issue you have by trying to replicate one of the denominators of table 11.8. To replicate the last 2 columns of table 11.8 you will need to use two datasets: KR and HR. The variables needed to select children living children 6-59 months old are: B5 and B19. To get the iodine information you will need variable HV234A from the "HR" dataset.

Please see below, the SPSS syntax I put together for you, and the frequencies that match the last column of table 11.8 of the final report.

If you have any other questions let me know.

*** Step 1: Open KR data file  Note that the PATH below is based on the folders structure I have on my computer.
GET  FILE='C:\Work2019\ETKR70FL.SAV'.

*** Step 2: Rename ID variables to match Household data.
RENAME VARIABLES V001 = hv001, V002 = HV002.
EXECUTE.

*** Step 3: Merge HR  data to children data.
MATCH FILES /FILE=*
  /TABLE='C:\Work2019\ETHR70FL.SAV'
  /BY HV001 HV002.
EXECUTE.

*** Step 4: Compute Weight variable.
COMPUTE WT = V005 / 1000000.
WEIGHT BY WT.

*** Step 5: Select denominator.
*** Children 6-59 months old and alive and household tested for iodine.
COMPUTE Chld_eligible= (B19 >= 6 & B19 <= 59 & B5 = 1 & HV234a <= 1).
VARIABLE LABELS Chld_eligible 'Children eligible for table 11.8 (last column)'.
VALUE LABELS Chld_eligible 0 'Not Selected' 1 'Selected'.
FILTER BY Chld_eligible.
EXECUTE.

FREQUENCIES Chld_eligible.
*** Step 1: Open KR data file.
GET  FILE='C:\Work2019\ETKR70FL.SAV'.

*** Step 2: Rename ID variables to match Household data.
RENAME VARIABLES V001 = hv001, V002 = HV002.
EXECUTE.
*** Step 3: Merge Idione data to children data.

MATCH FILES /FILE=*
  /TABLE='C:\Work2019\ETHR70FL.SAV'
  /BY HV001 HV002.
EXECUTE.

*** Step 4: Weight variable.
COMPUTE wt = V005 / 1000000.
WEIGHT BY WT.

*** Step 5: Select denominator.
*** Children 6-59 months old and alive and household tested for iodine = 0,1.
COMPUTE Chld_eligible= (B19 >= 6 & B19 <= 59 & B5 = 1 & HV234a <= 1).
VARIABLE LABELS Chld_eligible 'Children eligible for table 11.8 (last column)'.
VALUE LABELS Chld_eligible 0 'Not Selected' 1 'Selected'.
FILTER BY Chld_eligible.
EXECUTE.

FREQUENCIES Chld_eligible.

/index.php?t=getfile&id=1447&private=0

Attachment: child_eligible.png
(Size: 6.72KB, Downloaded 1103 times)

Report message to a moderator

Previous Topic:	Anthropometry_Ethiopia_2011DHS
Next Topic:	SPA data set related question

Goto Forum:

-=] Back to Top [=-

[ Syndicate this forum (XML) ] [

] [

]

Current Time: Mon Dec 30 09:23:08 Coordinated Universal Time 2024