The DHS Program User Forum      
Discussions regarding The DHS Program data and results
Home » Topics » Nutrition and Anthropometry » calculation of exclusive breastfeeding
calculation of exclusive breastfeeding [message #519] Fri, 07 June 2013 08:55 Go to next message
Shree is currently offline  Shree
Messages: 1
Registered: June 2013
Location: Denmark
Member
Hi,

I am trying to see the determinants of exclusive breastfeeding in Armenia using DHS of 2010. For the purpose I used birth recode file of Armenia 2010 DHS. I tried to use variable m39=0 as child exclusively breastfeed but the number does not match with the table no: 12.3.
So would you please suggest me how can i get exact result as in table 12.3 for exclusive breastfeed for youngest children of 0-5 months who were born in last 2 years and lives with mother at the time of survey. It would be very easy for if you sent STATA command to calculate it.

Thank you for your support.
Re: calculation of exclusive breastfeeding [message #566 is a reply to message #519] Tue, 25 June 2013 10:42 Go to previous messageGo to next message
Liz-DHS
Messages: 953
Registered: February 2013
Senior Member
Dear User,
You may want to refer to The Guide to DHS Statistics. http://www.measuredhs.com/pubs/pdf/DHSG1/Guide_to_DHS_Statis tics_29Oct2012_DHSG1.pdf
the document is bookmarked. Under "Infant Feeding" you will find information on how to calculate exclusive breastfeeding and other related indicators.
Re: calculation of exclusive breastfeeding [message #2735 is a reply to message #566] Mon, 18 August 2014 22:33 Go to previous messageGo to next message
jyourkavitch is currently offline  jyourkavitch
Messages: 1
Registered: August 2014
Member
Hi Liz,
I am having the same trouble calculating exclusive breastfeeding. I reviewed the "Guide..." and I understand the calculation but I don't know which variables yield the numerator. I can't figure out how to get it from M4 or M5. And M39 accounts for just solid or semi-solid foods but not infant formula or other liquids. The calculation of the numerator must be some combination of variables--is there a tab plan that includes those details?
I am using the Indonesia 2012 dataset in SAS.
Thanks,
Jennifer
Re: calculation of exclusive breastfeeding [message #2967 is a reply to message #2735] Wed, 24 September 2014 19:06 Go to previous messageGo to next message
thebull is currently offline  thebull
Messages: 3
Registered: September 2014
Member
Dear Liz, I also had similar problems, i reviewed the guide too.

[Updated on: Wed, 24 September 2014 20:55]

Report message to a moderator

Re: calculation of exclusive breastfeeding [message #2972 is a reply to message #2967] Thu, 25 September 2014 09:37 Go to previous messageGo to next message
Liz-DHS
Messages: 953
Registered: February 2013
Senior Member
Dear User,
Here is a response from one of our experts, Trevor Croft, in communicating with another user:
If you are finding M5_1, M5_2, ... M5_6, those are the variables for 6 different children of the woman, and you must be using the IR dataset. M5_1 is for the last birth, M5_2 is for the child before that, M5_3 is for the child before that, etc.
A problem is that the data on feeding is the for the last child born in the last two years LIVING WITH THE MOTHER. So it is not sufficient to just select women who have children under 6 you need to work out if the child was living with the mother. To do this is easier to work with the KR file, not the IR file. In the KR file, there is only one M5 variable. The code below was written to work with the KR file.
If you want subset that dataset down to the cases you want, you can select on
V008 - B3 < 24 & LastChild==1
For the codes, they should all be documented in the dataset. If the labels are not coming through in the dataset, look at the .SAS file and you can find the labels in there. Search for variable M5 and you will see the format that is used with it. Then search the file for the format and you will find the labels:
93 = "Ever breastfed, not currently breastfeeding"
94 = "Never breastfed"
97 = "Inconsistent"
98 = "Don't know"
And 99 is Missing.

Also of use is the DHS Recode manual, although the codes are not listed in there: http://dhsprogram.com/publications/publication-dhsg4-dhs-que stionnaires-and-manuals.cfm
If you have additional questions, please post again.
Re: calculation of exclusive breastfeeding [message #3366 is a reply to message #2972] Thu, 27 November 2014 21:43 Go to previous messageGo to next message
Shek
Messages: 5
Registered: November 2014
Member
I was able to create exclusive breastfeeding variable, which matched with the value reported in the DHS manual for the country am working on, however, i am getting results(when i cross tabulate exclusive breast feeding variable with M38 and M55Z) that shows that a small proportion of infants who were exclusively breastfeed also drank from a bottle with nipple(M38)and am also getting figures indicating that some of the exclusive breast fed infants were given something(M55Z) first 3 day before milk flowed. Could the variable i created exclusive breast feeding be wrong even if its matching with the figure reported in the DHS country report or were the small proportion of infants given expressed breast milk in a bottle with nipple(M38) and if they were given something before milk flowed(M55Z), how can i explain that they were exclusively breast fed. Thanks.
Re: calculation of exclusive breastfeeding [message #3367 is a reply to message #2972] Thu, 27 November 2014 21:44 Go to previous messageGo to next message
Shek
Messages: 5
Registered: November 2014
Member
Thanks. Above advice was helpful

[Updated on: Fri, 28 November 2014 12:40]

Report message to a moderator

Re: calculation of exclusive breastfeeding [message #3708 is a reply to message #3367] Thu, 29 January 2015 12:19 Go to previous messageGo to next message
Liz-DHS
Messages: 953
Registered: February 2013
Senior Member
Dear Shek,
Did we answer all your questions or something still pending on this post?
Thank you!
Re: calculation of exclusive breastfeeding [message #8221 is a reply to message #2972] Thu, 17 September 2015 10:09 Go to previous messageGo to next message
danafer is currently offline  danafer
Messages: 1
Registered: March 2013
Location: Boston, MA
Member
Here is the Stata code that I used to identify kids in the subpopulation for exclusive breastfeeding (for 0-5 months) and calculate exclusive breastfeeding. It can be used with the br or kr files. Note, I create my own numeric mom ID and start it with a random number like "8" to prevent missing zeros.

gen long momid = ((8000 + v001) * 10000) + (v002 * 100) + v003
by momid (bidx), sort: gen byte lastchild = sum(b5) == 1 & sum(b5[_n - 1]) == 0
gen byte exlbreast_subpop = 1 if (v008 - b3) < 6 & lastchild == 1 & b9 == 0
Re: calculation of exclusive breastfeeding [message #8761 is a reply to message #8221] Mon, 14 December 2015 11:44 Go to previous messageGo to next message
Lupe is currently offline  Lupe
Messages: 9
Registered: June 2013
Location: Lima
Member
Hello
I just do it, it was hard.
*LACTANCIA MATERNA EXCLUSICA MENORES DE 6 MESES
*Ubicando la carpeta donde se trabajara
cd "C:\Users\lvidal\Documents\ENDES\endes 2014\bases stata14"
******************************************
*ORDENANDO LOS ARCHIVOS DE DATOS
*Abrir archivo con información del hogar de la base REC0111 (95var)
use REC0111, clear
sort CASEID
save REC0111_tmp, replace
*Abrir archivo con información de reproductivo historia de nacimientos REC21 (19)
use REC21, clear
sort CASEID BIDX
rename BIDX MIDX
save REC21_tmp, replace
*Abrir archivo con información de STI, AIDS, CPN, know Violencia Dome REC91 (318)
use REC91, clear
sort CASEID
save REC91_tmp, replace
*Abrir archivo con información de maternidad REC41 (146)
use REC41, clear
sort CASEID MIDX
save REC41_tmp, replace

*UNIENDO LOS ARCHIVOS

merge m:1 CASEID MIDX using REC21_tmp.dta
keep if _merge==3
drop _merge
save REC41_tmp, replace
tab MIDX, mis
tab M4, mis


***SELECCIONAR LOS QUE VIVEN CON LAS MADRES
*La preg 211 ahora me gustaria conversar acerca de todos sus hijos e hijas
*La pregunta en el cuestionario es si vive con ud
*B9=child lives with whom renpondent=0 live elsewhere=4
tab B9
*selecionar solo a los que viven con sus madres
keep if B9==0

*se elimino 277 observaciones
*usando el valor minimo de MIDX=el valor minimo del indice de la historia de nacimiento
collapse (min) MIDX, by(CASEID)
*guardamos el nuevo archivo
save aggr, replace
tab MIDX

use aggr, replace
*unimos al archivo pre_natal_post
merge m:1 CASEID MIDX using REC41_tmp.dta
keep if _merge==3
drop _merge
*ordenamos y guardamos el archivo con el mismo nombre
sort CASEID
save REC41_tmp, replace
tab M4
tab MIDX

*Cargamos el archivo con información de lactancia y salud del niño REC42 ordenamos y guardamos
use REC42,replace
sort CASEID
*Unimos al archivo caracthogar
merge m:1 CASEID using REC0111_tmp.dta
keep if _merge==3
drop _merge
tab V401, mis

*unimos el archivo pre_natal_post
merge m:1 CASEID using REC41_tmp.dta
tab V401, mis
*keep if _merge==3
drop _merge
*igual en spss

*unimo el archivo cpn_its_violen
merge 1:1 CASEID using REC91_tmp.dta
keep if _merge==3
drop _merge
tab V401, mis

*guardar el archivo final que llameremos lactancia
save REC42_tmp, replace

************************************************************ ******************
*Estableciendo el tipo de muestra
*estableciendo los pesos
gen peso=v005/1000000
*cambiando la provincia del Callao por departamento de Lima
recode V024 (7=15)

*para sacar los valores igual a spsss se utiliza el comando
table V024 [pweight = peso]

************************************************************ ******************
*GENERANDO LA VARIABLE LACTANCIA
*recodificando la variable M4=duración de la lactancia del niño en meses
*M4:
tab M4
*con este comando salen los mismos valores del spss
table M4 [pweight = peso]
*94 Never breastfed
*95 Still breastfeeding
*98 DK

gen lacta=.
replace lacta=1 if M4!=. & M4<=94
replace lacta=2 if M4!=. & M4==95
table lacta, mis
*para sacar los valores igual a spsss se utiliza el comando
table lacta [pweight = peso]

*Incluyendo las variables de consumo de alimentos
foreach x of varlist V409-V414U {
replace lacta =1 if `x'==1 & `x'!=.
}

table lacta [pweight = peso]
label define lacta 1 "No lacta,lacta y otro alim" 2 "Solo lacta"
label values lacta lacta

************************************************************ ******************
*GENRANDO LA VARIABLE LACTANCIA EXCLUSIVA
*Generando la edad
gen edadm=V008-B3
recode edadm (0/3=1 "0a3 meses") ( 4/5=2 "4a5 meses") if edadm<6 , gen(EDAD2)
recode edadm (0/6=1 "0a6 meses") if edadm<7 , gen(EDAD_0a6)
*para sacar los valores igual a spsss se utiliza el comando

table EDAD2 [pweight = peso]
table EDAD_0a6 [pweight = peso]

*generando la variable lactancia exclusiva
gen lacta_xcl=.
replace lacta_xcl=2 if edadm<36 & lacta==1
replace lacta_xcl=1 if edadm<36 & lacta==2
label define lacta_xcl 1"Solo lacta y tiene 0-6m" 2 "No lacta exclusivamente o > 6m"
label values lacta_xcl lacta_xcl

table lacta_xcl [pweight = peso]
************************************************************ ******************
svyset V001 [pw=peso], strata(V022)
*Lactancia materna exclusiva a nivel nacional en <6m
svy: tabulate lacta_xcl if edadm<6
*Lactancia matenar exclusica a nivel urbano y rural en <6m
svy: tabulate V025 lacta_xcl if edadm<6, row
*Lactancia matenar exclusica en regiones en <6m
svy: tabulate sregion lacta_xcl if edadm<6, row
*Lactancia matenar exclusica en pobreza en <6m
svy: tabulate V190 lacta_xcl if edadm<6, row
*Lactancia matenar exclusica por departamento en <6m
svy: tabulate V024 lacta_xcl if edadm<6, row

calculation of exclusive breastfeeding [message #9037 is a reply to message #519] Sat, 30 January 2016 11:27 Go to previous messageGo to next message
anuth is currently offline  anuth
Messages: 9
Registered: November 2015
Location: Finland
Member
Hello,

I went through this thread to get insight on how to calculate exclusive breastfeeding. Unfortunately the discussion here is based on calculation using STATA but i am carrying the analysis on SPSS. Can anyone help me in this case??

I am using KR file of PDHS 2012-13 and want to carry analysis on IYCF practices.

Thank you;
Anupa


A

[Updated on: Sat, 30 January 2016 11:57]

Report message to a moderator

Re: calculation of exclusive breastfeeding [message #9094 is a reply to message #9037] Wed, 10 February 2016 15:03 Go to previous messageGo to next message
Liz-DHS
Messages: 953
Registered: February 2013
Senior Member
Dear User,
Please refer to the Guide to DHS Statistics: http:// www.dhsprogram.com/publications/publication-dhsg1-dhs-questi onnaires-and-manuals.cfm
The section dealing with exclusive breastfeeding begins on page 123. Please review and if you have additional questions, please feel free to post again. We do not have code in SPSS to distribute, but you may find some guidance on how to approach your analysis in The Guide to DHS Statistics.
Re: calculation of exclusive breastfeeding [message #9098 is a reply to message #9094] Wed, 10 February 2016 15:41 Go to previous messageGo to next message
Lupe is currently offline  Lupe
Messages: 9
Registered: June 2013
Location: Lima
Member
Hello

Sintax in spss is:

1.3. LACTANCIA EXCLUSIVA EN MENORES DE 6 MESES
* INDICADOR:.
******************
* LACTANCIA EXCLUSIVA EN MENORES DE 6 MESES.
* NOTAS:.
******************
* Ruta donde se encuentran los archivos.
* C:\Endes\2008\Base de datos\.
* Año: 2008.
* JUNTANDO LAS BASES DE DATOS NECESARIAS.
************************************************************ ****.
GET FILE='C:\ENDES\2008\Base de Datos\REC0111.SAV'.
sort cases by caseid (A).
SAVE OUTFILE='C:\ENDES\2008\Base de Datos\REC0111_tmp.SAV'.
GET FILE='C:\ENDES\2008\Base de Datos\REC21.SAV'.
sort cases by caseid (A) bidx (A) .
SAVE OUTFILE='C:\ENDES\2008\Base de Datos\REC21_tmp.SAV'.
GET FILE='C:\ENDES\2008\Base de Datos\REC91.SAV'.
sort cases by caseid (A) .
SAVE OUTFILE='C:\ENDES\2008\Base de Datos\REC91_tmp.SAV'.
GET FILE='C:\ENDES\2008\Base de Datos\REC41.SAV'.
sort cases by caseid (A) midx (A) .
MATCH FILES /FILE=*
/TABLE='C:\ENDES\2008\Base de Datos\REC21_tmp.SAV'
/RENAME BIDX=MIDX
/BY CASEID MIDX.
EXECUTE.
SAVE OUTFILE='C:\ENDES\2008\Base de Datos\REC41_tmp.SAV'.
* Los que viven con la madre.
FILTER OFF.
USE ALL.
SELECT IF(B9=0).
EXECUTE .
AGGREGATE
/OUTFILE='C:\ENDES\2008\Base de Datos/aggr.sav'
/BREAK=CASEID
/MIDX = MIN(MIDX).
GET FILE='C:\ENDES\2008\Base de Datos\aggr.SAV'.
MATCH FILES /FILE=*
/TABLE='C:\ENDES\2008\Base de Datos\rec41_tmp.SAV'
/BY CASEID MIDX.
EXECUTE.
SAVE OUTFILE='C:\ENDES\2008\Base de Datos\REC41_tmp.SAV'.
*Ordenamos, hacemos un merger y guardamos.
GET FILE='C:\ENDES\2008\Base de Datos\REC42.SAV'.
sort cases by caseid (A) .
MATCH FILES /FILE=*
/TABLE='C:\ENDES\2008\Base de Datos\REC0111_tmp.SAV'
/BY CASEID.
EXECUTE.
MATCH FILES /FILE=*
/TABLE='C:\ENDES\2008\Base de Datos\REC41_tmp.SAV'
/BY CASEID.
EXECUTE.
MATCH FILES /FILE=*
/TABLE='C:\ENDES\2008\Base de Datos\REC91_tmp.SAV'
/BY CASEID .
EXECUTE.
SAVE OUTFILE='C:\ENDES\2008\Base de Datos\REC42_tmp.SAV'.
* GENERANDO LAS VARIABLES USADAS EN LOS TABULADOS .
************************************************************ ********************.
*Generando el PESO para luego expandirlo.
*Utilizar la variable V005A para calcular resultados departamentales.
COMPUTE PESO=V005/1000000.
WEIGHT BY PESO.
**Recodificando la región natural.
recode sregion (4,5=4).

I hope you find it useful
Re: calculation of exclusive breastfeeding [message #9200 is a reply to message #8761] Mon, 22 February 2016 10:41 Go to previous messageGo to next message
tony is currently offline  tony
Messages: 10
Registered: March 2013
Location: Ghana
Member

Dear Lupe,

Can I have the English version of the Stata syntax on calculating Exclusive breastfeeding. Thanks
Re: calculation of exclusive breastfeeding [message #9201 is a reply to message #9200] Tue, 23 February 2016 08:15 Go to previous messageGo to next message
Lupe is currently offline  Lupe
Messages: 9
Registered: June 2013
Location: Lima
Member
Dear Tony
you have to follow the sintaxys and replace for your variables. That is all.
Good luck
Re: calculation of exclusive breastfeeding [message #9202 is a reply to message #9201] Tue, 23 February 2016 09:43 Go to previous messageGo to next message
tony is currently offline  tony
Messages: 10
Registered: March 2013
Location: Ghana
Member

Dear Lupe,

Thank you for the response. However, can your translate the headings, in the syntax, into English Language. It would help. Thank you once again.

Re: calculation of exclusive breastfeeding [message #9253 is a reply to message #8761] Sat, 27 February 2016 09:51 Go to previous messageGo to next message
tony is currently offline  tony
Messages: 10
Registered: March 2013
Location: Ghana
Member

Thanks

[Updated on: Sat, 27 February 2016 10:47]

Report message to a moderator

Re: calculation of exclusive breastfeeding [message #9254 is a reply to message #2972] Sat, 27 February 2016 14:27 Go to previous messageGo to next message
tony is currently offline  tony
Messages: 10
Registered: March 2013
Location: Ghana
Member

Dear Liz,

I'm using STATA to calculate for the number of youngest child under two years living with their mother. I used the KR file (children dataset) with variables codes MIDX, B9 and hw1; using the Keep if command in STATA. However, I'm not getting the figures in the report. Please, want am I doing wrong? I'm trying to replicate Table 11.3: Breastfeeding status by age of Ghana DHS 2014

[Updated on: Sat, 27 February 2016 16:34]

Report message to a moderator

Re: calculation of exclusive breastfeeding [message #9329 is a reply to message #9098] Sat, 12 March 2016 11:37 Go to previous messageGo to next message
Putri is currently offline  Putri
Messages: 3
Registered: March 2016
Location: United States
Member
Hi DHS team and All DHS users

I need your help to create exclusive breastfeeding variable from 2012 DHS data (Indonesia)
Which variable we can use to get the "current age of infants in months" since variable HW1 or HW1_1 doesn't have any value in my dataset.
for exclusive breastfeeding I need to take infants aged 0-5 months only.
Could you do me a favor?
How do you get exclusive breastfeeding variable?
(I'm using SAS)

Thanks anyway

Putri
Re: calculation of exclusive breastfeeding [message #9452 is a reply to message #9329] Tue, 29 March 2016 16:08 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 495
Registered: January 2013
Senior Member
To calculate the equivalent of hw1 you can create a new variable equal to the difference between the CMC date of interview and the CMC date of birth. In Stata, that is:
gen age = v008 - b3
but I'm sure you can translate that into SAS.
Re: calculation of exclusive breastfeeding [message #9467 is a reply to message #9098] Wed, 30 March 2016 10:06 Go to previous messageGo to next message
riakusumaw is currently offline  riakusumaw
Messages: 1
Registered: March 2016
Location: Jakarta
Member
dear Luke,
thank you so much for your share. i'm working with DHS Indonesia 2012 and having trouble with your sintax in SPSS
when i run it, there will be an error command like this
>Error # 4792 in column 11. Text: PESO
>The name of the weighting variable is undefined. Either the variable has not
>been defined or its name has been misspelled.
>Execution of this command stops.

can you tell me what's wrong with this? thanks before
Re: calculation of exclusive breastfeeding [message #9471 is a reply to message #9452] Wed, 30 March 2016 12:59 Go to previous messageGo to next message
Lupe is currently offline  Lupe
Messages: 9
Registered: June 2013
Location: Lima
Member
Hello
I use stata, but I think so that command in sas is
DATA ......;
age = v008 - b3;
END;
Re: calculation of exclusive breastfeeding [message #9599 is a reply to message #519] Wed, 20 April 2016 13:13 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 495
Registered: January 2013
Senior Member
See this message for Stata code for calculating breastfeeding status, including exclusive breastfeeding
Re: calculation of exclusive breastfeeding [message #10218 is a reply to message #9599] Sun, 10 July 2016 12:51 Go to previous messageGo to next message
sumonrupop is currently offline  sumonrupop
Messages: 12
Registered: August 2015
Location: Rajshahi
Member

Hi Trevor,
I used the code you given to calculate exclusive breastfeeding by using Bangladesh Demographic and Health survey 2014 data. I used the KR file. However, by using these code I found only 13.9% exclusive breastfeeding. In BDHS 2014 report this percentage is 55%. Can you help me to calculate the percentage reported in BDHS report?. Here the code i used .

use BDKR70FL.DTA

* Last child in the last 2 years living with mother
* age in months
gen age = v008-b3
* drop if too old or not alive
keep if age<24 & b5==1
* recode age into groups
recode age (0/1=1 "0-1")(2/3=2 "2-3")(4/5=3 "4-5")(6/8=4 "6-8")(9/11=5 "9-11") ///
(12/17=6 "12-17")(18/23=7 "18-23")(24/59=.), gen(child_age)
* tab of all living children born in the last 2 years
tab child_age
tab child_age [iw=v005/1000000]

* keep only those children living with mother ...
keep if b9==0
* ... and keep the last born of those
drop if _n > 0 & caseid == caseid[_n-1]
* check the deonimnator
tab child_age
tab child_age [iw=v005/1000000]

* breastfeeding status.

gen water=0
gen liquids=0
gen milk=0
gen solids=0
gen breast=0

* Water
replace water=1 if (v409>=1 & v409<=7)

* Other non-milk liquids
* check for country specific liquids
foreach xvar of varlist v409a v410 v410a v412c v413* {
replace liquids=1 if `xvar'>=1 & `xvar'<=7
}

* Powdered or tinned milk, formula, fresh milk
foreach xvar of varlist v411 v411a v412 {
replace milk=1 if `xvar'>=1 & `xvar'<=7
}

* Solid food
* check for country specific foods
foreach xvar of varlist v412a v412b v414* {
replace solids=1 if `xvar'>=1 & `xvar'<=7
}

* Still breastfeeding
replace breast=1 if m4==95

tab1 water liquids milk solids breast

* Generate column variable used in table 11.3
gen feeding=1
replace feeding=2 if water==1
replace feeding=3 if liquids==1
replace feeding=4 if milk==1
replace feeding=5 if solids==1
replace feeding=0 if breast==0
tab feeding,m

label define feeding 0 "Not breastfeeding" 1 "exclusive breastfeeding" 2 "+Water" 3 "+Liquids" 4 "+Other Milk" 5 "+Solids"
label val feeding feeding

tab child_age feeding [iweight=v005/1000000], row

Thanks in advance

Nuruzzaman


Md. Nuruzzaman Khan
Re: calculation of exclusive breastfeeding [message #10249 is a reply to message #10218] Tue, 12 July 2016 17:54 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 495
Registered: January 2013
Senior Member
You need to select for children under the age of 6 months. Just add
tab child_age feeding [iweight=v005/1000000] if child_age <= 3, row
and you will get 55%
Re: calculation of exclusive breastfeeding [message #11142 is a reply to message #10218] Tue, 08 November 2016 11:14 Go to previous messageGo to next message
anuth is currently offline  anuth
Messages: 9
Registered: November 2015
Location: Finland
Member
Hi Nuruzzaman,

I am following your instruction to calculate exclusive breastfeeding.I understood until Solid food calculation and have some queries. Grateful if you could help me.

1. * Still breastfeeding
replace breast=1 if m4==95

Can we use V404 instead of doing this as V404 gives us info about last child who are currently breastfed?

2. * Generate column variable used in table 11.3
gen feeding=1
replace feeding=2 if water==1
replace feeding=3 if liquids==1
replace feeding=4 if milk==1
replace feeding=5 if solids==1
replace feeding=0 if breast==0
tab feeding,m

I am doing the analysis in SPSS and couldn't understand what it mean by generating column variable?

Hoping to get your reply. Thanks a lot in advance.


A
Re: calculation of exclusive breastfeeding [message #11143 is a reply to message #11142] Tue, 08 November 2016 11:53 Go to previous messageGo to next message
Lupe is currently offline  Lupe
Messages: 9
Registered: June 2013
Location: Lima
Member
Dear Anuth
There is an explanation in spss at the botton of the page
Best regards,
Lupe
Re: calculation of exclusive breastfeeding [message #11144 is a reply to message #11143] Tue, 08 November 2016 13:29 Go to previous messageGo to next message
anuth is currently offline  anuth
Messages: 9
Registered: November 2015
Location: Finland
Member
Thanks!

A
Re: calculation of exclusive breastfeeding [message #11413 is a reply to message #11144] Sun, 18 December 2016 06:28 Go to previous messageGo to next message
Roselync is currently offline  Roselync
Messages: 11
Registered: December 2016
Location: Taiwan
Member
Hi Anuth,
I am trying to analyze the 2010 Malawi DHS,I have gone through all the threads on calculation of exclusive breastfeeding but I still cant figure out how to calculate exclusive breastfeeding, complementary and predominant feeding using SPSS.I end up getting different results from those of the MDHS report. Your help will be highly appreciated

Thanks,
Rose
Re: calculation of exclusive breastfeeding [message #11415 is a reply to message #11142] Sun, 18 December 2016 17:37 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 495
Registered: January 2013
Senior Member
Hi Anuth,

In answer to your questions:
1) You don't want to use v404, as that only applies to the last birth, and you might have more than one birth in the last 2 years (in which case v404 does not apply to that birth even though it is set for the woman). You need to use m4 which applies to each birth individually. V404 is a woman level variable and has the same value for all children. M4 is a child level variable and has a different value for each child.

2) Generating the column variable means creating a variable for each of the categories used in the table. The footnote to the tables in the report explain how each of the categories is constructed.
Re: calculation of exclusive breastfeeding [message #11416 is a reply to message #11415] Sun, 18 December 2016 17:39 Go to previous messageGo to next message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 495
Registered: January 2013
Senior Member
Hi Rose, I don't get the same results as the report either when I use my code (which usually matches the reports). In Malawi 2010, I think some of the foods or liquids must have been excluded or categorized differently in the analysis.
Re: calculation of exclusive breastfeeding [message #11417 is a reply to message #11416] Sun, 18 December 2016 19:14 Go to previous messageGo to next message
Roselync is currently offline  Roselync
Messages: 11
Registered: December 2016
Location: Taiwan
Member
Hi anuth,
So you did not include the exclusive breastfeeding in your analysis?
Thanks
Rose
Re: calculation of exclusive breastfeeding [message #11418 is a reply to message #11416] Sun, 18 December 2016 19:20 Go to previous messageGo to next message
Roselync is currently offline  Roselync
Messages: 11
Registered: December 2016
Location: Taiwan
Member
Hi Trevor,
Thanks for the response.In this case does it mean that I can not use the variable exclusive breastfeeding?any suggestions will be highly appreciated.
Thanks in advance,
Rose
Re: calculation of exclusive breastfeeding [message #11428 is a reply to message #11418] Mon, 19 December 2016 11:20 Go to previous message
Trevor-DHS is currently offline  Trevor-DHS
Messages: 495
Registered: January 2013
Senior Member
Note that there is a second thread addressing pretty much the same question at this link. The code is very similar to the code posted earlier.
Previous Topic: Calculation of median exclusive breastfeeding
Next Topic: Minimum Meal frequency in BDHS 2014
Goto Forum:
  


Current Time: Mon Apr 24 05:12:42 Eastern Daylight Time 2017