The DHS Program User Forum
Discussions regarding The DHS Program data and results
Home » Topics » Nutrition and Anthropometry » Calculated rates of exclusive breastfeeding not matching rates in reports
Calculated rates of exclusive breastfeeding not matching rates in reports [message #15712] Tue, 04 September 2018 18:54 Go to next message
IHME is currently offline  IHME
Messages: 11
Registered: October 2017
Member
We are attempting to calculate rates of exclusive breastfeeding among children 0-5 months for three surveys and are getting values near 0 after running code and tabulating, when DHS reports much higher values (which is what we expect to see in our calculations too).

We haven't been able to figure out where the issue is. It does seem like there is a lot of missingness on the food questions, which ultimately makes our sample size quite a bit smaller than that listed in the reports. The missing variables due to questions that weren't asked doesn't appear to be causing the issues we're having either.

The three surveys are Democratic Republic of Congo 2007, Mozambique 2003, and Rwanda 2005.

We are using the food diary questions from these child recode files: CDKR50DT, MZKR41DT, RWKR53DT

Any insight you can provide about what might be happening is very much appreciated.

Regards

[Updated on: Tue, 04 September 2018 18:55]

Report message to a moderator

Re: Calculated rates of exclusive breastfeeding not matching rates in reports [message #15748 is a reply to message #15712] Mon, 10 September 2018 12:28 Go to previous messageGo to next message
Liz-DHS
Messages: 1516
Registered: February 2013
Senior Member
Dear User,
Quote:

The exclusive breastfeeding estimates are based on current status data, and the types of food given in the previous 24 hours. To be included, the respondent must be currently breastfeeding and not receiving any of the listed foods in the prior 24 hours.
You can search the forum for "exclusive breastfeeding". There are several posts on this topic. Thank you!
Re: Calculated rates of exclusive breastfeeding not matching rates in reports [message #15757 is a reply to message #15748] Mon, 10 September 2018 21:06 Go to previous messageGo to next message
IHME is currently offline  IHME
Messages: 11
Registered: October 2017
Member
Hello Liz,

Thank you for your response. This is something that we have taken into account in our methodology and code already. Unfortunately, I am not able to find the answer to the issue we are seeing in other forum posts. Is it possible to follow up with you via email so that I can send you our methodology and code?

Regards,
Re: Calculated rates of exclusive breastfeeding not matching rates in reports [message #16046 is a reply to message #15757] Fri, 26 October 2018 10:04 Go to previous message
Bridgette-DHS is currently offline  Bridgette-DHS
Messages: 3016
Registered: February 2013
Senior Member
Following is a response from DHS Technical Specialist, Rukundo Benedict:

The variables you listed for the liquids and solids look correct. I suspect your issue may be with selecting the sample. The code below will ensure you select the correct sample and the results will match the report. I would encourage you to also review the new DHS-7 guide to statistics, particularly if you are comparing breastfeeding changes over time.

***SELECTING SAMPLE***
*Generate weight variable**
gen wgt=v005/1000000
*Generate age, keep those <2 years
gen age = v008-b3
*keep only those children alive 
ta b5
keep if b5==1
*Generate age groups
recode age (0/1=1 "0-1")(2/3=2 "2-3")(4/5=3 "4-5")(6/8=4 "6-8")(9/11=5 "9-11")(12/17=6 "12-17")(18/23=7 "18-23"), gen (age_months)
**If drank from bottle with nipple (bottlefeeding)
gen bottle=0
replace bottle=1 if m38==1 
ta age_month bottle  [iw=wgt], row
*Important Note: for the other indicators, children must be the youngest child and living with mother
*keep only those living with mother
keep if b9==0
* finding the youngest child living with the mother
bysort v001 v002 v003: egen minbidx=min(bidx) 
* keep only children less than 2 years 
keep if age<24
ta bidx minbidx 
* need to drop those that are bidx==2 and minbidx==1
drop if bidx>minbidx
ta age_month [iw=wgt]

***FOR CD***
gen water=0
gen liquids=0
gen milk=0
gen solids=0
gen breast=0
*To determine if child is given water, sugar water, jiuce, tea or other  
replace water=1 if (v409>=1 & v409<=7)
                  
* If given other liquids
foreach xvar of varlist v409a v410 v410a v413*  {
replace liquids=1 if `xvar'>=1 & `xvar'<=7
}
                                                                                          
* If given powder/tinned milk, formula or fresh milk 
foreach xvar of varlist v411 v411a v412 v414p {
replace milk=1 if `xvar'>=1 & `xvar'<=7
}
*If currently breastfeeding
replace breast=1 if m4==95 
*If given any solid
foreach xvar of varlist v414* {
replace solids=1 if `xvar'>=1 & `xvar'<=7
}
replace solids=1 if v412a==1 | v412b==1 
gen feeding=1
replace feeding=2 if water==1
replace feeding=3 if liquids==1
replace feeding=4 if milk==1
replace feeding=5 if solids==1
replace feeding=0 if breast==0
label define feeding 0 "Not breastfeeding" 1 "exclusive breastfeeding" 2 "+Water" 3 "+Liquids" 4 "+Other Milk" 5 "+Solids"
label val feeding feeding
ta age_month feeding  [iw=wgt], row

****FOR MZ & RW****
gen water=0
gen liquids=0
gen milk=0
gen solids=0
gen breast=0

*To determine if child is given water, sugar water, juice, tea or other  
replace water=1 if (m37a>=1 & m37a<=7)
                  
* If given other liquids 
foreach xvar of varlist m37b m37c m37d m37e m37i m37j m37l{
replace liquids=1 if `xvar'>=1 & `xvar'<=7
}
                                                                                          
* If given powder/tinned milk, formula or fresh milk 
foreach xvar of varlist m37f m37g m37h {
replace milk=1 if `xvar'>=1 & `xvar'<=7
}

*If currently breastfeeding
replace breast=1 if m4==95 


*If given any solid 
foreach xvar of varlist m37m m37n m37o m37p m37q m37r m37s m37t m37u m37v m37w m37x m37y{
replace solids=1 if `xvar'>=1 & `xvar'<=7
}

gen feeding=1
replace feeding=2 if water==1
replace feeding=3 if liquids==1
replace feeding=4 if milk==1
replace feeding=5 if solids==1
replace feeding=0 if breast==0
label define feeding 0 "Not breastfeeding" 1 "exclusive breastfeeding" 2 "+Water" 3 "+Liquids" 4 "+Other Milk" 5 "+Solids"
label val feeding feeding
ta age_month feeding  [iw=wgt], row
Previous Topic: Missing anthropometry data for African countries
Next Topic: determining Children Nutrition Using Children Z score
Goto Forum:
  


Current Time: Thu Mar 28 04:45:32 Coordinated Universal Time 2024