The DHS Program User Forum      
Discussions regarding The DHS Program data and results
Home » Topics » Mortality » Maternal Mortality
Maternal Mortality [message #8552] Fri, 13 November 2015 00:12 Go to next message
stellacs is currently offline  stellacs
Messages: 5
Registered: November 2015
Location: Australia
Member
Hi There,

I am trying to replicate the DHS numbers for maternal mortality rate in Indonesia for 2012. I am following the instructions given in the http://dhsprogram.com/pubs/pdf/DHSG1/Guide_to_DHS_Statistics _29Oct2012_DHSG1.pdf However, I am not able to get the same number of maternal deaths by age groups. To calculate the age groups I am using the sister's age at death, while to calculate the period of death I am using the difference between the date of death and date of interview, truncating it to a difference of 60 (given the dates CMC format). Although the total is similar, it should be the same and the age groups distribution as well differs greatly.

| DHS | My calculation
15-19 | 4 | 7
20-24 | 12 | 10
25-29 | 20 | 18
30-34 | 17 | 17
35-39 | 18 | 21
40-44 | 14 | 13
45-49 | 7 | 7
Total | 92 | 93

Is there any rescaling or weight factor I need to use? Is the death period correctly specified?

Thanks for any help.


Stella C
Re: Maternal Mortality [message #8599 is a reply to message #8552] Thu, 19 November 2015 21:27 Go to previous messageGo to next message
Reduced-For(u)m
Messages: 249
Registered: March 2013
Senior Member

Bump.

Also, did you use any of the survey weights? I'm not sure whether that is advised here or not.

Could you post a bit of the .do file you used here so that maybe the DHS staff can take a look?
Re: Maternal Mortality [message #8723 is a reply to message #8552] Wed, 09 December 2015 01:11 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 35
Registered: November 2015
Location: australia
Member
Hi,

Using Nepal DHS 2006, how to replicate table 9.2? What variables should we be using to calculate maternal mortality since i can not see the variables that DHS guide has mentioned under adult and maternal mortality section.

Any help would be great.

Thank you so much.

S
Re: Maternal Mortality [message #8744 is a reply to message #8723] Fri, 11 December 2015 15:28 Go to previous messageGo to next message
Reduced-For(u)m
Messages: 249
Registered: March 2013
Senior Member

Check out the "MM" variables for the maternal mortality calculations. These include all the information on the siblings of women interviewed (from which the maternal mortality rates are computed), their birth dates (MM4), whether they are alive (MM2), age at death (MM7), wether their death coincided with a pregnancy (MM9/10). From their you should be able to follow the DHS Guide to Statistics to calculate the rates.

Recode Manual: http://www.dhsprogram.com/pubs/pdf/DHSG4/Recode6_DHS_22March 2013_DHSG4.pdf

DHS Guide to Statistics: https://dhsprogram.com/pubs/pdf/DHSG1/Guide_to_DHS_Statistic s_29Oct2012_DHSG1.pdf

If you don't see those variables, which recode are you using?
Re: Maternal Mortality [message #8786 is a reply to message #8599] Thu, 17 December 2015 21:36 Go to previous messageGo to next message
stellacs is currently offline  stellacs
Messages: 5
Registered: November 2015
Location: Australia
Member
Hi there, thanks for your answer. Yes once I included the weights I got the same results as in the report. Likewise, for the exposure years. This is the program I used

After reshaping

gen year_5=1 if v008-mm8_<=60
label var year_5 "deaths in the last 5 years"
gen preg_death=1 if mm9_==2 | mm9_==3 | mm9_==6
replace preg_death=0 if mm9_==1
label var preg_death "Death during pregnancy or childbearing"
gen age_range= trunc((mm8_-mm4_)/60)
replace age_range=age_range-2
gen mat_dead=1 if (age_range>=1 & age_range<=7) & preg_death==1 & year_5==1
replace mat_dead=0 if (age_range>=1 & age_range<=7) & (preg_death==0) & mm1_==2
replace mat_dead=0 if mm2_==1 & mm1_==2 & (mm3_>=15 & mm3_<=54)
tab age_range mat_dead if mm1_==2
sum v005
scalar k=r(mean)
tab age_range mat_dead if mm1_==2 [iw=v005/k]

Now I want to calculate the confidence interval. What formula shall I use? Or is there any reference you can point out? I found Hanley, J. A., Hagen, C. A., & Shiferaw, T. (1996). However, this paper is for the direct method.
Thanks for your help.



Stella C
Re: Maternal Mortality [message #8802 is a reply to message #8786] Sun, 20 December 2015 17:55 Go to previous messageGo to next message
stellacs is currently offline  stellacs
Messages: 5
Registered: November 2015
Location: Australia
Member
I have an extra question. I am now trying to reproduce the calculations of maternal mortality in Indonesia for 2007. Using the same code, that give me the same numbers as the report in 2012, I get very different results. This after adjusting some changes in the coding of some variables like mm9_.

Is it possible that the method for calculating maternal mortality changed from 2007 to 2012?
I also noticed the sample is smaller and that the proportion of respondents 15-19 is very small compared to other age ranges. Also, when compared to 2012 is less evenly distributed. Could this having an impact in the results I am finding? Was there an extra adjustment on the weights in 2007?

Thank you for your help!


Stella C
Re: Maternal Mortality [message #8839 is a reply to message #8802] Wed, 30 December 2015 15:10 Go to previous messageGo to next message
Liz-DHS
Messages: 955
Registered: February 2013
Senior Member
Dear User,
Your query has been sent to one of our experts. As soon as we are able we will post. Thank you!
Re: Maternal Mortality [message #8851 is a reply to message #8552] Sun, 03 January 2016 16:14 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 498
Registered: January 2013
Senior Member
Below I'm giving my code for calculating the numerators and denominators for the maternal mortality rates (not the ratios) for All women samples. This code usually matches the counts given in the reports exactly, however, for Indonesia 2012 the denominators do not match exactly, although the differences are small - I think this is probably because the maternal mortality modules dates and ages were re-imputed since the tabulations for the report were produced. The program below defaults to a 7 year period, but to produce estimates for a five year period, just change the local variable for the period to be 60 (5 years) instead of 84 (7 years):

* Adult and maternal mortality counts - Trevor Croft - April 25, 2015
* This version applied to Indonesia DHS 2012 - Jan 3, 2016
cd "C:\Data\DHS_Stata"
use "IDIR63FL.DTA", clear

* keep only the variables needed
keep caseid v001 v002 v003 v005 v008 v011 v012 v013 awfactt mm* mmc* 

* Rename all of the repeating variables to drop the leading 0 to help with reshaping
rename mm*_0* mm*_*

* Reshape the file into a sibling history file
* This will be slow to run and could take several minutes or more.
reshape long mmidx_ mm1_ mm2_ mm3_ mm4_ mm5_ mm6_ mm7_ mm8_ mm9_ mm10_ mm11_ mm12_ mm13_ mm14_ mm15_, i(caseid) j(mmindex)

* Rename to drop the trailing underscore on the end of the reshaped variables
rename mm*_ mm*

* Drop empty entries
drop if mmidx==.

* Check total sisters and brothers - compare total from table 15.1
tab mm1

* Drop siblings without sex or survival status
drop if (mm1 == 8 | mm1 == 9 | mm2 == 8 | mm2 == 9 | mm1 == . | mm2 == .)

* Check counts of sisters and brothers by survival status - compare with living siblings and dead siblings from table 15.1
tab mm2 mm1


* Period to use
* 7 years (84 months) before interview or 5 years (60 months) 
local period 60

* Calculate deaths and exposure for each age group.  Each woman can contribute to up to 3 different age groups in the past 7 years.

* Calculate upper and lower limits in CMC for inclusion for time period. Exclude month of interview.
gen upplim = v008-1
* replace upper limit with CMC date of death for siblings that died
replace upplim = mm8 if mm2 == 0
* lower limit - 7 years (84 months) before interview or 5 years (60 months)
gen lowlim = v008-`period'
* Total exposure in the time period
gen exposure = upplim-lowlim+1
replace exposure = 0 if exposure < 0

* Oldest age group
gen agegrp1 = int((upplim-mm4)/60)
* Calculate exposure in this age group
gen expo1 = min(exposure,upplim - (mm4 + agegrp1*60) + 1)
* Calculate deaths
gen deaths1 = (mm2==0 & expo1 > 0)
* Calculate remaining exposure time
replace exposure = exposure - expo1

* Middle age group
gen agegrp2 = agegrp1 - 1
* Calculate exposure in this age group
gen expo2 = min(60,exposure)
* Set deaths to 0 - all deaths are in the oldest age group
gen deaths2 = 0
* Calculate remaining exposure time
replace exposure = exposure - expo2

* Youngest age group
gen agegrp3 = agegrp2 - 1
* Calculate exposure in this age group
gen expo3 = min(60,exposure)
* Set deaths to 0 - all deaths are in the oldest age group
gen deaths3 = 0

* Reshape so that there are separate records for each age group with exposure and eaths in those age groups
reshape long agegrp expo deaths, i(caseid mmindex) j(j)

* Only keep the deaths and exposure in age groups 3 (15-19) through 9 (45-49)
keep if agegrp >= 3 & agegrp <= 9
label define agegrp 3 "15-19" 4 "20-24" 5 "25-29" 6 "30-34" 7 "35-39" 8 "40-44" 9 " 45-49"
label values agegrp agegrp

* Sample weight
gen wt = v005/1000000

* Deaths from table 15.3
tab agegrp mm1 [iw=deaths*wt ] 
* Exposure from table 15.3 (expo is in months, division by 12 to give years)
tab agegrp mm1 [iw=expo*wt/12] 

* Deaths from table 15.4 - restict to maternal deaths
tab agegrp [iw=deaths*wt ] if mm1 == 2 & mm9 >= 2 & mm9 <= 6 
* Exposure from table 15.4 (expo is in months, division by 12 to give years) - restrict to women only
tab agegrp [iw=expo*wt/12] if mm1 == 2


The problem you are having is probably that the 2012 Indonesia survey was an All Women sample while the 2007 Indonesia survey was an Ever-Married Women sample. When analyzing ever-married women samples you need to make assumptions about the never-married women. For example in fertility analysis in surveys using ever-married women samples we assume that never-married women had no children. For maternal mortality where we analyze siblings of respondents we would have to make assumptions about the age and survival status of siblings of never-married women. There are two obvious choices we could make: 1) The simplest - just analyse the siblings of the ever-married women (which is presumably what you have tried), 2) Assume that the distribution of the ages and survival statuses of the siblings of never-married women is the same as that for the ever-married women of the same age, and just apply the all women factors to the siblings data. Unfortunately neither of these assumptions is very good. The first is probably biased as it is excluding siblings of never-married women and never-married women tend to be younger, thus the siblings are biased toward older ages. The second is probably biased as it assumes that ages and survival status of the siblings of never-married women of a certain age is the same as that of ever-married women of the same age, and it seems unlikely that this is true, e.g. less educated women women may marry younger, may have more siblings, and more of them may die at younger ages.

To use the second option using the all women factors, you can just multiply the weight by the all women factor. In other words, replace:
gen wt = v005/1000000

with
gen wt = (v005/1000000)*(awfactt/100)

I tried to reproduce the maternal mortality tables in the report with the second option and I come close to what is shown in the report. When I looked further at our archives I found a re-run version of the tables which I am able to match with the current dataset. I checked for an explanation and do not find one, but it appears that the maternal mortality in the dataset or the maternal mortality tabulation program were modified and the tables in the report do not match what is produced with the current version of the dataset.

Re: Maternal Mortality [message #8853 is a reply to message #8851] Sun, 03 January 2016 23:31 Go to previous messageGo to next message
stellacs is currently offline  stellacs
Messages: 5
Registered: November 2015
Location: Australia
Member
Hi Trevor,
Thanks a lot for your reply and your help. All is very clear now. Once I use the awfactt weight I obtain the exact same results as the report in 2007. Also, using the IDIR62FL.DTA I get the exact same results for 2012. Although the reports seem to have different reference periods, both were calculated using a 5 years period.


Stella C
Re: Maternal Mortality [message #8854 is a reply to message #8851] Sun, 03 January 2016 23:32 Go to previous messageGo to next message
stellacs is currently offline  stellacs
Messages: 5
Registered: November 2015
Location: Australia
Member
Hi Trevor,
Thanks a lot for your reply and your help. All is very clear now. Once I use the awfactt weight I obtain the exact same results as the report in 2007. Also, using the IDIR62FL.DTA I get the exact same results for 2012. Although the reports seem to have different reference periods, both were calculated using a 5 years period.


Stella C
Re: Maternal Mortality [message #8924 is a reply to message #8854] Fri, 15 January 2016 02:04 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 35
Registered: November 2015
Location: australia
Member
Hi, Can i use the same code for Nepal as well?
Re: Maternal Mortality [message #8993 is a reply to message #8924] Mon, 25 January 2016 12:57 Go to previous messageGo to next message
Liz-DHS
Messages: 955
Registered: February 2013
Senior Member
Dear User,
Do you still need assistance with this post?
Thank you!
Re: Maternal Mortality [message #9059 is a reply to message #8993] Wed, 03 February 2016 02:10 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 35
Registered: November 2015
Location: australia
Member
Hi,

I tried to calculate mortality using the same code. it worked!
Thank you

S
Re: Maternal Mortality [message #9063 is a reply to message #8851] Wed, 03 February 2016 20:12 Go to previous messageGo to next message
pramesh is currently offline  pramesh
Messages: 35
Registered: November 2015
Location: australia
Member
Hi,

The coding worked for Nepal DHS 2006 data as well. It matches the number (39 deaths). However, i found difficult to restrict the population into 26378 sisters which has been reported in NDHS 2006.

Is there any coding to restrict the population into 26378 sisters with 39 deaths?

Thanks



Re: Maternal Mortality [message #9169 is a reply to message #8552] Thu, 18 February 2016 01:23 Go to previous messageGo to next message
RAJEEV KUMAR is currently offline  RAJEEV KUMAR
Messages: 3
Registered: January 2016
Location: MUMBAI
Member
sir,

i am a student of M.Phil iips mumbai. i am working on maternal and child mortality in nigeria. i want to calculate maternal mortality rate and ratio of nigera DHS 2013 data. i have found problem with calculating maternal mortality rate and ratio of nigeria DHS data 2013 through stata.

please send me stata do file how to calculate maternal mortality rate and ratio of nigeria DHS-2013 data.
Re: Maternal Mortality [message #9224 is a reply to message #9169] Thu, 25 February 2016 14:07 Go to previous messageGo to next message
Liz-DHS
Messages: 955
Registered: February 2013
Senior Member
Dear User,
Please refer to message #8851 http:// userforum.dhsprogram.com/index.php?t=msg&th=4678&got o=8851&S=88552d01e5e51abc62a9ddeb9a547d04#msg_8851 posted by one of our subject experts. You should be able to adapt the code for your own analysis. Other resources are The Guide to DHS Statistics http:// www.dhsprogram.com/publications/publication-dhsg1-dhs-questi onnaires-and-manuals.cfm and The Standard Recode Manual http:// www.dhsprogram.com/pubs/pdf/DHSG4/Recode6_DHS_22March2013_DH SG4.pdf. After reviewing these resources, if you still have a question, please feel free to post again. Thank you!
Re: Maternal Mortality [message #9301 is a reply to message #9063] Mon, 07 March 2016 04:55 Go to previous messageGo to next message
RAJEEV KUMAR is currently offline  RAJEEV KUMAR
Messages: 3
Registered: January 2016
Location: MUMBAI
Member
sir,
I rajeev kumar a student of M.phil, I am working on maternal mortality in nigeria using DHS data 2013. I found some problem for calculating Age Adjusted General Fertility Rate and also facing Problem to calculatin Age Adjusted mortality rate. sir please send me do file for calculation of Age Adjusted General Fertility Rate and Age Adjusted mortality rate.
Re: Maternal Mortality [message #9302 is a reply to message #9063] Mon, 07 March 2016 05:04 Go to previous messageGo to next message
RAJEEV KUMAR is currently offline  RAJEEV KUMAR
Messages: 3
Registered: January 2016
Location: MUMBAI
Member
I rajeev kumar a student M.Phil. I have facing problem in calculating Age Adjusted General Fertility rate and Age Adjusted mortality rate. please help me how to calculate Age Adjusted General Fertility rate and Age Adjusted mortality rate using DHS-2013 data in nigeria. please send me do file for age adjusted general fertility rate and age adjusted mortality rate using stata.

Re: Maternal Mortality [message #9403 is a reply to message #9302] Thu, 24 March 2016 10:53 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 498
Registered: January 2013
Senior Member
We do not have a do file for calculating the maternal mortality ratios. The Guide to DHS Statistics is a good reference to how to compute the maternal mortality ratio, and the attached spreadsheet provides an example of how the age standardization works (column F comes from table 3.1 in most reports).
Re: Maternal Mortality [message #10274 is a reply to message #8552] Mon, 18 July 2016 05:23 Go to previous messageGo to next message
Resty is currently offline  Resty
Messages: 6
Registered: February 2016
Location: England
Member

Hi,

I am using IDHS in 2012 to calculate the maternal mortality rate in Indonesia. I've changed the file from wide to long data. However, the number of maternal deaths that I got is 372 while in the Indonesia Demographic Health Survey is 92 (Table 15.4). How could be it different?

thanks


Resty Armis
Re: Maternal Mortality [message #10278 is a reply to message #10274] Mon, 18 July 2016 10:13 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 498
Registered: January 2013
Senior Member
Have you restricted the time period to the same time period used in the report (usually the 7 years [0-6] preceding the survey), and have you used weights in your analysis?
Re: Maternal Mortality [message #10522 is a reply to message #10278] Tue, 02 August 2016 06:27 Go to previous messageGo to next message
Resty is currently offline  Resty
Messages: 6
Registered: February 2016
Location: England
Member

thanks, all is clear now.

Resty Armis
Re: Maternal Mortality [message #11274 is a reply to message #10522] Mon, 28 November 2016 03:23 Go to previous messageGo to next message
Opeyemi is currently offline  Opeyemi
Messages: 5
Registered: November 2016
Location: Nigeria
Member
Hello,

Please I would like to have a few clarification to help me with my analysis. I want to calculate the women persons years from the 2008 and 2013 NDHS data set. Please How do I go about that?
Re: Maternal Mortality [message #11286 is a reply to message #11274] Tue, 29 November 2016 00:47 Go to previous messageGo to next message
Opeyemi is currently offline  Opeyemi
Messages: 5
Registered: November 2016
Location: Nigeria
Member
Opeyemi wrote on Mon, 28 November 2016 09:23
Hello,

Please I would like to have a few clarification to help me with my analysis. I want to calculate the women persons years from the 2008 and 2013 NDHS data set. Please How do I go about that?


I have an additional question...I developed a complex sample analysis plan as i watched on the vidoes
/PLAN FILE='C:\Users\....................\Complex Plan for MM.csaplan'
/PLANVARS ANALYSISWEIGHT=WGT
/SRSESTIMATOR TYPE=WR
/PRINT PLAN
/DESIGN STRATA=V022 CLUSTER=V021
/ESTIMATOR TYPE=WR.
However, I am not sure if the Generalized linear module under the Complex plan is as robust as the GLM under the mixed model. The core of my real analysis is the random/mixed model.

So I would like to ask if I can use the mixed model model and then fix the newly weight variable generated with WGT/1000000 as the weight offset value and still get a reasonable result.

Thank you.
Re: Maternal Mortality [message #11291 is a reply to message #11274] Tue, 29 November 2016 14:07 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 498
Registered: January 2013
Senior Member
Here is some SPSS code that I have used for calculating the DHS maternal mortality tabulations. You can extract code from this to calculate the women person years that you need.
Re: Maternal Mortality [message #11292 is a reply to message #11291] Tue, 29 November 2016 14:11 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 498
Registered: January 2013
Senior Member
I don't use GLM and I have never tried using it under the Complex Survey plan, but in general, if you don't take into account the clustered sampling and stratification, and you basically treat the survey as a simple random sample then any confidence intervals will generally be too narrow and any significance tests will over estimate the significance.
Re: Maternal Mortality [message #11294 is a reply to message #11291] Tue, 29 November 2016 15:32 Go to previous messageGo to next message
Opeyemi is currently offline  Opeyemi
Messages: 5
Registered: November 2016
Location: Nigeria
Member
I really appreciate this. I would let you know the outcome, please.
Re: Maternal Mortality [message #11298 is a reply to message #11291] Wed, 30 November 2016 09:11 Go to previous messageGo to next message
Opeyemi is currently offline  Opeyemi
Messages: 5
Registered: November 2016
Location: Nigeria
Member
Thank you so much for the codes again. It has really helped my analysis. I would like to confirm though, the total maternal death (md) generated for the period of interest summed up to 104. Is that right? How is the 398 from the NHS 2008 report calculated?

[Updated on: Wed, 30 November 2016 09:12]

Report message to a moderator

Re: Maternal Mortality [message #11338 is a reply to message #11291] Tue, 06 December 2016 08:40 Go to previous messageGo to next message
Opeyemi is currently offline  Opeyemi
Messages: 5
Registered: November 2016
Location: Nigeria
Member
Thank you so much for the codes again. It has really helped my analysis. I would like to confirm though, the total maternal death (md) generated for the period of interest summed up to 104 unweighted and 110 weighted counts. Is that right? How is the 398 from the NDHS 2008 report calculated?
Re: Maternal Mortality [message #11410 is a reply to message #8552] Thu, 15 December 2016 08:04 Go to previous messageGo to next message
Resty is currently offline  Resty
Messages: 6
Registered: February 2016
Location: England
Member

Hi,

I have a question again. I am using IDHS in 2012 to calculate the maternal mortality rate in Indonesia. I've changed the women data set into sibling's record, but I want to know which one is the respondent and which one is the siblings in the long dataset. After reshaping, however, only the respondent has the unique number and as I reshaped the data into long format, the respondent shared the same id number with her siblings. And I want to know how many the respondents have 1, 2, or more siblings?, does each sibling also have unique id number to differ them from the respondent?. I've read about the egen command in many literature, but I need the unique number of the siblings.
many thanks


Resty Armis

[Updated on: Thu, 15 December 2016 08:47]

Report message to a moderator

Re: Maternal Mortality [message #11450 is a reply to message #11410] Thu, 22 December 2016 02:14 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 498
Registered: January 2013
Senior Member
The respondent is not included in the sibling history. The sibling history includes all siblings except for the respondent. The unique number for the sibling is given by MMIDX in conjunction with CASEID.
Re: Maternal Mortality [message #11639 is a reply to message #11450] Fri, 20 January 2017 07:45 Go to previous messageGo to next message
Resty is currently offline  Resty
Messages: 6
Registered: February 2016
Location: England
Member

Thanks, Trevor.

Another question, how can I calculate the confidence interval for the maternal mortality rates in Indonesia (IDHS 2012)?

Regards,
Resty


Resty Armis

[Updated on: Fri, 20 January 2017 07:45]

Report message to a moderator

Re: Maternal Mortality [message #11674 is a reply to message #11639] Wed, 25 January 2017 13:37 Go to previous message
Resty is currently offline  Resty
Messages: 6
Registered: February 2016
Location: England
Member

Hi again,

I found no guide on how to calculate confidence interval in MMR in Guide to DHS statistics. However, I've read the other papers using sisterhood method as well as the IDHS 2012.
It is said that Jackknife repeated replication method is used for variance estimation of more complex statistics such as fertility and mortality rates.
How can I calculate the Standard Error in Maternal Mortality Ratio using the Jackknife repeated replication method?
I hope anyone can help me since I didn't find the guide to calculate in Stata.

best regard,
Resty


Resty Armis

[Updated on: Thu, 26 January 2017 11:45]

Report message to a moderator

Previous Topic: Under 5 Mortality for Nepal
Next Topic: Maternal Mortality Ratio
Goto Forum:
  


Current Time: Sat Apr 29 15:22:11 Eastern Daylight Time 2017